Vertical center text in INPUT control

[Genotypek]

Hello.

I've got a problem. I want to center my input vertically, but I don't have any single idea how to do it.

There's my example code:

#include <GUIConstantsEx.au3>

$GUI = GUICreate("Gui", 237, 93, 192, 124)
$Input1 = GUICtrlCreateInput("Center vertically isn't correct", 16, 16, 201, 62)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

What could I do?

Greetings, "genotypek".

[BrewManNH]

Input controls aren't really designed to be centered vertically. Why would you want this?

[Genotypek]

I made a program for learning German, the person who is using it has bad sight, so inputs and text have to be bigger. If they're text isn't centered vertically. :/

[UEZ]

 

[Genotypek]

This works only, because he's creating background which looks like input without border, so it's still not allowed to use bigger size of font.

But okay, it's not so important.

But could you tell me, how to add event in input when eg. {enter} will be pressed? For example if {enter} will be pressed it should execute func "function()"?

Best regards.

[UEZ]

You mean something like this here?

Modified example from funkey's code:

expandcollapse popup

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

Global $hGui = GUICreate("Input without border", 215, 214, 192, 124)
;~ GUISetBkColor(0x000000)

Global $Input0 = GUICtrlCreateInput("Standard input control", 16, 10, 180, 20, $ES_CENTER)

Global $Input1 = _CreateInputWithoutBorderAndVerticalCenteredWithBgColor($hGui, "This is an input control", 16, 40, 180, 20, 0xFF0000, $ES_CENTER)
Global $Input2 = _CreateInputWithoutBorderAndVerticalCenteredWithBgColor($hGui, "and there is no border", 16, 70, 180, 51, 0x00FF00, $ES_CENTER)
Global $Input3 = _CreateInputWithoutBorderAndVerticalCenteredWithBgColor($hGui, "click and press enter", 16, 130, 180, 31, 0x00FFFF, $ES_CENTER)

Global $Input4 = GUICtrlCreateInput("Standard input control", 16, 170, 180, 36, $ES_CENTER)

Global $nTabFix = GUICtrlCreateDummy(), $iDummy_Enter = GUICtrlCreateDummy()
Global $AccelKeys[1][2] = [["{TAB}", $nTabFix]]

GUISetAccelerators($AccelKeys)

ControlFocus($hGui, "", $Input0)
GUICtrlSendMsg($Input0, $EM_SETSEL, 0, -1)

GUISetState(@SW_SHOW)

Global $nMsg, $nFocused

GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $nTabFix
            $nFocused = _WinAPI_GetDlgCtrlID(ControlGetHandle($hGui, "", ControlGetFocus($hGui)))
            Switch $nFocused
                Case $Input0
                    ControlFocus($hGui, "", $Input1)
                    GUICtrlSendMsg($Input1, $EM_SETSEL, 0, -1)
                Case $Input1
                    ControlFocus($hGui, "", $Input2)
                    GUICtrlSendMsg($Input2, $EM_SETSEL, 0, -1)
                Case $Input2
                    ControlFocus($hGui, "", $Input3)
                    GUICtrlSendMsg($Input3, $EM_SETSEL, 0, -1)
                Case $Input3
                    ControlFocus($hGui, "", $Input4)
                    GUICtrlSendMsg($Input4, $EM_SETSEL, 0, -1)
                Case Else
                    GUISetAccelerators(0)
                    Send("{TAB}")
                    GUISetAccelerators($AccelKeys)
            EndSwitch
        Case $GUI_EVENT_CLOSE
            Exit
        Case $iDummy_Enter
            MsgBox(0, "Information", "Call the function now")
    EndSwitch
WEnd

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    If $iwParam = 1 And GUIGetCursorInfo($hGui)[4] = $Input3 Then GUICtrlSendToDummy($iDummy_Enter)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func _CreateInputWithoutBorderAndVerticalCenteredWithBgColor($hParent, $sText, $iX, $iY, $iW, $iH, $iColor, $iStyle = -1, $iExStyle = 0)
    GUICreate("", $iW, $iH, $iX, $iY, $WS_CHILD, 0, $hParent)
    GUISetBkColor($iColor)
    Local $nInput = GUICtrlCreateInput($sText, 0, $iH / 2 - 6, $iW, 20, $iStyle, $iExStyle)
    GUICtrlSetFont(-1, 12, 200, 0, "Arial", 5)
    GUICtrlSetBkColor(-1, $iColor)
    GUISetState()
    GUISwitch($hParent)
    Return $nInput
EndFunc   ;==>_CreateInputWithoutBorderAndVerticalCenteredWithBgColor

 

[Genotypek]

On 31.12.2016 at 2:14 PM, UEZ said:

You mean something like this here?

Modified example from funkey's code:

expandcollapse popup

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

Global $hGui = GUICreate("Input without border", 215, 214, 192, 124)
;~ GUISetBkColor(0x000000)

Global $Input0 = GUICtrlCreateInput("Standard input control", 16, 10, 180, 20, $ES_CENTER)

Global $Input1 = _CreateInputWithoutBorderAndVerticalCenteredWithBgColor($hGui, "This is an input control", 16, 40, 180, 20, 0xFF0000, $ES_CENTER)
Global $Input2 = _CreateInputWithoutBorderAndVerticalCenteredWithBgColor($hGui, "and there is no border", 16, 70, 180, 51, 0x00FF00, $ES_CENTER)
Global $Input3 = _CreateInputWithoutBorderAndVerticalCenteredWithBgColor($hGui, "click and press enter", 16, 130, 180, 31, 0x00FFFF, $ES_CENTER)

Global $Input4 = GUICtrlCreateInput("Standard input control", 16, 170, 180, 36, $ES_CENTER)

Global $nTabFix = GUICtrlCreateDummy(), $iDummy_Enter = GUICtrlCreateDummy()
Global $AccelKeys[1][2] = [["{TAB}", $nTabFix]]

GUISetAccelerators($AccelKeys)

ControlFocus($hGui, "", $Input0)
GUICtrlSendMsg($Input0, $EM_SETSEL, 0, -1)

GUISetState(@SW_SHOW)

Global $nMsg, $nFocused

GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $nTabFix
            $nFocused = _WinAPI_GetDlgCtrlID(ControlGetHandle($hGui, "", ControlGetFocus($hGui)))
            Switch $nFocused
                Case $Input0
                    ControlFocus($hGui, "", $Input1)
                    GUICtrlSendMsg($Input1, $EM_SETSEL, 0, -1)
                Case $Input1
                    ControlFocus($hGui, "", $Input2)
                    GUICtrlSendMsg($Input2, $EM_SETSEL, 0, -1)
                Case $Input2
                    ControlFocus($hGui, "", $Input3)
                    GUICtrlSendMsg($Input3, $EM_SETSEL, 0, -1)
                Case $Input3
                    ControlFocus($hGui, "", $Input4)
                    GUICtrlSendMsg($Input4, $EM_SETSEL, 0, -1)
                Case Else
                    GUISetAccelerators(0)
                    Send("{TAB}")
                    GUISetAccelerators($AccelKeys)
            EndSwitch
        Case $GUI_EVENT_CLOSE
            Exit
        Case $iDummy_Enter
            MsgBox(0, "Information", "Call the function now")
    EndSwitch
WEnd

Func WM_COMMAND($hWnd, $iMsg, $iwParam, $ilParam)
    If $iwParam = 1 And GUIGetCursorInfo($hGui)[4] = $Input3 Then GUICtrlSendToDummy($iDummy_Enter)
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

Func _CreateInputWithoutBorderAndVerticalCenteredWithBgColor($hParent, $sText, $iX, $iY, $iW, $iH, $iColor, $iStyle = -1, $iExStyle = 0)
    GUICreate("", $iW, $iH, $iX, $iY, $WS_CHILD, 0, $hParent)
    GUISetBkColor($iColor)
    Local $nInput = GUICtrlCreateInput($sText, 0, $iH / 2 - 6, $iW, 20, $iStyle, $iExStyle)
    GUICtrlSetFont(-1, 12, 200, 0, "Arial", 5)
    GUICtrlSetBkColor(-1, $iColor)
    GUISetState()
    GUISwitch($hParent)
    Return $nInput
EndFunc   ;==>_CreateInputWithoutBorderAndVerticalCenteredWithBgColor

 

It's almost what I need, but this enter is captured only when this input is hovered by mouse in this time. But it's still better than button.
I already did it for Edit control:
 

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>

$GUI = GUICreate("Gui", 400, 100, -1, -1)
GUISetState(@SW_SHOW, $GUI)

$Edit1 = GUICtrlCreateEdit("", 50, 10, 300, 80, BitOR($ES_WANTRETURN,$ES_AUTOVSCROLL) + $WS_VSCROLL)

While 1
    If GUIGetMsg() = -3 Then Exit ; Closing program by X
    If StringInStr(GUICtrlRead($Edit1), @CRLF) Then ; Searching {enter} in string
        GUICtrlSetData($Edit1,StringReplace(GUICtrlRead($Edit1), @CRLF, "")) ; Remove {enter} from string
        calledFunc()
    EndIf
WEnd

Func calledFunc()
    MsgBox(64, "Info", "Enter was pressed.")
EndFunc