gui full screen, but task bar not hide

[Luigi]

Greetings,

I try create a GUI FULL SCREEN in Windows 10, I search many topics, change many Styles and ExStyles, but, always create a GUI, and a Windows task bar is showed.

What I do something wrong?

Someone have a example?

 

[InunoTaishou]

You want to use the $WS_POPUP style and set the width and height to the desktop dimensions

#include <GUIConstants.au3>

Global $hMain = GUICreate("Example", 600, 400, -1, -1, BitOR($WS_MAXIMIZEBOX, $WS_MINIMIZEBOX, $WS_SIZEBOX))
Global $btnFullScreen = GUICtrlCreateButton("Fullscreen", 10, 10, 100, 20)
Global $aGuiStyle = GUIGetStyle($hMain) ; Save the default styles

GUISetState(@SW_SHOW, $hMain)

While (True)
    Switch (GUIGetMsg())
        Case $GUI_EVENT_CLOSE
            Exit 0
        Case $btnFullScreen
            Fullscreen()
    EndSwitch
WEnd

Func Fullscreen()
    Local Static $bFullScreen = False

    $bFullScreen = Not $bFullScreen

    Switch ($bFullScreen)
        Case True
            GUISetStyle($WS_POPUP, -1, $hMain)
            WinMove($hMain, "", 0, 0, @DesktopWidth, @DesktopHeight)
        Case False
            GUISetStyle($aGuiStyle[0], -1, $hMain)
            WinMove($hMain, "", 0, 0, 600, 400)
    EndSwitch
EndFunc

 

Edited December 17, 2016 by InunoTaishou
Forgot to remove an unused include

[Luigi]

@InunoTaishou, thank you, it's work.