Correct syntax of "If NOT"

[leuce]

Hello everyone

In this script:

$selectoption = InputBox ("Select option", "Type 1, 2, 4 or 4", "5")

If NOT $selectoption = "1" Then
If NOT $selectoption = "2" Then
If NOT $selectoption = "3" Then
If NOT $selectoption = "4" Then
MsgBox (0, "Can't read option", "Option should be 1, 2, 3 or 4", 0)
Exit
EndIf
EndIf
EndIf
EndIf

MsgBox (0, "", "Grrr, it didn't work!", 0)

I expect the script to exit at the first MsgBox, if the $selectoption is anything other than 1, 2, 3 or 4 (e.g. if it is "5" or "hello").  But no, the script gives me the second MsgBox.  What am I doing wrong?

Thanks

Samuel

 

Edited December 3, 2016 by leuce

[j0kky]

you lost parentesis, the correct syntax is:

If Not (variable1 = variable2) Then

Instead, if you write:

If Not variable1 = variable2 Then

is equal to:

If (Not variable1) = variable2 Then

Edited December 3, 2016 by j0kky

[leuce]

Thanks, I never knew that I had to use brackts.  It doesn't say so in the help files. :-(

[j0kky]

It's because that's an implicit logical operator rule, just like +-*/ priority in math

[mikell]

Alternative for the nested IFs  

$selectoption = InputBox ("Select option", "Type 1, 2, 3 or 4", "5")

If NOT StringRegExp($selectoption, '^[1234]$') Then _ 
    Exit MsgBox (0, "Can't read option", "Option should be 1, 2, 3 or 4", 0)
MsgBox (0, "", "it worked !", 0)

 

[Jos]

1 hour ago, leuce said:

Thanks, I never knew that I had to use brackts.  It doesn't say so in the help files. :-(

Are you sure about that? Strait from the helpfile:

Quote

Remarks

This version of the If statement is used to execute a single statement without the overhead of an EndIf.
The expression can contain the boolean operators of And, Or, and Not as well as the logical operators <, <=, >, >=, =, ==, and <> grouped with parentheses as needed.

Related

Jos 

[water]

Why do you use an invalid value as default for the InputBox?

$selectoption = Number(InputBox ("Select option", "Type 1, 2, 3 or 4"))
If $selectoption < 1 Or $selectoption > 4 Then MsgBox (0, "Invalid selection", "Option should be 1, 2, 3 or 4")

 

Edited December 3, 2016 by water

[iamtheky]

number like that leaves edge cases for days because of the way it behaves with mixed strings, I would go very literal if you only have 4 options

 

$selectoption = number(InputBox ("Select option", "Type 1, 2, 3 or 4" , "3hello"))
If $selectoption < 1 Or $selectoption > 4 Then MsgBox (0, "Invalid selection", "Option should be 1, 2, 3 or 4")
   
$selectoption = InputBox ("Select option", "Type 1, 2, 3 or 4" , "3hello")
If stringregexp($selectoption , "1/z|2/z|3/z|4/z") = 0 Then MsgBox (0, "Invalid selection", "Option should be 1, 2, 3 or 4")

 

Edited December 3, 2016 by iamtheky

[water]

Enhanced version

$sSelectOption = InputBox("Select option", "Type 1, 2, 3 or 4")
$iSelectOption = Number($sSelectOption)
If StringLen($sSelectOption) <> 1 Or ($iSelectOption < 1 Or $iSelectOption > 4) Then MsgBox(0, "Invalid selection", "Option should be 1, 2, 3 or 4")

 

Edited December 3, 2016 by water

[mikell]

iamtheky,
Your regex example doesn't work for me
Looks like a typo, but if you meant 1\z etc then it allows 51 so it's less precise than  '^[1234]$' 

[iamtheky]

"Pointing out other people's problems with something that has lots of problems itself".  Is my new slogan.

[mikell]

Did you say 'problems' ?

Quote

Some people, when confronted with a problem, think
“I know, I'll use regular expressions.”
Now they have two problems.

[kylomas]

mikell,

You made my night!

[leuce]

19 hours ago, Jos said:

Are you sure about that? Strait from the helpfile:

Jos 

Missed that, sorry.

[leuce]

19 hours ago, water said:

Why do you use an invalid value as default for the InputBox?

$selectoption = Number(InputBox ("Select option", "Type 1, 2, 3 or 4"))
If $selectoption < 1 Or $selectoption > 4 Then MsgBox (0, "Invalid selection", "Option should be 1, 2, 3 or 4")

 

For testing purposes.  The final script will have a valid default value.

[Exit]

my 2 cents

$selectoption = Number(InputBox ("Select option", "Type 1, 2, 3 or 4",""," M1"))
If Not StringInStr("1234",$selectoption) Then MsgBox ("", "Invalid selection", "Option should be 1, 2, 3 or 4")

 

[iamtheky]

combobox would prevent all the additional fun we can have making inputbox do tricks.