Convert VBA Autocad to Autoit

[Danyfirex]

Another alternative to LarsJ's suggestion to avoid DllCallAddress is using ObjCreateInterface where you can set the Method data type so you could pass the pointer to safearray of doubles.

 

Saludos

[mLipok]

@LarsJ thanks for explanation.

@Danyfirex Would you create an example ? That would be quite a landmark achievement.

Edited December 6, 2018 by mLipok

[LarsJ]

Danyfirex, That's not true. Even with ObjCreateInterface it's not possible to tell wether a safearray that's passed as a pointer is a pointer to a safearray of variants or a safearray of doubles. These COM conversion are absolutely the same for both ObjCreate/ObjGet and ObjCreateInterface.

However, I'm unsure whether the COM conversions come into play when the array is transferred as a pointer. Try this

Opt( "MustDeclareVars", 1 )

#include "Variant.au3"
#include "SafeArray.au3"

Example()

Func Example()
  Local $psa, $psaData

  ; Create safearray of doubles with 3 elements
  Local $tsaBound = DllStructCreate( $tagSAFEARRAYBOUND )
  DllStructSetData( $tsaBound, "cElements", 3 )
  DllStructSetData( $tsaBound, "lLbound", 0 )
  $psa = SafeArrayCreate( $VT_R8, 1, $tsaBound )

  ; Store 5.0, 5.0, 0.0 in safearray 
  SafeArrayAccessData( $psa, $psaData )
  DllStructSetData( DllStructCreate( "double", $psaData +  0 ), 1, 5 )
  DllStructSetData( DllStructCreate( "double", $psaData +  8 ), 1, 5 )
  DllStructSetData( DllStructCreate( "double", $psaData + 16 ), 1, 0 )
  SafeArrayUnaccessData( $psa )

  ; Execute method
  ; ... Create object ...
  $oAcad.ActiveDocument.Modelspace.AddPoint( $psa )
EndFunc

VariantsAndSafearrays.7z

Edited December 6, 2018 by LarsJ

[Danyfirex]

@LarsJ I mean something like overwrite the object methods types.

 

This is not a working script but it shows what I mean.

Global Const $sIID_IModelSpace = "{E1E8DC11-DBAF-46E4-978B-06856A0FCF66}"
Global Const $sTagIModelSpace = "Method hresult(ptr); Method hresult(ptr);AddPoint hresult(ptr)"

Local $psa, $psaData

; Create safearray of doubles with 3 elements
Local $tsaBound = DllStructCreate($tagSAFEARRAYBOUND)
DllStructSetData($tsaBound, "cElements", 3)
DllStructSetData($tsaBound, "lLbound", 0)
$psa = SafeArrayCreate($VT_R8, 1, $tsaBound)

; Store 5.0, 5.0, 0.0 in safearray
SafeArrayAccessData($psa, $psaData)
DllStructSetData(DllStructCreate("double", $psaData + 0), 1, 5)
DllStructSetData(DllStructCreate("double", $psaData + 8), 1, 5)
DllStructSetData(DllStructCreate("double", $psaData + 16), 1, 0)
SafeArrayUnaccessData($psa)

Local $oAcad = ObjGet("", "AutoCAD.Application")
Local $oModelSpance = $oAcad.ActiveDocument.Modelspace

$oNewModelSpance = ObjCreateInterface($oModelSpance, $sIID_IModelSpace, $sTagIModelSpace)

$oNewModelSpance.AddPoint($psa)

 

 

I'm unable to load the code beautifier feature(due to my slow internet connection). I'm sorry.

 

Saludos

 

 

 

 

 

 

[VAN0]

@LarsJ unfortunately same error

[LarsJ]

One last attempt. let's try to store the safearray in a variant of type $VT_ARRAY + $VT_R8 before it's passed to the method:

Opt( "MustDeclareVars", 1 )

#include "Variant.au3"
#include "SafeArray.au3"

Example()

Func Example()
  Local $psa, $psaData

  ; Create safearray of doubles with 3 elements
  Local $tsaBound = DllStructCreate( $tagSAFEARRAYBOUND )
  DllStructSetData( $tsaBound, "cElements", 3 )
  DllStructSetData( $tsaBound, "lLbound", 0 )
  $psa = SafeArrayCreate( $VT_R8, 1, $tsaBound )

  ; Store 5.0, 5.0, 0.0 in safearray 
  SafeArrayAccessData( $psa, $psaData )
  DllStructSetData( DllStructCreate( "double", $psaData +  0 ), 1, 5 )
  DllStructSetData( DllStructCreate( "double", $psaData +  8 ), 1, 5 )
  DllStructSetData( DllStructCreate( "double", $psaData + 16 ), 1, 0 )
  SafeArrayUnaccessData( $psa )

  ; Store safearray in variant of type $VT_ARRAY + $VT_R8
  Local $tVar = DllStructCreate( $tagVARIANT )
  Local $pVar = DllStructGetPtr( $tVar )
  Local $tvt = DllStructCreate( "word", $pVar )
  DllStructSetData( $tvt, 1, $VT_ARRAY + $VT_R8 )
  Local $tData = DllStructCreate( "ptr", $pVar + 8 )
  DllStructSetData( $tData, 1, $psa )

  ; Execute method
  ; ... Create object ...
  $oAcad.ActiveDocument.Modelspace.AddPoint( $pVar )
EndFunc

 

[VAN0]

Same error " Exception occurred. "

[LarsJ]

I have no more ideas. I think the easiest way to go on is to use VBA code.

[Danyfirex]

I was reading about Autocad and you can use SendCommand.

Local $oAcad = ObjGet("", "AutoCAD.Application.20")

Local $iX = 0
Local $iY = 0
Local $sCommand = ""
For $i = 1 To 100
    $iX = $i * 0.1
    $iY = $i * 0.1
    $sCommand = "Point " & $iX & "," & $iY & ",0" & @CR
    $oAcad.ActiveDocument.SendCommand($sCommand)
Next

$oAcad.ActiveDocument.SendCommand("-Text 10,10,0" & @CR  & "0.5" &  @CR & "45" & @CR & "AutoIt Lovers" & @CR )
$oAcad.ActiveDocument.SendCommand("-MText 10,5,0" & @CR  & "0.5" &   @CR & "AutoIt"  & @CR & "Rocks" & @CR & @CR )

Saludos

[VAN0]

Awesome! Thank you, works great.

 

Just a note in case someone is using different version of AutoCAD, in Danyfirex's example the number 20 in

Local $oAcad = ObjGet("", "AutoCAD.Application.20")

represent AutoCAD 2015/2016, removing it will make the script version independent.

Local $oAcad = ObjGet("", "AutoCAD.Application")

 

[Danyfirex]

Hello Again. After a lot a reasearch here is a working example of the solution that I suggested here.

@mLipok @LarsJ This is what I was talking about...

 

expandcollapse popup

#include "Variant.au3"
#include "SafeArray.au3"


Global Const $sIID_IModelSpace = "{E1E8DC11-DBAF-46E4-978B-06856A0FCF66}"

Global $sTagIModelSpace = ""
;Build Dummy Interface Methods
For $i = 1 To 47
    $sTagIModelSpace &= "Method" & $i & " hresult();"
Next
;Append AddPoint Method
$sTagIModelSpace &= "AddPoint hresult(struct;ptr*);"


Local $oErrorHandler = ObjEvent("AutoIt.Error", "_ErrFunc")
Local $oAcad = ObjGet("", "AutoCAD.Application.20")

If IsObj($oAcad) Then
    ConsoleWrite("IsObj($oAcad): " & IsObj($oAcad) & @CRLF)
    Local $oNewModelSpace = ObjCreateInterface($oAcad.ActiveDocument.Modelspace, $sIID_IModelSpace, $sTagIModelSpace)
    If IsObj($oNewModelSpace) Then
        ConsoleWrite("IsObj($oNewModelSpace): " & IsObj($oNewModelSpace) & @CRLF)
        Local $psa, $psaData
        ; Create safearray of doubles with 3 elements
        Local $tsaBound = DllStructCreate($tagSAFEARRAYBOUND)
        DllStructSetData($tsaBound, "cElements", 3)
        DllStructSetData($tsaBound, "lLbound", 0)
        $psa = SafeArrayCreate($VT_R8, 1, $tsaBound)

        Local $tSafeArray = DllStructCreate($tagSAFEARRAY, $psa)

;~ ; Store 5.0, 5.0, 0.0 in safearray
        SafeArrayAccessData($psa, $psaData)
        DllStructSetData(DllStructCreate("double", $psaData + 0), 1, 5.0)
        DllStructSetData(DllStructCreate("double", $psaData + 8), 1, 5.0)
        DllStructSetData(DllStructCreate("double", $psaData + 16), 1, 0.0)
        SafeArrayUnaccessData($psa)

        ; Store safearray in variant of type $VT_ARRAY + $VT_R8
        Local $tVar = DllStructCreate($tagVARIANT)
        Local $pVar = DllStructGetPtr($tVar)
        DllCall("OleAut32.dll", "none", "VariantInit", "ptr", $pVar)
        Local $tvt = DllStructCreate("word", $pVar)
        DllStructSetData($tvt, 1, $VT_ARRAY + $VT_R8)
        Local $tData = DllStructCreate("ptr", $pVar + 8)
        DllStructSetData($tData, 1, $psa)

        Local $pIAcadPoint = 0
        $oNewModelSpace.AddPoint($tVar, $pIAcadPoint)
        ConsoleWrite("$pIAcadPoint: " & $pIAcadPoint & @CRLF)
    EndIf

EndIf

Exit


; User's COM error function. Will be called if COM error occurs
Func _ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc

A bunch of thanks to trancexx for helping me to solve this.

 

Saludos

 

 

 

[LarsJ]

We have known this since 2014 as described here.

Does the code work as 64 bit code? I doubt. Also described here.

[Danyfirex]

LarsJ I just wanted to point that It was possible to solve this using my suggestion here.

To make it work in x64 and x86 version just need to change this:

 

$sTagIModelSpace &= "AddPoint hresult(struct;ptr*);"

by this:

$sTagIModelSpace &= "AddPoint hresult(struct" & (@AutoItX64 ? "*" : "") & ";ptr*);"

 

Saludos

 

[LarsJ]

Your suggestion is exactly what was done in 2014. Changing the method parameter data types. Nothing new.

[Danyfirex]

Probably I did not explain me well or you did not understand me. anyway forget it. 

 

Saludos