Adding Images to Tab

[aa2zz6]

How would I add a image to a tab?  

expandcollapse popup

#include <GUIConstants.au3>

Local $htab, $iCombo

$hGUI = GUICreate("Built-In Tab Example", 705, 369)
GUISetBkColor(0xFFFFFF)

$hTab = GUICtrlCreateTab(172 + 4, 10 + 4, 523 - 8, 300 - 8)

; Create tabitems
For $i = 0 To 5

    If $i = 0 Then
        GUICtrlCreateTabItem("Tab 0")
        ;GUICtrlSetImage(-1, "shell32.dll", -6, 0)
        GUICtrlSetImage(-1, @ScriptDir & "\Images\Test.png")
        GUICtrlSetState(-1, $GUI_SHOW)
        GUICtrlCreateLabel("Sel. Style", 20, 325, 250, 17)
        $iCombo = GUICtrlCreateCombo("", 20, 340, 310, 120)
        GUICtrlSetData(-1, "$GUI_SS_DEFAULT_TAB|$TCS_FIXEDWIDTH|$TCS_FIXEDWIDTH+$TCS_FORCEICONLEFT|$TCS_FIXEDWIDTH+$TCS_FORCELABELLEFT|$TCS_BOTTOM", "$GUI_SS_DEFAULT_TAB")
    EndIf

    If $i = 1 Then
        GUICtrlCreateTabItem("Tab 1")
    EndIf

    If $i = 2 Then
        GUICtrlCreateTabItem("Tab 2")
    EndIf

    If $i = 3 Then
        GUICtrlCreateTabItem("Tab3")
    EndIf

    If $i = 4 Then
        GUICtrlCreateTabItem("Tab4")
    EndIf

    ;GUICtrlCreateButton("Button " & $i, 20 + ($i * 100), 40 + ($i * 50), 80, 30)
Next
; Close Tab definiton
GUICtrlCreateTabItem("")

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $iCombo
            GUICtrlSetStyle($htab, BitOR($GUI_SS_DEFAULT_TAB, Execute(GUICtrlRead($iCombo))))
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

 

[InunoTaishou]

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTab.au3>
#include <WinAPI.au3>
#include <GDIPlus.au3>

Example()

Func Example()
    _GDIPlus_Startup()

    Local $hGUI = GUICreate("Tab Control Set Item Image", 400, 300)
    Local $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    Local $hImageList = _GUIImageList_Create(50, 20)
    Local $aImages[4]
    
    For $i = 0 To 3
        ; Load the GDI+ bitmap
        Local $hBitmapTmp = _GDIPlus_BitmapCreateFromFile("Tab" & $i & ".jpg")
        ; Conver the GDI+ bitmap to a HBitmap
        $aImages[$i] = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmapTmp)
        ; Get rid of the GDI+ bitmap
        _GDIPlus_BitmapDispose($hBitmapTmp)
        ; Add the HBitmap to the image list
        _GUIImageList_Add($hImageList, $aImages[$i])
    Next
    
    _GUICtrlTab_SetImageList($idTab, $hImageList)
    For $i = 0 To 3
        _GUICtrlTab_InsertItem($idTab, $i, "")
        _GUICtrlTab_SetItemImage($idTab, $i, $i)
    Next

    GUISetState(@SW_SHOW)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
    
    ; Dispose of the HBitmap objects properly
    For $i = 0 To 3
        _WinAPI_DeleteObject($aImages[$i])
    Next
EndFunc   ;==>Example

 

[aa2zz6]

To be honest I haven't worked with _GDIPlus_BitmapCreateFromFile but wouldn't the directory reference be something like below?

Local $hBitmapTmp = _GDIPlus_BitmapCreateFromFile(@MyDocumentsDir & "\Tab 1.png")

Edit: This brings up the image. I guess I'll revise my script so each tab has a different image.

Thanks man

Local $hBitmapTmp = _GDIPlus_BitmapCreateFromFile(@ScriptDir & "\test.bmp")

 

Edited November 17, 2016 by aa2zz6

[mLipok]

@aa2zz6 look here: