[Solved] Reading ExitCode of runned CMD program.

[iXX]

Hello!

I need to run cmd line program and if it is running longer than defined time, kill it.

I have it done by this script.

But I dont know how to add next feature:  If the program ends in-time, then read its Exit Code (It should be number from 0 to 255).

PLS can anyone help?

If FileChangeDir("C:\X") <> 1 Then Exit
$PID = Run('"C:\Program Files\WinRAR\Rar.exe" A -TS -T "C:\X\Archive.RAR" *', "", @SW_HIDE)
If @Error <> 0 Then Exit
$C = TimerInit()
While 1
   Sleep(250)
   If ProcessExists($PID) = 0 Then ExitLoop
   If TimerDiff($C) > 10000 Then
      RunWait("TaskKill /F /PID " & $PID, "", @SW_HIDE)
   EndIf
WEnd
$ExitCode = ""   ; ???? HOW-TO?

 

Edited November 3, 2016 by iXX
Solved.

[iXX]

I know, for return exit code of program normally works RunWait, but in this case, how to program the timeout?

If the program hangs or something, RunWait will wait forever...

[BrewManNH]

Try here, might need some tweaking to work with newer versions.

 

 

[Gianni]

you should redirect the output stream of rar.exe to your script, so to catch the output,
2 changes in you script are needed:
1) setup the redirection stream to your script within the "run()" command
2) read the output stream to get rar.exe output...
following script should do what you need

#include <AutoItConstants.au3>
If FileChangeDir("C:\X") <> 1 Then Exit
$PID = Run('"C:\Program Files\WinRAR\Rar.exe" A -TS -T "C:\X\Archive.RAR" *', "", @SW_HIDE, $STDERR_MERGED)
If @error <> 0 Then Exit
$C = TimerInit()
While 1
    Sleep(250)
    If ProcessExists($PID) = 0 Then ExitLoop
    If TimerDiff($C) > 10000 Then
        RunWait("TaskKill /F /PID " & $PID, "", @SW_HIDE)
    EndIf
WEnd
$ExitCode = StdoutRead($PID) ; ???? HOW-TO?

ConsoleWrite($ExitCode & @CRLF)

 

[iXX]

Just tryed, but while RunWait returns just needed ExitCode number, the edited script above pukes text of rar's progress....

 

[Gianni]

maybe something like this...

; example from this post by @funkey:
; https://www.autoitscript.com/forum/topic/152133-run-runwait-and-exit-codes/?do=findComment&comment=1091035

#include <ProcessConstants.au3>
#include <WinAPIProc.au3>
#include <WinAPISys.au3>

Local $sCmd = '"C:\Program Files\WinRAR\Rar.exe" A -TS -T "C:\X\Archive.RAR" *'

If FileChangeDir("C:\X") <> 1 Then Exit

AdlibRegister("Timeout", 10000) ; max allowed 10 seconds

Global $iPID = Run($sCmd, "", @SW_HIDE)
If Not $iPID Then Exit

Global $hProcess
If _WinAPI_GetVersion() >= 6.0 Then
    $hProcess = _WinAPI_OpenProcess($PROCESS_QUERY_LIMITED_INFORMATION, 0, $iPID)
Else
    $hProcess = _WinAPI_OpenProcess($PROCESS_QUERY_INFORMATION, 0, $iPID)
EndIf
If Not $hProcess Then Exit
ProcessWaitClose($iPID)
Global $ExitCode = DllCall("kernel32.dll", "bool", "GetExitCodeProcess", "HANDLE", $hProcess, "dword*", -1)
_WinAPI_CloseHandle($hProcess)
ConsoleWrite("Exit code: " & $ExitCode[2] & @LF)

Func Timeout()
    RunWait("TaskKill /F /PID " & $iPID, "", @SW_HIDE)
EndFunc   ;==>Timeout

 

Edited November 3, 2016 by Chimp
added _WinAPI_CloseHandle in code

[iXX]

Yes, this works!

Thank You very much!!