Extract String

[Queener]

I'm not sure about how to do this. Can someone help? I have long list that piped and each of the line, I only want the string within the second and third piper. For example:

ID:9999 | James Crawler | Data Entry | Age: 19 | MTWTF|RM101

I only want to extract the James Crawler and leave out the rest.

 

 

[AutoBert]

One of possible solutions:

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

$sData='ID:9999 | James Crawler | Data Entry | Age: 19 | MTWTF|RM101'
$aSplit=StringSplit($sData,'|', $STR_NOCOUNT)

MsgBox($MB_ICONINFORMATION,'Wanted:',$aSplit[1])

 

[Queener]

Thank you so much, I did find another way, but I like yours.

 

;Variables to locate the right columns
$SearchString = GUICtrlRead(GUICtrlRead($List_Status))
$SearchString = _StringBetween($SearchString, "|", "|")
$SearchString = $SearchString[0]

[Gianni]

Another possible solution (... a tribute to Rube Goldberg )

Local $sData = 'ID:9999 | James Crawler | Data Entry | Age: 19 | Rube Goldberg | MTWTF|RM101'

Local $iItem = 5 ; wanted item
Local $SearchString = StringMid($sData, StringInStr($sData, '|', 0, $iItem - 1) + 1, StringInStr($sData, '|', 0, $iItem) - (StringInStr($sData, '|', 0, $iItem - 1) + 1))

MsgBox(0, "Debug", $SearchString)

 

[ThioFoX]

Alternatives:

$sText = "ID:9999 | James Crawler | Data Entry | Age: 19 | MTWTF|RM101 "
$aExtract = StringRegExp($sText, "(.*?)\|", 3)
MsgBox(4096, "", $aExtract[1])

$sExtract = StringRegExpReplace($sText, "^.*?\|(.*?)\|.*$", "$1")
MsgBox(4096, "", $sExtract)

 

[jguinch]

Another one :

$string = "ID:9999 | James Crawler | Data Entry | Age: 19 | MTWTF|RM101"
$extract = StringRegExpReplace($string, "^[^|]*\|\h*|\h*\|\N*", "")
ConsoleWrite($extract)

 

[mikell]

$string = "ID:9999 | James Crawler | Data Entry | Age: 19 | MTWTF|RM101"
$extract = StringRegExpReplace($string, "^[^|]*\|([^|]*).*", "$1")
ConsoleWrite($extract)

[Jfish]

The other solutions are better but just tossing the trimming concept out there as well ... 

$string = "ID:9999 | James Crawler | Data Entry | Age: 19 | MTWTF|RM101"
$extractLeft=stringtrimleft($string,StringInStr($string,"|"))
$extractRight=StringTrimRight($extractLeft,stringlen($extractLeft)-StringInStr($extractLeft,"|")+1)
ConsoleWrite($extractRight&@crlf)