Ghost Interface

[Adele]

I'm trying to make an always on top interface showing informations on an edge of desktop. I'd like that it doesn't disturb the user, so when the user moved cursor over the transparent interface, the cursor should be detected by the bottom window like the interface never exist. Good day.

Edited September 28, 2016 by Adele

[JLogan3o13]

@Adele that is a great explanation of what you want. Now, how about what you have tried? There are functions in the help file for making a GUI always on top, as well as transparency. Why don't you post what you have tried on your own, and where you're stuck?

[Adele]

If you aren't kidding me, it's good to hear that I've explained good, I hadn't thought that my English was enough.

I need just help about to make detecting cursor by the bottom window when cursor was moved over the window. I know things like using gui, transparency.

Edited September 29, 2016 by Adele

[UEZ]

Check out 4th return array value of 

GUIGetCursorInfo

 

Edited September 29, 2016 by UEZ

[Adele]

@UEZ I've looked it, it isn't actually relevant to that I want but it has given me an idea. I will use that on smartboard (so it is used with touch panel). When a user clicked point where does the interface exist, the script will get cursor's coordinates and quickly click the actual location over bottom window hiding itself. I would want to make that without hiding quickly the interface but it isn't a badly needed. Maybe if I would use that on desktop... If someone has still idea about how can we do that please let them share.

Edited September 30, 2016 by Adele

[UEZ]

Something like this here?

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>

Global $hGUI = GUICreate("Ghost", 100, 50, @DesktopWidth - 100, 0, $WS_POPUP, $WS_EX_TOPMOST)
GUISetBkColor(0x808080)
Global $iLbl = GUICtrlCreateLabel("Hover me :-)", 10, 10)
GUICtrlSetColor(-1, 0xFFFFFF)
GUISetState()

AdlibRegister("HoverChk", 50)
Do
Until GUIGetMsg() = -3
AdlibUnRegister("HoverChk")
GUIDelete()


Func HoverChk()
    Local $iFadeIn = 8, $iFadeOut = 64
    Local Static $iTransparency = 255
    Local $aPos = WinGetPos($hGUI)
    If _WinAPI_PtInRectEx(MouseGetPos(0), MouseGetPos(1), $aPos[0], $aPos[1], $aPos[2] + $aPos[0] + 1, $aPos[3] + $aPos[1] + 1) Then
        If $iTransparency >= 0 Then
            $iTransparency -= $iFadeOut
            $iTransparency = $iTransparency < 0 ? 0 : $iTransparency
            WinSetTrans($hGUI, "", $iTransparency)
        EndIf
    Else
        If $iTransparency <= 255 Then
            $iTransparency += $iFadeIn
            $iTransparency = $iTransparency > 255 ? 255 : $iTransparency
            WinSetTrans($hGUI, "", $iTransparency)
        EndIf
    EndIf
EndFunc

 

[Scrappy53]

On 30.09.2016 at 7:42 PM, UEZ said:

Something like this here?

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>

Global $hGUI = GUICreate("Ghost", 100, 50, @DesktopWidth - 100, 0, $WS_POPUP, $WS_EX_TOPMOST)
GUISetBkColor(0x808080)
Global $iLbl = GUICtrlCreateLabel("Hover me :-)", 10, 10)
GUICtrlSetColor(-1, 0xFFFFFF)
GUISetState()

AdlibRegister("HoverChk", 50)
Do
Until GUIGetMsg() = -3
AdlibUnRegister("HoverChk")
GUIDelete()


Func HoverChk()
    Local $iFadeIn = 8, $iFadeOut = 64
    Local Static $iTransparency = 255
    Local $aPos = WinGetPos($hGUI)
    If _WinAPI_PtInRectEx(MouseGetPos(0), MouseGetPos(1), $aPos[0], $aPos[1], $aPos[2] + $aPos[0] + 1, $aPos[3] + $aPos[1] + 1) Then
        If $iTransparency >= 0 Then
            $iTransparency -= $iFadeOut
            $iTransparency = $iTransparency < 0 ? 0 : $iTransparency
            WinSetTrans($hGUI, "", $iTransparency)
        EndIf
    Else
        If $iTransparency <= 255 Then
            $iTransparency += $iFadeIn
            $iTransparency = $iTransparency > 255 ? 255 : $iTransparency
            WinSetTrans($hGUI, "", $iTransparency)
        EndIf
    EndIf
EndFunc

 

Is it possible to make it completely transparent instead of trying to hide a little?

[UEZ]

On 12/16/2016 at 5:50 PM, Scrappy53 said:

Is it possible to make it completely transparent instead of trying to hide a little?

I do not understand what you mean!

[Scrappy53]

I actually want the same thing on the first post.

Edited December 17, 2016 by Scrappy53

[Scrappy53]

I've recorded a video to show what i want. There is a running window as you see and despite I can do something on desktop like there isn't any window.

 

 

[UEZ]

If I understand you correctly, try this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>

Global $hGUI = GUICreate("Ghost", 200, 100, @DesktopWidth - 210, 10, $WS_POPUP, BitOR($WS_EX_TOPMOST, $WS_EX_TRANSPARENT))
GUISetBkColor(0x808080)
Global $iLbl = GUICtrlCreateLabel("Hover me :-)", 10, 10, 180, 80, BitOR($SS_CENTERIMAGE, $SS_CENTER))
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetFont(-1, 24)
GUISetState()

Global $iMin = 64

AdlibRegister("HoverChk", 50)
Do
Until GUIGetMsg() = -3
AdlibUnRegister("HoverChk")
GUIDelete()


Func HoverChk()
    Local $iFadeIn = 8, $iFadeOut = 64
    Local Static $iTransparency = 255
    Local $aPos = WinGetPos($hGUI)
    If _WinAPI_PtInRectEx(MouseGetPos(0), MouseGetPos(1), $aPos[0], $aPos[1], $aPos[2] + $aPos[0] + 1, $aPos[3] + $aPos[1] + 1) Then
        If $iTransparency >= $iMin Then
            $iTransparency -= $iFadeOut
            $iTransparency = ($iTransparency < $iMin) ? $iMin : $iTransparency
            WinSetTrans($hGUI, "", $iTransparency)
        EndIf
    Else
        If $iTransparency <= 255 Then
            $iTransparency += $iFadeIn
            $iTransparency = ($iTransparency > 255) ? 255 : $iTransparency
            WinSetTrans($hGUI, "", $iTransparency)
        EndIf
    EndIf
EndFunc

 

[Alenis]

17 hours ago, UEZ said:

If I understand you correctly, try this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <WinAPIGdi.au3>

Global $hGUI = GUICreate("Ghost", 200, 100, @DesktopWidth - 210, 10, $WS_POPUP, BitOR($WS_EX_TOPMOST, $WS_EX_TRANSPARENT))
GUISetBkColor(0x808080)
Global $iLbl = GUICtrlCreateLabel("Hover me :-)", 10, 10, 180, 80, BitOR($SS_CENTERIMAGE, $SS_CENTER))
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetFont(-1, 24)
GUISetState()

Global $iMin = 64

AdlibRegister("HoverChk", 50)
Do
Until GUIGetMsg() = -3
AdlibUnRegister("HoverChk")
GUIDelete()


Func HoverChk()
    Local $iFadeIn = 8, $iFadeOut = 64
    Local Static $iTransparency = 255
    Local $aPos = WinGetPos($hGUI)
    If _WinAPI_PtInRectEx(MouseGetPos(0), MouseGetPos(1), $aPos[0], $aPos[1], $aPos[2] + $aPos[0] + 1, $aPos[3] + $aPos[1] + 1) Then
        If $iTransparency >= $iMin Then
            $iTransparency -= $iFadeOut
            $iTransparency = ($iTransparency < $iMin) ? $iMin : $iTransparency
            WinSetTrans($hGUI, "", $iTransparency)
        EndIf
    Else
        If $iTransparency <= 255 Then
            $iTransparency += $iFadeIn
            $iTransparency = ($iTransparency > 255) ? 255 : $iTransparency
            WinSetTrans($hGUI, "", $iTransparency)
        EndIf
    EndIf
EndFunc

 

 

@EUZ Thanks again, I start to have a issue to generate a similar UI and you already have an answer, your UI magic is always welcome.