_WinAPI_MarkScreenRegionAndCapture 0.92 build 2017-01-22

[UEZ]

Here a small function to mark a region on the desktop and capture that region to a bitmap handle or to the clipboard:

expandcollapse popup

#include-once
#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIGdi.au3>
#include <WindowsConstants.au3>

#Region Example
;capture manual coordinates
FileDelete(@ScriptDir & "\Captured.bmp")
Global $hHBitmap = _WinAPI_MarkScreenRegionAndCapture(0, False, True, 0, 0, 99, 99)
_WinAPI_SaveHBITMAPToFile(@ScriptDir & "\Captured.bmp", $hHBitmap)
_WinAPI_DeleteObject($hHBitmap)
If FileExists(@ScriptDir & "\Captured.bmp") Then ShellExecute(@ScriptDir & "\Captured.bmp")

;save the captured bitmap to a file
FileDelete(@ScriptDir & "\Captured.bmp")
Global $hHBitmap = _WinAPI_MarkScreenRegionAndCapture()
_WinAPI_SaveHBITMAPToFile(@ScriptDir & "\Captured.bmp", $hHBitmap)
_WinAPI_DeleteObject($hHBitmap)
If FileExists(@ScriptDir & "\Captured.bmp") Then ShellExecute(@ScriptDir & "\Captured.bmp")


;copy captured bitmap to clipboard
Switch _WinAPI_MarkScreenRegionAndCapture(1, True)
    Case 1
        MsgBox($MB_ICONINFORMATION, "Information", "Marked region was properly captured to clipboard!", 30)
    Case 0
        MsgBox($MB_ICONERROR, "ERROR", "An error has occured!", 30)
EndSwitch
#EndRegion

; #FUNCTION# ====================================================================================================================
; Name ..........: _WinAPI_MarkScreenRegionAndCapture
; Description ...: Selected area on desktop will be captured and save to clipbord or GDI bitmap handle will be returned.
; Syntax ........: _WinAPI_MarkScreenRegionAndCapture([$iFillMode = 0[, $bClipboard = True]])
; Parameters ....: $iFillMode           - [optional] an integer value. Default is 0.
;                                           0: marked area filled with solid color
;                                           1: marked area filled with hatch pattern ($HS_DIAGCROSS)
;                                           2: marked area without any fill pattern / color - only red border
;                  $bClipboard          - [optional] a boolean value. Default is False. If True then no GDI bitmap handle will be returned.
;                                         If false then GDI bitmap handle will be returned.
;                  $bManual             - [optional] a boolean value. Default is False. If True manual capturing is activated.
;                  $iX1                 - [optional] an integer value. Default is 0. If $bManual is true enter the x1 screen pos.
;                  $iY1                 - [optional] an integer value. Default is 0. If $bManual is true enter the Y1 screen pos.
;                  $iX2                 - [optional] an integer value. Default is 0. If $bManual is true enter the x2 screen pos.
;                  $iY2                 - [optional] an integer value. Default is 0. If $bManual is true enter the y2 screen pos.
; Return values .: 0 / 1 / -1 / GDI bitmap handle
; Author ........: UEZ
; Version .......: 0.92 build 2017-01-22
; Modified ......:
; Remarks .......: Do not forget to dispose returned GDI bitmap handle for non clipboard mode using _WinAPI_DeleteObject!
; Related .......:
; Link ..........:
; Example .......: Yes
; ===============================================================================================================================
Func _WinAPI_MarkScreenRegionAndCapture($iFillMode = 0, $bClipboard = False, $bManual = False, $iX1 = 0, $iY1 = 0, $iX2 = 0, $iY2 = 0)
    If @OSBuild > 6299 Then ;https://msdn.microsoft.com/en-us/library/windows/desktop/ms724832(v=vs.85).aspx
        DllCall("Shcore.dll", "long", "PROCESS_DPI_AWARENESS", 1) ;PROCESS_SYSTEM_DPI_AWARE = 1 (https://msdn.microsoft.com/en-us/library/windows/desktop/dn280512(v=vs.85).aspx)
    Else
        DllCall("User32.dll", "bool", "SetProcessDPIAware")
    EndIf
    Local $iOld = AutoItSetOption("MouseCoordMode", 1)
    If Not $bManual Then
        Local Const $hDesktop = WinGetHandle("[TITLE:Program Manager;CLASS:Progman]")
        Local Const $aFullScreen = WinGetPos($hDesktop) ;should work also on multi screens
        Local Const $iW = $aFullScreen[2], $iH = $aFullScreen[3]
        Local Const $hGUI_Screencapture = GUICreate("", $iW, $iH, $aFullScreen[0], $aFullScreen[1], $WS_POPUP, BitOR($WS_EX_TOPMOST, $WS_EX_LAYERED))
        GUISetState(@SW_SHOW, $hGUI_Screencapture)
        Local Const $hDC = _WinAPI_GetDC($hGUI_Screencapture)
        Local Const $hGfxDC = _WinAPI_CreateCompatibleDC($hDC)
        Local Const $hBitmapGDI = _WinAPI_CreateCompatibleBitmap($hDC, $iW, $iH)
        Local $hObjOld = _WinAPI_SelectObject($hGfxDC, $hBitmapGDI)
        Local $tSize = DllStructCreate($tagSIZE)
        $tSize.x = $iW
        $tSize.y = $iH
        Local $tSource = DllStructCreate($tagPOINT)
        Local $tBlend = DllStructCreate($tagBLENDFUNCTION)
        $tBlend.Alpha = 0xFF
        $tBlend.Format = 1
        Local $tDest = DllStructCreate($tagPOINT), $pPoint = DllStructGetPtr($tDest)
        $tDest.x = $aFullScreen[0]
        $tDest.y = $aFullScreen[1]

        Local Const $hPen = _WinAPI_CreatePen($PS_SOLID, 1, 0x0000FF)
        Local Const $hPen_Orig = _WinAPI_SelectObject($hGfxDC, $hPen)
        Local $hBrush, $iAlpha2, $iFlag
        $iFillMode = $iFillMode > 2 ? 2 : $iFillMode < 0 ? 0 : $iFillMode
        Switch $iFillMode
            Case 0
                $hBrush = _WinAPI_CreateBrushIndirect($BS_SOLID, 0x808080)
                $iAlpha2 = 0xA0
                $iFlag = $ULW_ALPHA
            Case 1
                $hBrush = _WinAPI_CreateBrushIndirect($BS_HATCHED, 0x808000, $HS_DIAGCROSS)
                $iAlpha2 = 0x30
                $iFlag = $ULW_ALPHA
            Case 2
                $hBrush = _WinAPI_CreateBrushIndirect($BS_HOLLOW, 0x000000)
                $iAlpha2 = 0xFF ;not needed
                $iFlag = $ULW_COLORKEY
        EndSwitch

        Local $hBrush_Orig = _WinAPI_SelectObject($hGfxDC, $hBrush)
    Else
        If Not BitOr($iX1, $iX2, $iY1, $iY2) Then Return SetError(4, 0, 0)
    EndIf
    Local $aMPos[5], $aMPos_old[4], $tRECT = _WinAPI_CreateRect(0, 0, 0, 0)
    Do
        If $bManual Then
            $aMPos[2] = 1
        Else
            GUISetCursor(16, 1, $hGUI_Screencapture)
            $aMPos = GUIGetCursorInfo($hGUI_Screencapture)
            $aMPos_old[0] = $aMPos[0]
            $aMPos_old[1] = $aMPos[1]
            $aMPos_old[2] = MouseGetPos(0)
            $aMPos_old[3] = MouseGetPos(1)
        EndIf
        Switch $aMPos[2]
            Case 0 ;display crosshair
                _WinAPI_BitBlt($hGfxDC, 0, 0, $iW, $iH, $hGfxDC, 0, 0, $CAPTUREBLT)
                _WinAPI_DrawLine($hGfxDC, $tDest.x, $aMPos[1], $iW, $aMPos[1])
                _WinAPI_DrawLine($hGfxDC, $aMPos[0], $tDest.y, $aMPos[0], $iH)
                _WinAPI_UpdateLayeredWindow($hGUI_Screencapture, $hDC, $tDest, $tSize, $hGfxDC, $tSource, 0, $tBlend, $ULW_COLORKEY)
            Case 1 ;capture selected region
                If Not $bManual Then
                    $tBlend.Alpha = $iAlpha2
                    While $aMPos[2] ;mark region
                        GUISetCursor(14, 1, $hGUI_Screencapture) ;WinGetHandle(AutoItWinGetTitle()))
                        $aMPos = GUIGetCursorInfo($hGUI_Screencapture)
                        _WinAPI_BitBlt($hGfxDC, 0, 0, $iW, $iH, $hGfxDC, 0, 0, $CAPTUREBLT) ;clear bitmap

                        ;draw rectangle
                        $tRECT.Left = $aMPos_old[0]
                        $tRECT.Top = $aMPos_old[1]
                        $tRECT.Right = $aMPos[0]
                        $tRECT.Bottom = $aMPos[1]
                        _WinAPI_Rectangle($hGfxDC, $tRECT)
                        If $iFillMode <> 2 Then _WinAPI_InvertRect($hGfxDC, $tRECT)
                        _WinAPI_UpdateLayeredWindow($hGUI_Screencapture, $hDC, $tDest, $tSize, $hGfxDC, $tSource, 0, $tBlend, $iFlag)
                        Sleep(10)
                    WEnd
                    _WinAPI_SelectObject($hGfxDC, $hObjOld)
                    _WinAPI_ReleaseDC($hGUI_Screencapture, $hDC)
                    _WinAPI_DeleteDC($hGfxDC)
                    _WinAPI_DeleteObject($hBitmapGDI)
                    _WinAPI_SelectObject($hGfxDC, $hPen_Orig)
                    _WinAPI_DeleteObject($hPen)
                    _WinAPI_SelectObject($hGfxDC, $hBrush_Orig)
                    _WinAPI_DeleteObject($hBrush)
                    GUIDelete($hGUI_Screencapture)
                    ;capture region
                    $aMPos[0] = MouseGetPos(0)
                    $aMPos[1] = MouseGetPos(1)
                Else
                    $aMPos_old[2] = $iX1
                    $aMPos_old[3] = $iY1
                    $aMPos[0] = $iX2
                    $aMPos[1] = $iY2
                EndIf

                Local Const $hDC_Region = _WinAPI_GetDC(0)
                Local Const $hMemDC = _WinAPI_CreateCompatibleDC($hDC_Region)
                Local Const $iW_Region = Abs($aMPos[0] - $aMPos_old[2]) + 1, $iH_Region = Abs($aMPos[1] - $aMPos_old[3]) + 1
                Local $hHBitmap_Captured = _WinAPI_CreateCompatibleBitmap($hDC_Region, $iW_Region, $iH_Region)
                $hObjOld = _WinAPI_SelectObject($hMemDC, $hHBitmap_Captured)
                _WinAPI_BitBlt($hMemDC, 0, 0, $iW_Region, $iH_Region, $hDC_Region, _
                        $aMPos[0] > $aMPos_old[2] ? $aMPos_old[2] : $aMPos[0], _
                        $aMPos[1] > $aMPos_old[3] ? $aMPos_old[3] : $aMPos[1], BitOR($SRCCOPY, $CAPTUREBLT))
                Local $hHBitmap_Clipboard = _WinAPI_CopyImage($hHBitmap_Captured, 0, 0, 0, BitOR($LR_COPYDELETEORG, $LR_COPYRETURNORG))
                _WinAPI_SelectObject($hHBitmap_Captured, $hObjOld)
                _WinAPI_DeleteDC($hHBitmap_Captured)
                _WinAPI_ReleaseDC(0, $hDC_Region)

                AutoItSetOption("MouseCoordMode", $iOld)
                If $bClipboard Then
                    ;put captured region to clipboard
                    If Not _ClipBoard_Open(0) Then
                        _WinAPI_DeleteObject($hHBitmap_Clipboard)
                        Return SetError(1, 0, 0)
                    EndIf
                    If Not _ClipBoard_Empty() Then
                        _WinAPI_DeleteObject($hHBitmap_Clipboard)
                        Return SetError(2, 0, 0)
                    EndIf
                    Local Const $hCP = _ClipBoard_SetDataEx($hHBitmap_Clipboard, $CF_BITMAP)
                    If Not $hCP Or @error Then
                        _WinAPI_DeleteObject($hHBitmap_Clipboard)
                        Return SetError(3, 0, 0)
                    EndIf
                    _ClipBoard_Close()
                    _WinAPI_DeleteObject($hHBitmap_Clipboard)
                    Return 1
                Else
                    Return $hHBitmap_Clipboard
                EndIf
        EndSwitch

        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _WinAPI_SelectObject($hGfxDC, $hObjOld)
                _WinAPI_ReleaseDC($hGUI_Screencapture, $hDC)
                _WinAPI_DeleteDC($hGfxDC)
                _WinAPI_DeleteObject($hBitmapGDI)
                _WinAPI_SelectObject($hGfxDC, $hPen_Orig)
                _WinAPI_DeleteObject($hPen)
                GUIDelete($hGUI_Screencapture)
                AutoItSetOption("MouseCoordMode", $iOld)
                Return -1
        EndSwitch
    Until False
EndFunc   ;==>_WinAPI_MarkScreenRegionAndCapture

Might be useful...

 

Download:  _WinAPI_MarkScreenRegionAndCapture.au3  (same as above in the code box)

 

Tested only on Win10 x64 but should work also on other Window versions. If not please reply.

 

Edited January 22, 2017 by UEZ
Little update

[wakillon]

Hi UEZ 

Tested on Win8.1 x64 without problem.

Nice work 

[l3ill]

UEZ,

Excellent resource !! Awesome as always...

Win 7 32 BIT

BTW: whatever happened to your old avatar? the guy rubbing sand in his own face...  that was kewl 

Keep um coming!

Bill

 

[UEZ]

2 hours ago, wakillon said:

Hi UEZ 

Tested on Win8.1 x64 without problem.

Nice work 

Thanks for testing. 

 

1 hour ago, l3ill said:

UEZ,

Excellent resource !! Awesome as always...

Win 7 32 BIT

BTW: whatever happened to your old avatar? the guy rubbing sand in his own face...  that was kewl 

Keep um coming!

Bill

 

Thanks also to you for testing . You mean that image probably:

 

Quote

Prep
Photograph by Sucheta Das / AP
A traditional Indian wrestler smears mud on his head during a March practice session in Calcutta, India.

http://img.timeinc.net/time/pictures_of_the_year/pictures_of_the_year_28.jpg

Edited September 26, 2016 by UEZ

[jguinch]

Works perfectly with multiple monitors

 

[UEZ]

3 minutes ago, jguinch said:

Works perfectly with multiple monitors

 

I know. 

[junkew]

@UEZ: Is nowadays GDI still the standard to capture screens? Probably GDI is the most easy and stable one over the years

http://www.codeproject.com/Articles/5051/Various-methods-for-capturing-the-screen

 

[UEZ]

@junkew: well, the GDI / GDI+ stuff might be outdated meanwhile but it works probably and "fast" enough for basic tasks such as screen capturing and moving some "objects" around -> old school.

I didn't try DirectX neither Windows Media API yet but thanks for the link. Time to explore the DirectX / D2D stuff...

 

Edited September 26, 2016 by UEZ

[junkew]

I have the feeling that within W10 still GDI is the way to work with as DirectX and WMP is not allways directly installed. Anyway I like your example and will check if I can incorporate this somehow in simplespy and iuiautomation stuff.

 

[coffeeturtle]

Always appreciate your work @UEZ ! Thank you for sharing!

*cough* would be nice to have same concept but with video recording too *cough*  :-D  just throwing that out there...

[UEZ]

1 minute ago, coffeeturtle said:

Always appreciate your work @UEZ ! Thank you for sharing!

*cough* would be nice to have same concept but with video recording too *cough*  :-D  just throwing that out there...

Well with AutoIt video recording is a tough stuff but I had it implemented already in  AutoIt Windows Screenshooter

Try it out.

 

[coffeeturtle]

7 hours ago, UEZ said:

Well with AutoIt video recording is a tough stuff but I had it implemented already in  AutoIt Windows Screenshooter

Try it out.

 

Never knew about that. Thanks! You already thought of it and implemented it! Nicely done!

 

[qwert]

No need to change anything, but could you comment on why this function doesn't pick up any "always on top" windows or dialogs.

I mention this because the PC's Print Screen button always captures the current view ... but the screen capture utilities I've tried usually don't.

 

[UEZ]

46 minutes ago, qwert said:

No need to change anything, but could you comment on why this function doesn't pick up any "always on top" windows or dialogs.

I mention this because the PC's Print Screen button always captures the current view ... but the screen capture utilities I've tried usually don't.

 

For me on Win10 b1607 it works properly also for MsgBoxes / GUI with topmost flag.

I need to test it in my Win7 / Vista vm...

[qwert]

Now that you mention Win10, I do recall there was some issue related to Win7 running "non-Aero" ... which is how I configure my PCs.

What would be great is a setting in the capture function that could specify Aero mode just for the capture ... or some other method, of course.

Thanks for looking at this.

[UEZ]

Well, I just tested in my Win7 vm and it works properly with / without Aero. The AutoIt test GUI with topmost attribute is captured.

[qwert]

I've traced it to layered windows.  I put together a very simple example.  If I compile the script below, launch it and then run your capture, the torus is not captured.

expandcollapse popup

;
;       Layered GUI for screen capture test
;
#include <GDIPlus.au3>
#include <WindowsConstants.au3>

_GDIPlus_Startup()
$hImage = _GDIPlus_ImageLoadFromFile("C:\AutoIt3\Examples\GUI\Torus.png")

Global $GUI = GUICreate("Layered Test", 200, 200, -1, -1, $WS_POPUP, BitOR($WS_EX_TOPMOST, $WS_EX_LAYERED)) ; layered is necessary
SetBitmap($GUI, $hImage, 255)
GUISetState()

Sleep(20000)

_GDIPlus_Shutdown()

Func SetBitmap($hGUI, $hImage, $iOpacity)
    Local Const $AC_SRC_ALPHA = 1                   ; don't really understand why these are set
    Local Const $ULW_ALPHA = 2
    Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend

    $hScrDC = _WinAPI_GetDC(0)
    $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)
    $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)

    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    DllStructSetData($tSize, "X", _GDIPlus_ImageGetWidth($hImage))
    DllStructSetData($tSize, "Y", _GDIPlus_ImageGetHeight($hImage))
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    DllStructSetData($tBlend, "Alpha", $iOpacity)
    DllStructSetData($tBlend, "Format", $AC_SRC_ALPHA)

    _WinAPI_UpdateLayeredWindow($hGUI, $hScrDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
    _WinAPI_ReleaseDC(0, $hScrDC)
    _WinAPI_SelectObject($hMemDC, $hOld)
    _WinAPI_DeleteObject($hBitmap)
    _WinAPI_DeleteDC($hMemDC)
EndFunc   ;==>SetBitmap

Is there some setting I can adjust on Win7 ... other than enabling Areo?

[UEZ]

Got it now - torus is not visible only when Aero is enabled.

One quick and dirty solution is to enable Aero within the script using

_WinAPI_DwmEnableComposition(True)

and disable Aero again when finished.

Anyhow, I will try to find a workaround...

[UEZ]

@qwert I updated the code. Can you try again?

[qwert]

Excellent!  Thanks!

I’ll will take a close look at the changes you made to try to understand ... but would you mind summarizing what you found in a sentence or two ... and what change was needed?

 

Captured.bmp