Add .txt to GUICtrlCreateListView

[PINTO1927]

Hi Guys,

I'm working on this project:

$Import = GUICtrlCreateButton("Import", 15, 175, 90, 40, $WS_GROUP)
$List = GUICtrlCreateListView("Name|Address|E-mail", 15, 220, 400, 363, $LVS_SORTDESCENDING)
$Item1 = GUICtrlCreateListViewItem("test|test|test", $List)
GUISetState(@SW_SHOW, $GUI)

While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE, $Exit
      Exit
   Case $Import
      $Table_Import = FileOpenDialog("Import list '*.txt'", @DesktopDir & "\", "Text (*.txt)")
      If @error Then ContinueLoop
      GUICtrlSetData($Item1, $Table_Import)

In the text file the fields are delimited with "|" and the values are not in the same row but one below the other.
However in the txt file the sum of the values may change.

Can you help me?

Thank's

[Jos]

1 minute ago, PINTO1927 said:

Can you help me?

Help with what? What isn't working yet?

How exactly does that input file look?

Jos

[PINTO1927]

When presented with the import it is only replaced the first item "test" with the imported file directory.
No it is replaced with the content.

[Jos]

You missed to answer a question there! How exactly does the input looks like?

Jos

[PINTO1927]

I'm sorry.

In the text file are present these values, for example:

josh|address|josh@gmail.com
james|address|james@yahoo.com

They must be imported into GUICtrlCreateListView line by line.

[Jos]

Ok, that makes sense now. 
So for starters, you are not reading the file at all at the moment. FileOpenDialog retuns the filename, not its content.
You could read the whole file into an Array with _FileReadToArray() and then loop though the records adding them a line at the time with GUICtrlCreateListViewItem()

Making sense?

Jos

[PINTO1927]

Ok.
But I would need that of 'importing result remains in the GUI, that's why I was going to use GUICtrlCreateListView.
You have an example to show me?

[Jos]

No idea what you mean with the first sentence. Which part of what I described is unclear and do you have questions about? 
You should be able to code it yourself when the process is clear.

Jos 

[PINTO1927]

You can not import the text file into GUICtrlCreateListView?

[Jos]

No...  as I described: just loop through the records and add them one at the time. What is the issue with that?

[PINTO1927]

Ok. my question is:
I can use the _FileReadToArray () function, leaving the array table in the GUI and not in the window?

[PINTO1927]

We did it by setting this command

$Import = GUICtrlCreateButton("Import", 15, 175, 90, 40, $WS_GROUP)
$List = GUICtrlCreateListView("Name|Address|E-mail", 15, 220, 400, 363, $LVS_SORTDESCENDING)
$Item1 = GUICtrlCreateListViewItem("test|test|test", $List)
GUISetState(@SW_SHOW, $GUI)

While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE, $Exit
      Exit
   Case $Import
      $Table_Import = FileOpenDialog("Import list '*.txt'", @DesktopDir & "\", "Text (*.txt)")
      If @error Then ContinueLoop
      Local $Array_Lista
      ;============================================================ ADD TO GUICtrlCreateListView
      _FileReadToArray($Tabella_Importa, $Array_Lista)
      $Limite_Array = UBound($Array_Lista) - 1
      For $i = 1 To $Limite_Array
          $All_Box = String($Array_Lista[$i])
          GUICtrlCreateListViewItem($All_Box, $Lista)
      Next

 

[Jos]

Is that now working as you want or is there still a question as I don't understand the last question posted?

Jos

[PINTO1927]

Last question concerning last posted script.
You can copy the text of a row in GUICtrlCreateListView?

now I can only select rows

[PINTO1927]

I managed to obtain import the text file, and I have the result we wanted (see Annex).
Now I would like, if a row is selected, and then pressed the button "Sele", the data "NAME & SURNAME | ADDRESS | EMAIL" is transferred into their inputbox you see on the right.

[PINTO1927]

45 minutes ago, PINTO1927 said:

I managed to obtain import the text file, and I have the result we wanted (see Annex).
Now I would like, if a row is selected, and then pressed the button "Sele", the data "NAME & SURNAME | ADDRESS | EMAIL" is transferred into their inputbox you see on the right.

 

[kylomas]

Pinto1927,

This is a demo listview showing how to create a listview and read row values based on the row clicked.  Hope you find it useful.

expandcollapse popup

#include <ListViewConstants.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <Array.au3>
#include <GuiListView.au3>

Local $Clients = _
        [["1560", "Ben", "Age: 25", "Bla bla...", "Bla bla..."], _
        ["1025", "Somebody", "Age: 14", "Bla bla...", "Bla bla..."], _
        ["9684", "John", "Age: 36", "Bla bla...", "Bla bla..."], _
        ["1002", "Laura", "Age: 15", "Bla bla...", "Bla bla..."], _
        ["1234", "Another guy", "Age: 18", "Bla bla...", "Bla bla..."]]

;Create simple GUI
$Form1 = GUICreate("Select client:", 150, 200)

;Create list of clients
$List_Clients = GUICtrlCreateListView("ID|Name", 10, 10, 130, 200)

; dummy control actioned by notify routine when user clicks on control
$dummy_detail = GUICtrlCreateDummy()

GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")

; populate listview columns with ID and NAME
For $i = 0 To UBound($Clients) - 1
    _GUICtrlListView_AddItem($List_Clients, $Clients[$i][0])
    _GUICtrlListView_AddSubItem($List_Clients, $i, $Clients[$i][1], 1)
Next

; distribute column widths evenly to show all data
For $i = 0 To _GUICtrlListView_GetColumnCount($List_Clients)
    _GUICtrlListView_SetColumnWidth($List_Clients, $i, $LVSCW_AUTOSIZE_USEHEADER)
Next

While 1
    Switch GUIGetMsg()
        Case $gui_event_close
            Exit
            ; this control is actioned by the notification routine
        Case $dummy_detail
            _get_client_detail(_GUICtrlListView_GetItemTextString($List_Clients, -1))
    EndSwitch

WEnd

Func _get_client_detail($str)

    $str = StringRegExpReplace($str, '([^\|])\|.*', '$1')

    Local $out
    For $i = 0 To UBound($Clients) - 1
        If $Clients[$i][0] <> $str Then ContinueLoop
        For $j = 0 To UBound($Clients, 2) - 1
            $out &= $Clients[$i][$j] & ' '
        Next
    Next
    MsgBox(0, 'CLIENT DETAIL', $out)

EndFunc   ;==>_get_client_detail

; routine to run when user clicks on any entry in the listview
Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)

    Local $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)

    Switch $tNMHDR.IDFrom
        Case $List_Clients
            Switch $tNMHDR.Code
                Case $nm_click
                    GUICtrlSendToDummy($dummy_detail) ; action dummy control in the message loop
            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

kylomas

Edited September 2, 2016 by kylomas
clarification

[PINTO1927]

Hi kylomas, and thanks for the help.
hi kylomas, and thanks for the help.
The problem is that the data inside the GUICtrlCreateListView are imported through a text file, accordingly the time when I try to return this value in a row, brings me 0.
I have created a "Sele" button to simulate the data transfer.

Case $Sele
     $SeleRow = _GUICtrlListView_GetSelectedIndices($List, 0)
     $aItem = _GUICtrlListView_GetItemTextArray($List, 1)
     MsgBox(0, "", $aItem)

With this I try to import the text in the row, but the value is 0.

Something wrong?

[BrewManNH]

You're returning an array with the $aItem line, are you reading it as an array or as a simple variable?

[kylomas]

Pinto1927,

See if this makes sense...

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

GUICreate("E-Mail", 300, 200)
Local $idSelBtn = GUICtrlCreateButton('Sele', 10, 05, 40, 20)
Local $idListview = GUICtrlCreateListView("Name|Location|Email Address", 10, 30, 280, 180, $LVS_SORTDESCENDING)
_GUICtrlListView_SetColumnWidth($idListview, 2, $LVSCW_AUTOSIZE_USEHEADER)

; populate listview from text file...columns are "|" delimited

Local $aTextFile = StringSplit(FileRead(@ScriptDir & '\lv.test.txt'), @CRLF, $STR_ENTIRESPLIT)
For $i = 1 To $aTextFile[0]
    If $aTextFile[$i] = '' Then ContinueLoop
    GUICtrlCreateListViewItem($aTextFile[$i], $idListview)
Next

GUISetState(@SW_SHOW)

Local $aIndices, $out

While 1
    Switch GUIGetMsg()
        Case $idSelBtn
            ; get # of listview rows selected
            $aIndices = _GUICtrlListView_GetSelectedIndices($idListview, True)
            $out = ''
            ; loop thru selected indicies and format out
            For $i = 1 To $aIndices[0]
                $out &= _GUICtrlListView_GetItemTextString($idListview, $aIndices[$i]) & @CRLF
            Next
            MsgBox(0, 'Email Selection', $out)
        Case $GUI_EVENT_CLOSE
            GUIDelete()
            Exit
    EndSwitch
WEnd

Input file...lv.test.txt

As BrewmanNH said you are trying to display an array as a simple variable.  If you want to display an array use _arraydisplay($yourarray).

kylomas

edit: same code addressing your other question...

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

GUICreate("E-Mail", 300, 200)
Local $idSelBtn = GUICtrlCreateButton('Sele', 10, 05, 40, 20)
Local $idListview = GUICtrlCreateListView("Name|Location|Email Address", 10, 30, 280, 180, $LVS_SORTDESCENDING)
_GUICtrlListView_SetColumnWidth($idListview, 2, $LVSCW_AUTOSIZE_USEHEADER)

; populate listview from text file...columns are "|" delimited

Local $aTextFile = StringSplit(FileRead(@ScriptDir & '\lv.test.txt'), @CRLF, $STR_ENTIRESPLIT)
For $i = 1 To $aTextFile[0]
    If $aTextFile[$i] = '' Then ContinueLoop
    GUICtrlCreateListViewItem($aTextFile[$i], $idListview)
Next

GUISetState(@SW_SHOW)

Local $aIndices, $out

While 1
    Switch GUIGetMsg()
        Case $idSelBtn
            ; get # of listview rows selected
            $aIndices = _GUICtrlListView_GetSelectedIndices($idListview, True)
            $out = ''
            ; loop thru selected indicies and format out
            For $i = 1 To $aIndices[0]
                $out &= _GUICtrlListView_GetItemText($idListview, $aIndices[$i],0) & @TAB
                $out &= _GUICtrlListView_GetItemText($idListview, $aIndices[$i],2) & @CRLF
            Next
            MsgBox(0, 'Email Selection', $out)
        Case $GUI_EVENT_CLOSE
            GUIDelete()
            Exit
    EndSwitch
WEnd

 

Edited September 3, 2016 by kylomas
additional info