*Answered* Submit form - no name,no ID, no submit works, no OnClick event...

[sharkys]

Hi,

I'm trying to search around specific issue I have but unsuccessfully.

<INPUT onmouseover=onMouseOverButtonHandler(this); onfocus=onMouseOverButtonHandler(this); onmouseout=onMouseOutButtonHandler(this); onblur=onMouseOutButtonHandler(this); class=button accessKey=o type=submit value=OK>

Is there any way around this ?

Following doesn't work or  returning empty string...

_IEAction($oSubmit, "click")

or

_IEGetObjByName($oIE, "OK")

or

$oButtons = _IETagNameGetCollection ($oIE, "button")
For $oButton In $oButtons
    If $oButton.type = "submit" Then  _IEAction ($oIE, "click")
Next

Thank you for advice and sorry if it's already mentioned somewhere but really I was searching already for hours....

Edited August 24, 2016 by sharkys

[mLipok]

Maybe like this:

expandcollapse popup

.......
.......
.......
_Example($oIE)
.......
.......
.......

Func _Example(ByRef $oIE)
    ; <INPUT onmouseover=onMouseOverButtonHandler(this); onfocus=onMouseOverButtonHandler(this); onmouseout=onMouseOutButtonHandler(this); onblur=onMouseOutButtonHandler(this); class=button accessKey=o type=submit value=OK>

    ; https://www.w3.org/TR/css3-selectors/#selectors
    ; find INPUT tag with attribute onmouseover="onMouseOverButtonHandler(this)"
    Local $oSelection = _IEquerySelectorAll($oIE, 'input[onmouseover="onMouseOverButtonHandler(this)"]', 0)
    If Not @error Then _IEAction($oSelection, 'click')
EndFunc   ;==>_Example




;#FUNCTION#=============================================================================================================
; Name...........: _IEquerySelectorAll()
; Description ...: Returns an Object or a Colection of objects
; Syntax.........: (ByRef $oDoc, $sQuery, $iItemIndex = Default)
; Parameters ....: $oDoc - The document object from IE
;                  $sQuery - String of Query. Example: _IEquerySelectorAll($oDoc, '"div.note, div.alert"', Default) will return a colection of div elements with classes of note and alert
;                  $iItemIndex -     [optional] Default returns a colection, else use a 0 based index to indicate the object in sequence
; Return values .: Success - Object or a Colection of objects
;                  Failure - returns 0 sets the @error flag to non-zero.
;                   3 ($_IEStatus_InvalidDataType) - Invalid Data Type
;                   4 ($_IEStatus_InvalidObjectType) - Invalid Object Type
;                   5 ($_IEStatus_InvalidValue) - Invalid Value
;                   7 ($_IEStatus_NoMatch) - No Match
; Author ........: XThrax aka uncommon
; Remarks .......: This fuction was pretty much stolen from Dale Hohm the IE UDF creator so much credit to him, also to mLipok who made the error checking better.
;                   Also note that this a relatively recent add-on to IE so it requires IE 9 and above.
;                   If you find you receive a com error of "unknown name" its likely the site is using meta tag attribute X-UA-Compatible which has reverted the browser to forget about it.
;
; Related .......: _IETagNameAllGetCollection();_IEClassNameGetCollection()
; Link ..........;https://www.autoitscript.com/forum/topic/181376-_iequeryselectorall/
;                 https://msdn.microsoft.com/en-us/library/cc304115(v=vs.85).aspx
; Example .......; No
; =====================================================================================================================


Func _IEquerySelectorAll(ByRef $oDoc, $sQuery, $iItemIndex = Default)
    If Not IsObj($oDoc) Then
        ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidDataType & " Invalid DataType" & @LF)
        Return SetError($_IEStatus_InvalidDataType, 1, 0)
    ElseIf Not __IEIsObjType($oDoc, "browserdom") Then
        ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidObjectType & " Invalid ObjectType" & @LF)
        Return SetError($_IEStatus_InvalidObjectType, 2, 0)
    ElseIf Not IsNumber($iItemIndex) And $iItemIndex <> Default Then
        ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidValue & " Invalid Index" & @LF)
        Return SetError($_IEStatus_InvalidValue, 3, 0)
    ElseIf $iItemIndex = Default Or $iItemIndex >= 0 Then
        Local $oTemp = Null
        If __IEIsObjType($oDoc, "documentcontainer") Then
            $oTemp = _IEDocGetObj($oDoc)
            If @error Then Return SetError(@error, @extended, 0)
        Else
            $oTemp = $oDoc
        EndIf
        Local $oClassColl = $oTemp.querySelectorAll($sQuery)
        If @error Then
            ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IESTATUS_GeneralError & " GeneralError1: " & @error & @LF)
            Return SetError($_IESTATUS_GeneralError, 3, 0)
        ElseIf (Not IsObj($oClassColl)) Or $oClassColl = Null Or $oClassColl.length = 0 Then
            ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_NoMatch & " NoMatch" & @LF)
            Return SetError($_IEStatus_NoMatch, 0, 0) ; Could be caused by parameter 2, 3 or both
        Else
            If $iItemIndex = Default Then
                Return SetError($_IEStatus_Success, $oClassColl.length, $oClassColl)
            ElseIf $iItemIndex > $oClassColl.length Then
                ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidValue & " Invalid Value" & @LF)
                Return SetError($_IEStatus_InvalidValue, $oClassColl.length, 0)
            Else
                $oItem = $oClassColl.Item($iItemIndex)
                If @error Then
                    ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IESTATUS_GeneralError & " GeneralError2: " & @error & @LF)
                    Return SetError($_IESTATUS_GeneralError, 3, 0)
                ElseIf (Not IsObj($oItem)) Or $oItem = Null Then
                    ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_NoMatch & " NoMatch Index: " & $iItemIndex & @LF)
                    Return SetError($_IEStatus_NoMatch, 0, 0) ; Could be caused by parameter 2, 3 or both
                Else
                    Return SetError($_IEStatus_Success, 0, $oItem)
                EndIf
            EndIf
        EndIf
    Else
        ConsoleWriteError("--> _IEquerySelectorAll Error: " & $_IEStatus_InvalidValue & " Invalid Value: " & $iItemIndex & @LF)
        Return SetError($_IEStatus_InvalidValue, 3, 0)
    EndIf
EndFunc   ;==>_IEquerySelectorAll

 

btw.
Please also read this:    How to use IE.au3  UDF with  AutoIt v3.3.14.x  

Edited August 22, 2016 by mLipok

[sharkys]

Thank you, I see it first time, unfortunately using AutoIT just from time to time ;-(

[mLipok]

7 minutes ago, sharkys said:

Thank you, I see it first time, unfortunately using AutoIT just from time to time ;-(

As I see by last 8 years

EDIT:
You was not said it clear, so I ask: Whether this my example solves your problem ?

Edited August 22, 2016 by mLipok

[sharkys]

16 hours ago, mLipok said:

As I see by last 8 years

EDIT:
You was not said it clear, so I ask: Whether this my example solves your problem ?

Well, so long since 1st registration ? Uf ;-) But really I have created just 1 simple app in AutoIt, really I'm green horn.

As for the example/function, it's pretty clear still it doesn't work for me - need to spend more time on that.

On above mentioned example, even following should work, right?

_IEquerySelectorAll($oIE, 'input[value="OK"]', 0)

Actually it seems to be normal "form", so even standard SUBMIT should work - not sure why it doesn't.... maybe some stupid error I don't see at the moment.

 

<form name="RecertificationActivityForm" method="post" action="/itim/self/Activity.do">
    <input type="hidden" name="command" value="submit">
....
....

<input type="submit" accesskey="o" value="OK" onmouseover="onMouseOverButtonHandler(this);" onmouseout="onMouseOutButtonHandler(this);" onblur="onMouseOutButtonHandler(this);" onfocus="onMouseOverButtonHandler(this);" class="button">

<INPUT class="button"  onfocus="onMouseOverButtonHandler(this);" onblur="onMouseOutButtonHandler(this);" onmouseover="onMouseOverButtonHandler(this);" onmouseout="onMouseOutButtonHandler(this);" type="button" accesskey="c" value="Cancel" onclick="javascript:window.location.href='./Review.do?refresh=1';"/>

</form>

Getting :

Local $oClassColl = $oTemp.querySelectorAll($sQuery)
Local $oClassColl = $oTemp^ ERROR

I need to debug it.

Edited August 23, 2016 by sharkys

[Danp2]

Did you try _IEFormSubmit?

[mLipok]

 

48 minutes ago, sharkys said:

Getting :

Local $oClassColl = $oTemp.querySelectorAll($sQuery)
Local $oClassColl = $oTemp^ ERROR

I need to debug it.

 

18 hours ago, mLipok said:

Please also read this:    How to use IE.au3  UDF with  AutoIt v3.3.14.x  

 

[sharkys]

1 hour ago, Danp2 said:

Did you try _IEFormSubmit?

I'm idiot I tell you. This works, thank you so much, I really overlooked this basic !

@mLipok, @Danp2, thank you for all your replies, learned again something new ;-)