Change values in config files

[ur]

I have a custom configuration file which has key-value pairs as in below format.

BuildLocation:C:\Build
BuildExe:setup.exe
Release:r9.64.02
Silent:No
InstallPath:default
Compare :No
MartUpgrade :Yes
Bit:64
ERwinUpgrade:No

I need to change the value of "BuildExe" using my program.

Is there any inbuilt function already available for these kind of files?.

Can any one help me how to do this.

[Melba23]

ur,

What code have you tried that has not worked?

M23

[aiter]

Perhaps you can just read and write to it using IniRead and IniWrite (see helpfile). I noticed the file name does not have to end in .ini for these function to work.

It expects = though for the assigns so I am not sure.

 

[ur]

55 minutes ago, aiter said:

Perhaps you can just read and write to it using IniRead and IniWrite (see helpfile). I noticed the file name does not have to end in .ini for these function to work.

It expects = though for the assigns so I am not sure.

 

But in this file there is no sections as in INI files.

And also here we are using : instead of =.

[ur]

2 hours ago, Melba23 said:

ur,

What code have you tried that has not worked?

M23

Hi Melba,

I starting writing logic as reading line by line and doing string compare and split at : in that particular line.

But my colleague told that he saw sometime back direct library for these kind of files in AutoIT.

So, can you suggest anything like that if possible.

[Melba23]

ur,

Alas I have no knowledge of such a library.

I would have suggested reading the file into an array, looking for the element containing "BuildExe:" and replacing it, before rewriting the file.

M23

Edit: When you reply, please use the "Reply to this topic" button at the top of the thread or the "Reply to this topic" editor at the bottom rather than the "Quote" button - responders know what they wrote and it just pads the thread unnecessarily.

 

Edited August 12, 2016 by Melba23

[AutoBert]

this is one of the possible solutions:

#include <Array.au3>
#include <File.au3>

Global $aText[1][1]
Global $sConfig = 'MyConfigFile.txt'

_FileReadToArray($sConfig, $aText, $FRTA_COUNT)
_ArrayColInsert($aText, 1)
For $i = 1 To $aText[0][0]
    $aSplit = StringSplit($aText[$i][0], ':')
    $aText[$i][0] = $aSplit[1]
    For $j = 2 To $aSplit[0]
        $aText[$i][1] &= $aSplit[$j]
        If $j < $aSplit[0] Then $aText[$i][1] &= ':'
    Next
Next
;_ArrayDisplay($aText)
_ChangeValueForKey($aText, 'BuildExe', 'NewValue')  ;change NewValue to your needs
;_ArrayDisplay($aText)
_FileWriteFromArray($sConfig,$aText,1,Default,':')

Func _ChangeValueForKey(ByRef $aArray, $sKey, $sValue)
    For $i = 1 To $aArray[0][0]
        If $aArray[$i][0] = $sKey Then
            $aArray[$i][1] = $sValue
            Return
        EndIf
    Next
EndFunc   ;==>_ChangeValueForKey

note: the solution is exactly to your demo data, if real data isn't conform to it, it doesn't work.

[InunoTaishou]

Here's another way. Uses regex to support multiple different separators for the key and value delimiter.

expandcollapse popup

#include <File.au3>

FileWrite(@ScriptDir & "\Config File.cfg", "BuildLocation:C:\Build" & @CRLF & _
"BuildExe:setup.exe" & @CRLF & _
"Release:r9.64.02" & @CRLF & _
"Silent:No" & @CRLF & _
"InstallPath:default" & @CRLF & _
"Compare :No" & @CRLF & _
"MartUpgrade :Yes" & @CRLF & _
"Bit:64" & @CRLF & _
"ERwinUpgrade:No")

ConfigFileWrite(@ScriptDir & "\Config File.cfg", "BuildExe", "New Builder Program.exe")

ShellExecute(@ScriptDir & "\Config File.cfg")

Func ConfigFileWrite(Const $sFilePath, Const $sConfigKey, Const $sConfigValue, $sRegexPattern = Default)
    Local $aFileData = Null
    Local $sSeperator = Null

    _FileReadToArray($sFilePath, $aFileData, $FRTA_NOCOUNT)

    If (@error) Then Return SetError(@Error, @Extended, 0)

    If ($sRegexPattern = Default) Then
        $sRegexPattern = "([:-])"
    Else
        $sRegexPattern = "([" & $sRegexPattern & "])"
    EndIf

    For $i = 0 to UBound($aFileData) - 1
        Local $aFileLine = StringSplit(StringRegExpReplace($aFileData[$i], $sRegexPattern, "=", 1), "=", $STR_NOCOUNT)
        If (Not IsArray($aFileLine)) Then Return SetError(-1, 0, "")

        If (StringStripWS($aFileLine[0], $STR_STRIPLEADING + $STR_STRIPTRAILING) = $sConfigKey) Then
            $aFileData[$i] = StringReplace($aFileData[$i], StringStripWS($aFileLine[1], $STR_STRIPLEADING + $STR_STRIPTRAILING), $sConfigValue)
            Return _FileWriteFromArray($sFilePath, $aFileData)
        EndIf
    Next

    Return SetError(-2, 0, 0)
EndFunc

 

[orbs]

simpler example, based on script by AutoBert in post #7:

#include <Array.au3>
#include <File.au3>

Global $aConfig
Global $sConfigFile = 'config.txt'

_FileReadToArray($sConfigFile, $aConfig, $FRTA_NOCOUNT)
_ChangeValueForKey($aConfig, 'BuildExe', 'NewValue')
_FileWriteFromArray($sConfigFile, $aConfig)

Func _ChangeValueForKey(ByRef $aConfig, $sKey, $sValue)
    For $i = 0 To UBound($aConfig) - 1
        If StringLeft($aConfig[$i], StringLen($sKey) + 1) = $sKey & ':' Then
            $aConfig[$i] = $sKey & ':' & $sValue
            Return
        EndIf
    Next
EndFunc   ;==>_ChangeValueForKey

you don't need to split each line by colon (it's also prone to issues as there may be more than one colon in each line - e.g. first line in demo config at first post). all you need to do is check each line, the first one that you see that begins with the key name, you simply rewrite it.

Edited August 12, 2016 by orbs

[ur]

this is the one I came up with.

Func writeConfig($sFilePath,$intStartCode,$sReplaceText)

;$sReplaceText = "sdfdsfdsfsd"
;$sFilePath = "C:\Users\KIRUD01\Desktop\Config.txt"
;$intStartCode = "BuildExe"
$arrRetArray = ""
$s = _FileReadToArray($sFilePath, $arrRetArray);Reading text file and saving it to array $s will show status of reading file..
$intStartingPointFound = 0
    For $i = 1 To UBound($arrRetArray)-1
        $line = $arrRetArray[$i];retrieves taskengine text line by line
        If StringInStr($line, $intStartCode) Then
                $intStartingPointFound = 1;if found the starting point of the module to copy then set this variable to 1
                ConsoleWrite ("Starting point " &  @CRLF)
                $arrRetArray[$i] = $intStartCode & ": " & $sReplaceText
                ExitLoop
        EndIf
        if $i = UBound($arrRetArray)-1 then ConsoleWrite("Not Found" & @CRLF)
    Next
_FileWriteFromArray ($sFilePath, $arrRetArray,1)

EndFunc

 

Edited August 17, 2016 by ur