GUICtrlSetResizing and hidden window

[TommyDDR]

Hi,

I have to set a resizing mode to differents controls in a hidden gui, that gui is initialised (hidden) and resized by a WinMove.

But when i show it, control are not resized where thez should.

There is a simple code that reproduce the problem.

Same gui, same content, one displayed then moved, the other moved then displayed :

#include <GUIConstantsEx.au3>

Opt("GUIOnEventMode", 1)
Opt("MustDeclareVars", 1)

Global $gui[2]
Global $labels[2]
Global $taille[2] = [200, 100]

For $i = 0 To UBound($gui, 1) - 1
    $gui[$i] = GUICreate($i, $taille[0], $taille[1], $i * ($taille[0]+100) + 500, (@DesktopHeight-$taille[1])/2)
    GUISetOnEvent($GUI_EVENT_CLOSE, "quit", $gui)
    $labels[$i] = GUICtrlCreateLabel("Test resizing...", $taille[0]-105, $taille[1]-25, 100, 20)
    GUICtrlSetBkColor($labels[$i], 0xE0E0E0)
    GUICtrlSetResizing($labels[$i], BitOR($GUI_DOCKRIGHT, $GUI_DOCKBOTTOM, $GUI_DOCKWIDTH, $GUI_DOCKHEIGHT))
Next
GUISetState(@SW_SHOW, $gui[0])

For $i = 0 To UBound($gui, 1) - 1
    WinMove($gui[$i], "", Default, Default, $taille[0]+100, $taille[1]+100)
Next
GUISetState(@SW_SHOW, $gui[1])

While(True)
    Sleep(10)
WEnd

Func quit()
    Exit
EndFunc

Is that a bug or do miss i something ?

EDIT : This bug disapear if gui is shown at lease one time (even if hide then)

Edited July 11, 2016 by TommyDDR

[Melba23]

TommyDDR,

This is not a bug, but AutoIt's behaviour changed between the 3,3,12.# and 3.3.14.# releases. I ran into a similar problem and when I asked I was told that It had to with getting the $WS_EX_RTL extended style to work correctly. Now you need to use GUISetState before using WinMove as until then the function will only affect the GUI and not its controls - as your code shows.

The simple solution to your problem is to set the GUI as hidden before using WinMove:

GUISetState(@SW_SHOW, $gui[0])
GUISetState(@SW_HIDE, $gui[1]) ; Added line <<<<<<<<<<<<<<<

Now the controls are correctly positioned in both GUIs after the move.

M23

[TommyDDR]

Thank's for the tips, it works now