Help inserting two zeros every other two characters in a string

[Mannyfresh15]

I need some help inserting two zeros every other two characters in a string

 

#include <String.au3>


$sString = "manny1"

$NewString = _StringInsert (    $sString, "00",0 )

MsgBox (0,"Hello" , "Your String After Inserting 00's  " & $NewString ,0)

the outcome need to be ma00nn00y100 but IDK how to do it. Please help.

Edited July 1, 2016 by Mannyfresh15

[Jfish]

#include <String.au3>
$sString = "manny1"
for $a=StringLen($sString) to 1 step -2
        $sString=_StringInsert ($sString, "00",$a)
Next
MsgBox (0,"Hello" , "Your String After Inserting 00's  " & $sString ,0)

 

Edited July 1, 2016 by Jfish

[Mannyfresh15]

  On 7/1/2016 at 7:29 PM, Jfish said:

#include <String.au3>
$sString = "manny1"
for $a=StringLen($sString) to 1 step -2
        $sString=_StringInsert ($sString, "00",$a)
        MsgBox(0,'',$sString)
Next
MsgBox (0,"Hello" , "Your String After Inserting 00's  " & $sString ,0)

 

Expand  

Thank you very much that works just fine... (:

[Jfish]

Glad I could help ... you may want to remove the extra message box from the for loop like I did in my edited post ... 

[Melba23]

Mannyfresh15,

Or you could do something like this:

$sString = "manny1"

$aRet = StringRegExp($sString, "(.{2})", 3)

$sNewString = ""

For $i = 0 To UBound($aRet) - 1
    $sNewString &= $aRet[$i] & "00"
Next

MsgBox(0, "Result", $sNewString)

M23

[ViciousXUSMC]

Meh I'll throw my 2 cents into the pot.  

$sString = "manny1"
$sNewString = StringRegExpReplace($sString, "(.{2})", "${0}00")
MsgBox(0, "Result", $sNewString)

 

One Liner just for fun:

MsgBox(0, "Results", StringRegExpReplace("Manny1", "(..)", "${0}00"))

 

Edited July 1, 2016 by ViciousXUSMC

[Mannyfresh15]

You guys are Awesome!  All your codes work like a charm!

[mikell]

My 2 cents 

$sString = "manny1"
$sNewString = StringRegExpReplace($sString, '..\K', "00")
MsgBox(0, "Result", $sNewString)

 

[Mannyfresh15]

@mikell thanks for those cents

[SadBunny]

I am so curious... What's the use?  This sounds like the kind of thing that solves a problem that need not be there in the first place, i.e. it may be useful to explain the bigger picture, maybe you'll get some better ideas?