GUIRegisterMsg(WM_NOTIFY) cause _ArrayDisplay() fail

[maniootek]

This happens to me again. GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY") cause _ArrayDisplay pop up freeze without any data displayed.

Code example:

expandcollapse popup

#include <WindowsConstants.au3> ;$WM_NOTIFY
#include <GUIConstantsEx.au3> ;$GUI_RUNDEFMSG
#include <GuiListView.au3> ;$tagNMHDR
#include <Array.au3>

GUICreate("")
$idListview = GUICtrlCreateListView("col1", 5, 5)
GUICtrlCreateListViewItem("item", $idListview)
GUICtrlCreateListViewItem("item", $idListview)

Local $aArray[0]
for $i=0 to 10
    _ArrayAdd($aArray, $i)
Next

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState(@SW_SHOW)

; Loop until the user exits.
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $idOK
            ExitLoop
    EndSwitch
WEnd


Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)

    Local $hWndFrom, $iCode, $tNMHDR, $hWndListView
    $hWndListView = GUICtrlGetHandle($idListview)
    If Not IsHWnd($hWndListView) Then $hWndListView = GUICtrlGetHandle($hWndListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode

                Case -3 ;$NM_DBLCLK ; Sent by a list-view control when the user double-clicks an item with the left mouse button
                    Local $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)

                    $index = DllStructGetData($tInfo, "Index")
                    $subitemNR = DllStructGetData($tInfo, "SubItem")

                    If $index <> -1 Then
                        ;msgbox(0,0,$index & $subitemNR)
                        _ArrayDisplay($aArray)
                    EndIf

            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

result

any idea what could be wrong? is it a bug?

Edited July 1, 2016 by Melba23
Amended title

[Melba23]

maniootek,

Most certainly not a bug and entirely due to your code. The Help file is quite clear:

Warning: blocking of running user functions which executes window messages with commands such as "MsgBox()" can lead to unexpected behavior, the return to the system should be as fast as possible !!!

_ArrayDisplay is a blocking function - so the crash is quite expected.

You need to set a flag in the handler and then action it in your idle loop - like this:

expandcollapse popup

#include <WindowsConstants.au3> ;$WM_NOTIFY
#include <GUIConstantsEx.au3> ;$GUI_RUNDEFMSG
#include <GuiListView.au3> ;$tagNMHDR
#include <Array.au3>

Global $fActivated = False

GUICreate("")
$idListview = GUICtrlCreateListView("col1", 5, 5)
GUICtrlCreateListViewItem("item", $idListview)
GUICtrlCreateListViewItem("item", $idListview)

Local $aArray[0]
for $i=0 to 10
    _ArrayAdd($aArray, $i)
Next

GUIRegisterMsg($WM_NOTIFY, "WM_NOTIFY")
GUISetState(@SW_SHOW)

; Loop until the user exits.
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $idOK
            ExitLoop
    EndSwitch

    If $fActivated Then
        $fActivated = False
        ;msgbox(0,0,$index & $subitemNR)
        _ArrayDisplay($aArray)
    EndIf

WEnd


Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)

    Local $hWndFrom, $iCode, $tNMHDR, $hWndListView
    $hWndListView = GUICtrlGetHandle($idListview)
    If Not IsHWnd($hWndListView) Then $hWndListView = GUICtrlGetHandle($hWndListView)

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode

                Case -3 ;$NM_DBLCLK ; Sent by a list-view control when the user double-clicks an item with the left mouse button
                    Local $tInfo = DllStructCreate($tagNMITEMACTIVATE, $ilParam)

                    $index = DllStructGetData($tInfo, "Index")
                    $subitemNR = DllStructGetData($tInfo, "SubItem")

                    If $index <> -1 Then
                        $fActivated = True
                    EndIf

            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

M23

[maniootek]

Thank you, it works now.