Shuffle string

[cookiemonster]

Hoping for some guidance, I have a string like:

$string='vXx2586578£&'

How can I go abouts shuffling the contents of the string?

[argumentum]

make an array and do the shuffling, then reconstruct the string

[czardas]

#include <Array.au3>

Local $string = 'vXx2586578£&'
Local $aChars = StringSplit($string, "", 2)

_ArrayShuffle($aChars)

Local $sNewString
For $i = 0 To UBound($aChars) - 1
    $sNewString &= $aChars[$i]
Next
MsgBox(0, "New String", $sNewString)

 

[jguinch]

Also this one :

 

[cookiemonster]

8 hours ago, czardas said:

#include <Array.au3>

Local $string = 'vXx2586578£&'
Local $aChars = StringSplit($string, "", 2)

_ArrayShuffle($aChars)

Local $sNewString
For $i = 0 To UBound($aChars) - 1
    $sNewString &= $aChars[$i]
Next
MsgBox(0, "New String", $sNewString)

 

Works perfectly, I had tried doing it this way but messed part of it up, thanks for clarification.

[JLogan3o13]

A few less lines:

#include <Array.au3>

Local $string = 'vXx2586578£&'
Local $aChars = StringSplit($string, "", 2)

_ArrayShuffle($aChars)
MsgBox(0, "New String", StringReplace(_ArrayToString($aChars), "|", ""))

 

[UEZ]

Here the non array version:

Global $string='1234567890'

ConsoleWrite(ShuffleChars($string) & @CRLF)

Func ShuffleChars($sString, $iRounds = 1)
    Local $sTemp1, $sTemp2, $i, $j, $r, $t, $iLen, $rnd, $sLeft, $sMid, $sRight
    $iLen = StringLen($sString)
    For $r = 1 To $iRounds
        For $i = 1 To $iLen
            $j = $i
            $rnd = Random(1, $iLen, 1)
            If $rnd = $i Then ContinueLoop
            If $j < $rnd Then
                $t = $j
                $j = $rnd
                $rnd = $t
            EndIf
            $sTemp1 = StringMid($sString, $rnd, 1)
            $sTemp2 = StringMid($sString, $j, 1)
            $sLeft = StringMid($sString, 1, $rnd - 1)
            $sMid = StringMid($sString, $rnd + 1, $j - $rnd - 1)
            $sRight = StringMid($sString, $j + 1)
            $sString = $sLeft & $sTemp2 & $sMid & $sTemp1 & $sRight
        Next
    Next
    Return $sString
EndFunc

 

[iamtheky]

meant to post this here not in JG's example

-with powershell

#include<AutoItConstants.au3>
#include <Array.au3>

$Str = "shuffling"

$iPID = run("powershell -join ('" & _ArrayToString(stringsplit($Str , "" , 2) , "','") & "' | Get-Random -Count " & StringLen($Str) & ")" , "" , @SW_HIDE , $stdout_child)

$sOutput = ""

     While 1
        $sOutput &= StdoutRead($iPID)
        If @error Then ExitLoop
        WEnd

msgbox(0, '' , $sOutput)

 

[JLogan3o13]

AutoIt is like Burger King, you get so many great ways of doing things, you can have it your way 

[UEZ]

12 minutes ago, JLogan3o13 said:

 

AutoIt is like Burger King

 

Bad taste 

 

[jguinch]

@iamtheky : ah OK, I didn't really understand why you posted in the Example post (it already happened to me)

[iamtheky]

The one time i would have used the delete button properly...

[Danyfirex]

Hello I did this just for fun. it's based on swapping.

 

Local $string = 'vXx2586578£&'

ConsoleWrite(_StringShuffle($string) & @CRLF)
ConsoleWrite(_StringShuffle($string) & @CRLF)

Func _StringShuffle($sString)
Local $iRnd1 = 0
Local $iRnd2 = 0
Local $sChar1 = ""
Local $sChar2 = ""
Local $iMax = StringLen($sString)
For $i = 1 To $iMax
    $iRnd1 = Random(1, $iMax, 1)
    $iRnd2 = Random(1, $iMax, 1)
    $sChar1 = StringMid($sString, $iRnd1, 1)
    $sChar2 = StringMid($sString, $iRnd2, 1)
    $sString = StringReplace($sString, $iRnd1, $sChar2)
    $sString = StringReplace($sString, $iRnd2, $sChar1)
Next
Return $sString
EndFunc

Saludos