_GDIPlus_BitmapApplyFilter v0.9.8 build 2024-04-17 beta

[UEZ]

Since I disovered FreeBasic I decided to create a DLL to implement much faster image processing functionality to AutoIt.

Following functions are implemented yet:

expandcollapse popup

_GDIPlus_BitmapApplyFilter_BWJJNDithering
_GDIPlus_BitmapApplyFilter_BWBayerOrderedDithering
_GDIPlus_BitmapApplyFilter_Cartoon1
_GDIPlus_BitmapApplyFilter_ColorAccent
_GDIPlus_BitmapApplyFilter_Convolution_AnotherBlur
_GDIPlus_BitmapApplyFilter_Convolution_BoxBlur
_GDIPlus_BitmapApplyFilter_Convolution_EdgeDetection1
_GDIPlus_BitmapApplyFilter_Convolution_EdgeDetection2
_GDIPlus_BitmapApplyFilter_Convolution_EdgeDetection3
_GDIPlus_BitmapApplyFilter_Convolution_EdgeDetection4
_GDIPlus_BitmapApplyFilter_Convolution_EdgeDetection5
_GDIPlus_BitmapApplyFilter_Convolution_EdgeDetection6
_GDIPlus_BitmapApplyFilter_Convolution_Emboss1
_GDIPlus_BitmapApplyFilter_Convolution_Emboss45Degree
_GDIPlus_BitmapApplyFilter_Convolution_EmbossTopLeftBottomRight
_GDIPlus_BitmapApplyFilter_Convolution_Gaussian3x3
_GDIPlus_BitmapApplyFilter_Convolution_Gaussian5x5_1
_GDIPlus_BitmapApplyFilter_Convolution_Gaussian5x5_2
_GDIPlus_BitmapApplyFilter_Convolution_GaussianBlur
_GDIPlus_BitmapApplyFilter_Convolution_IntenseEmboss
_GDIPlus_BitmapApplyFilter_Convolution_Kirsch
_GDIPlus_BitmapApplyFilter_Convolution_Laplace1
_GDIPlus_BitmapApplyFilter_Convolution_Laplace2
_GDIPlus_BitmapApplyFilter_Convolution_Laplace3
_GDIPlus_BitmapApplyFilter_Convolution_LaplacianOfGaussian
_GDIPlus_BitmapApplyFilter_Convolution_ManualMatrix
_GDIPlus_BitmapApplyFilter_Convolution_MotionBlur
_GDIPlus_BitmapApplyFilter_Convolution_Outline3x3
_GDIPlus_BitmapApplyFilter_Convolution_Prewitt
_GDIPlus_BitmapApplyFilter_Convolution_Sharpen1
_GDIPlus_BitmapApplyFilter_Convolution_Sharpen2
_GDIPlus_BitmapApplyFilter_Convolution_Sobel
_GDIPlus_BitmapApplyFilter_Convolution_SovelVsPrewitt
_GDIPlus_BitmapApplyFilter_Convolution_TriangleBlur
_GDIPlus_BitmapApplyFilter_Convolution_Unsharp
_GDIPlus_BitmapApplyFilter_Convolution_Unsharp5x5
_GDIPlus_BitmapApplyFilter_Delaunay
_GDIPlus_BitmapApplyFilter_Dilatation
_GDIPlus_BitmapApplyFilter_DistortionBlur
_GDIPlus_BitmapApplyFilter_Edges
_GDIPlus_BitmapApplyFilter_Erosion
_GDIPlus_BitmapApplyFilter_FakeGreyscale
_GDIPlus_BitmapApplyFilter_FishEye
_GDIPlus_BitmapApplyFilter_Indexed
_GDIPlus_BitmapApplyFilter_Jitter
_GDIPlus_BitmapApplyFilter_Kuwahara
_GDIPlus_BitmapApplyFilter_Linellism
_GDIPlus_BitmapApplyFilter_Median
_GDIPlus_BitmapApplyFilter_Median2
_GDIPlus_BitmapApplyFilter_Mosaic
_GDIPlus_BitmapApplyFilter_OilPainting
_GDIPlus_BitmapApplyFilter_Open
_GDIPlus_BitmapApplyFilter_PenSketch
_GDIPlus_BitmapApplyFilter_PenSketch2
_GDIPlus_BitmapApplyFilter_Pixelate
_GDIPlus_BitmapApplyFilter_Pointillism
_GDIPlus_BitmapApplyFilter_RadialBlur
_GDIPlus_BitmapApplyFilter_Raster
_GDIPlus_BitmapApplyFilter_Spiral
_GDIPlus_BitmapApplyFilter_Swirl
_GDIPlus_BitmapApplyFilter_SymmetricNearestNeighbour
_GDIPlus_BitmapApplyFilter_TiltShift
_GDIPlus_BitmapApplyFilter_TimeWarp
_GDIPlus_BitmapApplyFilter_Ver
_GDIPlus_BitmapApplyFilter_Wave
_GDIPlus_BitmapApplyFilter_XRay

 

Since I am absolutely a newbie in FreeBasic, the DLL may contain errors.  Please report any bug.

 

FreeBasic source code can be found here: https://pastebin.com/Lugp6rCR

 

To do:

• add function headers with descriptions
• speed-up FB code -> partly done
• add more filters -> ongoing

 

Credits to:

• Jakub Szymanowski
• rdc
• Dewald Esterhuizen
• Santhosh G_ 
• Christian Graus
• www.gutgames.com

 

Have fun.

 

You can compare the speed with AutoIt version:

expandcollapse popup

#AutoIt3Wrapper_Version=b
#include <Array.au3>
#include <GDIPlus.au3>

Global $sFile = FileOpenDialog("Select an image", "", "Images (*.jpg;*.png;*.gif;*.bmp)")
If @error Then Exit

_GDIPlus_Startup()
Global Const $STM_SETIMAGE = 0x0172
Global Const $hImage = _GDIPlus_ImageLoadFromFile($sFile)
Global Const $iW = _GDIPlus_ImageGetWidth($hImage), $iH = _GDIPlus_ImageGetHeight($hImage)
Global Const $hGUI = GUICreate("GDI+ Image Filters", $iW * 2, $iH)
Global $fProg = 0, $iEnd = $iW * $iH - 1
AdlibRegister("Progress", 490)
Global $t = TimerInit()
Global Const $hGDIBitmap = _GDIPlus_BitmapApplyFilter_Median($hImage, 4)
ConsoleWrite(Round(TimerDiff($t) / 1000, 2) & " s / " & Round(TimerDiff($t) / 60000, 2) & " min" & @CRLF)
Global Const $iPic = GUICtrlCreatePic("", 0, 0, $iW - 1, $iH - 1)
Global Const $iPic_o = GUICtrlCreatePic("", $iW, 0, $iW - 1, $iH - 1)
_WinAPI_DeleteObject(GUICtrlSendMsg($iPic, $STM_SETIMAGE, $IMAGE_BITMAP, $hGDIBitmap))
Global Const $hGDIBitmap2 = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
_WinAPI_DeleteObject(GUICtrlSendMsg($iPic_o, $STM_SETIMAGE, $IMAGE_BITMAP, $hGDIBitmap2))

GUISetState()
AdlibUnRegister("Progress")
ToolTip("")

Do
Until GUIGetMsg() = -3

_GDIPlus_ImageDispose($hImage)
_WinAPI_DeleteObject($hGDIBitmap)
_WinAPI_DeleteObject($hGDIBitmap2)
_GDIPlus_Shutdown()

Exit

Func Progress()
    ToolTip(Int($fProg / $iEnd * 100) & " % / " & Round(TimerDiff($t) / 60000, 2) & " min", MouseGetPos(0) + 30, MouseGetPos(1) + 30)
EndFunc

#Region Symmetric Nearest Neighbour
Func _GDIPlus_BitmapApplyFilter_SymmetricNearestNeighbour($hImage, $fRadius = 2, $bGDI = True) ;no alpha channel implemented yet
    Local Const $iW = _GDIPlus_ImageGetWidth($hImage), $iH = _GDIPlus_ImageGetHeight($hImage)

    Local Const $hBitmap_Dest = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    Local Const $tBitmapData_Dest = _GDIPlus_BitmapLockBits($hBitmap_Dest, 0, 0, $iW - 1, $iH - 1, $GDIP_ILMWRITE, $GDIP_PXF32ARGB)
    Local Const $iScan0_Dest = DllStructGetData($tBitmapData_Dest, "Scan0")
    Local Const $tPixel_Dest = DllStructCreate("int[" & $iW * $iH & "];", $iScan0_Dest)

    Local Const $tBitmapData = _GDIPlus_BitmapLockBits($hImage, 0, 0, $iW - 1, $iH - 1, $GDIP_ILMREAD, $GDIP_PXF32ARGB)
    Local Const $iScan0 = DllStructGetData($tBitmapData, "Scan0")
    Local Const $tPixel = DllStructCreate("int[" & $iW * $iH & "];", $iScan0)

    Local $iRowOffset, $iX, $iY, $c, $k, $sumR, $sumG, $sumB, $iCount, $xx, $yy, $iR, $iG, $iB, $iR1, $iG1, $iB1, $iR2, $iG2, $iB2, $x, $y

    For $iY = 0 To $iH - 1
        $iRowOffset = $iY * $iW
        For $iX = 0 To $iW - 1
            $sumR = 0
            $sumG = 0
            $sumB = 0
            $iCount = 0
            $c = DllStructGetData($tPixel, 1, $iRowOffset + $iX)
            $iR = BitShift(BitAND(0x00FF0000, $c), 16)
            $iG = BitShift(BitAND(0x0000FF00, $c), 8)
            $iB = BitAND(0x000000FF, $c)
            For $yy = -$fRadius To $fRadius
                For $xx = -$fRadius To $fRadius
                    $k = $iX + $xx
                    $x = $k < 0 ? 0 : $k > $iW - 1 ? $iW - 1 : $k
                    $k = $iY + $yy
                    $y = $k < 0 ? 0 : $k > $iH - 1 ? $iH - 1 : $k
                    $c = DllStructGetData($tPixel, 1, $y * $iW + $x)
                    $iR1 = BitShift(BitAND(0x00FF0000, $c), 16)
                    $iG1 = BitShift(BitAND(0x0000FF00, $c), 8)
                    $iB1 = BitAND(0x000000FF, $c)
                    $k = $iX - $xx
                    $x = $k < 0 ? 0 : $k > $iW - 1 ? $iW - 1 : $k
                    $k = ($iY - $yy)
                    $y = $k < 0 ? 0 : $k > $iH - 1 ? $iH - 1 : $k
                    $c = DllStructGetData($tPixel, 1, $y * $iW + $x)
                    $iR2 = BitShift(BitAND(0x00FF0000, $c), 16)
                    $iG2 = BitShift(BitAND(0x0000FF00, $c), 8)
                    $iB2 = BitAND(0x000000FF, $c)
                    If __DeltaE($iR, $iG, $iB, $iR1, $iG1, $iB1) < __DeltaE($iR, $iG, $iB, $iR2, $iG2, $iB2) Then
                        $sumR += $iR1
                        $sumG += $iG1
                        $sumB += $iB1
                    Else
                        $sumR += $iR2
                        $sumG += $iG2
                        $sumB += $iB2
                    EndIf
                    $iCount += 1
                Next
            Next
            DllStructSetData($tPixel_Dest, 1, 0xFF000000 + Int($sumR / $iCount) * 0x10000 + Int($sumG / $iCount) * 0x100 + Int($sumB / $iCount), $iRowOffset + $iX)
            $fProg += 1
        Next
    Next
    _GDIPlus_BitmapUnlockBits($hImage, $tBitmapData)
    _GDIPlus_BitmapUnlockBits($hBitmap_Dest, $tBitmapData_Dest)
    _GDIPlus_ImageSaveToFile($hBitmap_Dest, @ScriptDir & "\Filter_SNN" & $fRadius & "_" & @YEAR & @MON & @MDAY & @MIN & @SEC & ".png")
    If $bGDI Then
        Local $hGDIBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap_Dest)
        _GDIPlus_BitmapDispose($hBitmap_Dest)
        Return $hGDIBitmap
    EndIf
    Return $hBitmap_Dest
EndFunc

Func __DeltaE($iR1, $iG1, $iB1, $iR2, $iG2, $iB2)
  Return Sqrt(($iR1 - $iR2) * ($iR1 - $iR2) + ($iG1 - $iG2) * ($iG1 - $iG2) + ($iB1 - $iB2) * ($iB1 - $iB2))
EndFunc
#EndRegion

#Region Jitter
Func _GDIPlus_BitmapApplyFilter_Jitter($hImage, $iAmount = 20, $bGDI = True)
    Local Const $iW = _GDIPlus_ImageGetWidth($hImage), $iH = _GDIPlus_ImageGetHeight($hImage)

    Local Const $hBitmap_Dest = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    Local Const $tBitmapData_Dest = _GDIPlus_BitmapLockBits($hBitmap_Dest, 0, 0, $iW - 1, $iH - 1, $GDIP_ILMWRITE, $GDIP_PXF32ARGB)
    Local Const $iScan0_Dest = DllStructGetData($tBitmapData_Dest, "Scan0")
    Local Const $tPixel_Dest = DllStructCreate("int[" & $iW * $iH & "];", $iScan0_Dest)

    Local Const $tBitmapData = _GDIPlus_BitmapLockBits($hImage, 0, 0, $iW - 1, $iH - 1, $GDIP_ILMREAD, $GDIP_PXF32ARGB)
    Local Const $iScan0 = DllStructGetData($tBitmapData, "Scan0")
    Local Const $tPixel = DllStructCreate("int[" & $iW * $iH & "];", $iScan0)
    Local $iX, $iY, $iRowOffset, $fNX, $fNY

    For $iY = 0 To $iH - 1
        $iRowOffset = $iY * $iW + 1
        For $iX = 0 To $iW - 1
            $fNX = $iX + Int((Random() - 0.5) * $iAmount)
            $fNX = $fNX < 1 ? 1 : $fNX > $iW - 1 ? $iW - 1 : $fNX
            $fNY = ($iY + Int((Random() - 0.5) * $iAmount))
            $fNY = $fNY < 1 ? 1 : $fNY > $iH - 1 ? $iH - 1 : $fNY
            $fNY *= $iW
            DllStructSetData($tPixel_Dest, 1, DllStructGetData($tPixel, 1, $fNY + $fNX), $iRowOffset + $iX)
            $fProg += 1
        Next
    Next
    _GDIPlus_BitmapUnlockBits($hImage, $tBitmapData)
    _GDIPlus_BitmapUnlockBits($hBitmap_Dest, $tBitmapData_Dest)
    _GDIPlus_ImageSaveToFile($hBitmap_Dest, @ScriptDir & "\Filter_Jitter" & $iAmount & "_" & @YEAR & @MON & @MDAY & @MIN & @SEC & ".png")
    If $bGDI Then
        Local $hGDIBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap_Dest)
        _GDIPlus_BitmapDispose($hBitmap_Dest)
        Return $hGDIBitmap
    EndIf
    Return $hBitmap_Dest
EndFunc
#EndRegion

#Region Median
Func _GDIPlus_BitmapApplyFilter_Median($hImage, $fRadius = 3, $bGDI = True)
    Local Const $iW = _GDIPlus_ImageGetWidth($hImage), $iH = _GDIPlus_ImageGetHeight($hImage)

    Local Const $hBitmap_Dest = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    Local Const $tBitmapData_Dest = _GDIPlus_BitmapLockBits($hBitmap_Dest, 0, 0, $iW - 1, $iH - 1, $GDIP_ILMWRITE, $GDIP_PXF32ARGB)
    Local Const $iScan0_Dest = DllStructGetData($tBitmapData_Dest, "Scan0")
    Local Const $tPixel_Dest = DllStructCreate("int[" & $iW * $iH & "];", $iScan0_Dest)

    Local Const $tBitmapData = _GDIPlus_BitmapLockBits($hImage, 0, 0, $iW - 1, $iH - 1, $GDIP_ILMREAD, $GDIP_PXF32ARGB)
    Local Const $iScan0 = DllStructGetData($tBitmapData, "Scan0")
    Local Const $tPixel = DllStructCreate("int[" & $iW * $iH & "];", $iScan0)
    Local $iX, $iY, $iRowOffset

    For $iY = 0 To $iH - 1
        $iRowOffset = $iY * $iW + 1
        For $iX = 0 To $iW - 1
            DllStructSetData($tPixel_Dest, 1, __Median_Value($iX, $iY, $fRadius, $tPixel, $iW, $iH), $iRowOffset + $iX)
            $fProg += 1
        Next
    Next

    _GDIPlus_BitmapUnlockBits($hImage, $tBitmapData)
    _GDIPlus_BitmapUnlockBits($hBitmap_Dest, $tBitmapData_Dest)
    _GDIPlus_ImageSaveToFile($hBitmap_Dest, @ScriptDir & "\Filter_Median" & $fRadius & "_" & @YEAR & @MON & @MDAY & @MIN & @SEC & ".png")
    If $bGDI Then
        Local $hGDIBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap_Dest)
        _GDIPlus_BitmapDispose($hBitmap_Dest)
        Return $hGDIBitmap
    EndIf
    Return $hBitmap_Dest
EndFunc

Func __Median_Value($iPosX, $iPosY, $fRadius, $tPixel, $iW, $iH)
    Local $iX, $iY, $aColors[1000], $iColors = 0, $iSize = $iW * $iH - 1, $iOff, $e
    For $iX = $iPosX - $fRadius To $iPosX + $fRadius
        For $iY = $iPosY - $fRadius To $iPosY + $fRadius
            $iOff = 1 + $iY * $iW + $iX
            $aColors[$iColors] = DllStructGetData($tPixel, 1, $iOff < 1 ? 1 : $iOff > $iSize ? $iSize : $iOff)
            $iColors += 1
        Next
    Next
    ReDim $aColors[$iColors]
;~  _ArraySort($aColors, 0)
    $e = $iColors - 1
    __ArrayQuickSort1D($aColors, 0, $e)
    Local $iMid = Floor($iColors / 2), $iMedian
    If BitAND($iColors, 1) Then
        $iMedian = Int($aColors[$iMid + 1])
    Else
        $iMedian = Int(($aColors[$iMid] + $aColors[$iMid + 1]) / 2)
    EndIf
    Return $iMedian
EndFunc
#EndRegion

 

 

 

 

_GDIPlus_BitmapApplyFilter v0.9.8 build 2024-04-17 beta.7z

Edited April 17 by UEZ
Update

[wakillon]

No, now you are not a newbie in FreeBasic, but an advanced user 

The effects are beautiful and your work is fantastic!
Succeed to adapt GDI functions used with AutoIt in FreeBASIC is downright genial!
The execution time is so fast !

A so small dll who can give so great effects, you deserve to be named the GDI King ! 

Thanks a lot ! 

[mLipok]

Looks impresive.

mLipok

[UEZ]

@wakillon / @mLipok: thanks for your feedback!

 

Small Update:

• Added UDF headers
• speeded up OilPainting, Dilatation, Erosion and Kuwahara functions (GdipBitmapGetPixel / GdipBitmapSetPixel is too slow)

 

I compiled the DLL with SSE2 option. I hope it will work also for you.

Edited June 25, 2016 by UEZ

[Lakes]

I had to look up what the Kuwahara (interesting name) function was.

[wakillon]

I have tested previous version and latest for Kuwahara func and it's 6X faster ! 

Edit : for a png (3200x2400) it's ~ 10X faster ! 

Very good improvement ! 

Edited June 25, 2016 by wakillon

[UEZ]

When I understood multi threading properly I will add it to some of the functions.

[dmob]

Wow!! is all I can say... 

[wakillon]

5 hours ago, UEZ said:

When I understood multi threading properly I will add it to some of the functions.

UEZ, please do a pause for avoid a brain overheating ! 

[UEZ]

Just now, wakillon said:

UEZ, please do a pause for avoid a brain overheating ! 

Multi theading is more for women... 

 

I think I've understood the concept of mt but I need to do several tests to fully cover it.

[wakillon]

Pff...and you said you were a newbie !
What modesty ! 

[UEZ]

9 minutes ago, wakillon said:

Pff...and you said you were a newbie !
What modesty ! 

But that's the truth. I started with FB 3-4 weeks ago because I "tasted blood" to speed up that GDI+ stuff and I must say it is very powerful like a stallion.

Not too hard to learn because it has similar AutoIt syntax like most BASIC languages.

Edited June 25, 2016 by UEZ

[wakillon]

I agree with similar syntax but variables declaration seems to be more complex !

[UEZ]

Updated to _GDIPlus_BitmapApplyFilter v0.9.3 build 2016-07-08 beta

[wakillon]

Nice new effects ! 

Bravo UEZ ! 

 

[Jardz]

Truly amazing!! Thank you UEZ!

I'd love to know the steps you did to achieve unsharp masking in GDI+ 

 

[UEZ]

9 minutes ago, Jardz said:

Truly amazing!! Thank you UEZ!

I'd love to know the steps you did to achieve unsharp masking in GDI+ 

 

The issue is not GDI+ but speed. You have to calculate each pixel separately which is a pain doing it with AutoIt.

Doing it with AutoIt takes ~10-15 times longer!

[Jardz]

Thanks UEZ,

I was hoping a function within GDI or GDI+ would do the hard work for me.

I was looking at MaskBlt in GDI but I don't think it would work.

 

 

[UEZ]

This is how convolution works in AutoIt using GDI+

expandcollapse popup

#include <GDIPlus.au3>

Global $sFile = FileOpenDialog("Select an image", "", "Image (*.jpg;*.png;*.bmp;*.gif)")
If @error Then Exit

_GDIPlus_Startup()
Global $hImage = _GDIPlus_ImageLoadFromFile($sFile)
If @error Then
    _GDIPlus_Shutdown()
    Exit
EndIf

Global $aMatrix_Unsharp_3x3[3][3] = [[-1, -1, -1], _
                                     [-1,  9, -1], _
                                     [-1, -1, -1]]

Global $aDim = _GDIPlus_ImageGetDimension($hImage)
Global $hGUI = GUICreate("GDI+", $aDim[0], $aDim[1])
Global $iPic = GUICtrlCreatePic("", 0, 0, $aDim[0], $aDim[1])

Global Const $STM_SETIMAGE = 0x0172
Global $fTimer = TimerInit()
Global $hBitmap = _GDIPlus_BitmapApplyFilter_Convolution($hImage, $aMatrix_Unsharp_3x3)
ConsoleWrite("Finished in " & TimerDiff($fTimer) & " ms." & @CRLF)
Global $hBmp_GDI = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
_WinAPI_DeleteObject(GUICtrlSendMsg($iPic, $STM_SETIMAGE, $IMAGE_BITMAP, $hBmp_GDI))

GUISetState()

Do
Until GUIGetMsg() = -3

_WinAPI_DeleteObject($hBmp_GDI)
_GDIPlus_ImageDispose($hBitmap)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_Shutdown()


Func _GDIPlus_BitmapApplyFilter_Convolution($hImage, $aMatrix, $fFactor = 1.0, $fBias = 0.0)
    If Not IsPtr($hImage) Then Return SetError(1, 0, 0)
    If Not IsArray($aMatrix) Then Return SetError(2, 0, 0)
    If UBound($aMatrix, 2) < 3 Then Return SetError(3, 0, 0)
    Local $aDim = _GDIPlus_ImageGetDimension($hImage)
    If @error Then Return SetError(4, 0, 0)
    Local $iW = $aDim[0], $iH = $aDim[1]
    Local $filterHeight = UBound($aMatrix), $filterWidth = UBound($aMatrix, 2)
    Local $tConvolution = DllStructCreate("float fMatrix[" & $filterHeight * $filterWidth & "]"), $iX, $iY, $i = 1
    For $iY = 0 To $filterHeight - 1
        For $iX = 0 To $filterWidth - 1
            $tConvolution.fMatrix(($i)) = $aMatrix[$iY][$iX]
            $i += 1
        Next
    Next

    Local $fW = $filterWidth / 2, $fH = $filterHeight / 2, $iRowOffset

    Local $tBitmapData = _GDIPlus_BitmapLockBits($hImage, 0, 0, $iW, $iH)
    Local $tPixel = DllStructCreate("int argb[" & $iW * $iH & "]", $tBitmapData.Scan0)

    Local $hBitmap_Converted = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    Local $tBitmapData_Convolution = _GDIPlus_BitmapLockBits($hBitmap_Converted, 0, 0, $iW, $iH, $GDIP_ILMWRITE, $GDIP_PXF32ARGB)
    Local $tPixel_Convolution = DllStructCreate("int argb[" & $iW * $iH & "]", $tBitmapData_Convolution.Scan0)

    Local $filterX, $filterY, $fRedSum, $fRedSumX, $fRedSumY, $fGreenSum, $fGreenSumX, $fGreenSumY, $fBlueSum, $fBlueSumX, $fBlueSumY, $fSum, _
          $imageX, $imageY, $c, $iARGB, $iR, $iG, $iB, $fMatrix
    For $iY = 0 To $iH - 1
        $iRowOffset = $iY * $iW + 1
        For $iX = 0 To $iW - 1
            $fRedSum = 0.0
            $fRedSumX = 0.0
            $fRedSumY = 0.0
            $fGreenSum = 0.0
            $fGreenSumX = 0.0
            $fGreenSumY = 0.0
            $fBlueSum = 0.0
            $fBlueSumX = 0.0
            $fBlueSumY = 0.0
            $fSum = 0.0
            $i = 1
            For $filterY = 0 To $filterHeight - 1
                For $filterX = 0 To $filterWidth - 1
                    $imageX = 1 + Mod(Int($iX - $fW + $filterX + $iW), $iW)
                    $imageY = 1 + Mod(Int($iY - $fH + $filterY + $iH), $iH)
                    $c = $tPixel.argb(($imageY * $iW + $imageX))
                    $iR = BitAND(BitShift($c, 16), 0xFF)
                    $iG = BitAND(BitShift($c, 8), 0xFF)
                    $iB = BitAND($c, 0xFF)
                    $fMatrix = $tConvolution.fMatrix(($i))
                    $fRedSum += $iR * $fMatrix
                    $fGreenSum += $iG * $fMatrix
                    $fBlueSum += $iB * $fMatrix
                    $fSum += $fMatrix
                    $i += 1
                Next
            Next
            $fSum = $fSum <= 0 ? 1.0 : $fSum
            $iARGB = 0xFF000000 + _
                     BitShift(Min(Abs(Int($fFactor * $fRedSum / $fSum + $fBias)), 255), -16) + _
                     BitShift(Min(Abs(Int($fFactor * $fGreenSum / $fSum + $fBias)), 255), -8) + _
                              Min(Abs(Int($fFactor * $fBlueSum / $fSum + $fBias)), 255)
            $tPixel_Convolution.argb(($iRowOffset + $iX)) = $iARGB
        Next
    Next
    _GDIPlus_BitmapUnlockBits($hBitmap, $tBitmapData_Convolution)
    _GDIPlus_BitmapUnlockBits($hBitmap, $tBitmapData)
    Return $hBitmap_Converted
EndFunc

Func Min($a, $b)
    If $a < $b Then Return $a
    Return $b
EndFunc

Compare the speed to the DLL version. 

Edited July 11, 2016 by UEZ

[Jardz]

Thanks UEZ that's brilliant!!

You weren't wrong about the speed 

 

It'll take me a few days to fully understand it, but it will teach me a lot so thank you very much!!!