Username/Password Webpage | Username works, password doesnt

[kelso]

Hello,

 

I am trying to automate the login window for mimecast. if I inspect element for the user name, I get the following:

I can also pass that stage in my script using:

#include <IE.au3>

Global $oIE = _IECreate("https://webmail-us.mimecast.com/")
Global $oForm = _IEFormGetObjByName($oIE, "loginForm")
Global $oUser = _IEFormElementGetObjByName($oForm, "username")
Global $oPass = _IEFormElementGetObjByName($oForm, "password")
_IEDocInsertText($oUser, "test@gmail.com")
_IEFormSubmit($oForm, 0) ;this works
sleep(5000)
_IEDocInsertText($oPass, "Password123") ; this doesn't nothing is inputted to the password field.

If I inspect element for password, I get:

Yet nothing is adding into the password field. any ideas?

 

Thanks,

Kelso

[mLipok]

Try this:

#include <IE.au3>

Global $oIE = _IECreate("https://webmail-us.mimecast.com/",1)
Global $oPass = _IEGetObjById($oIE, "editPassword")
Global $oUser = _IEGetObjById($oIE, "editUsername")
Global $oSubmit = _IEGetObjById($oIE, "submitLink")
_IEDocInsertText($oUser, "test@gmail.com")
_IEDocInsertText($oPass, "Password123") ; this doesn't nothing is inputted to the password field.
_IEAction($oSubmit,'click')

 

[MichaelHB]

The form changes after submiting the email, so you need to grab the form again (@kelso  you can see that if you look at the output error of your script). Try this:

#include <IE.au3>

Local $oIE = _IECreate("https://webmail-us.mimecast.com/")
If Not IsObj($oIE) Then Exit ConsoleWrite("Error in $oIE" & @CRLF)

Local $oForm = _IEFormGetObjByName($oIE, "loginForm")
If Not IsObj($oForm) Then Exit ConsoleWrite("Error in $oForm" & @CRLF)

Local $oUser = _IEFormElementGetObjByName($oForm, "username")
If Not IsObj($oUser) Then Exit ConsoleWrite("Error in $oUser" & @CRLF)

$oUser.fireEvent("OnClick")
_IEFormElementSetValue($oUser, "test@gmail.com")

$oSubmit = _IEGetObjById($oIE, "submitLink")
If Not IsObj($oSubmit) Then Exit ConsoleWrite("Error in $oSubmit" & @CRLF)

_IEAction($oSubmit, "click")
_IELoadWait($oIE)

Local $oForm2 = _IEFormGetObjByName($oIE, "loginForm")
If Not IsObj($oForm2) Then Exit ConsoleWrite("Error in $oForm2" & @CRLF)

Local $oPass = _IEFormElementGetObjByName($oForm2, "password")
If Not IsObj($oPass) Then Exit ConsoleWrite("Error in $oPass" & @CRLF)

_IEFormElementSetValue($oPass, "password")

$oSubmit2 = _IEGetObjById($oIE, "submitLink")
If Not IsObj($oSubmit2) Then Exit ConsoleWrite("Error in $oSubmit2" & @CRLF)

_IEAction($oSubmit2, "click")
_IELoadWait($oIE)

Exit