[Solved] Skip/check AutoIt COM object Error

[Trong]

How can I check if there is errors to ignore?
==> The requested action with this object has failed.:
 

Global $aURL = "https://www.autoitscriptA.com"

Local $urlStatus = _URLStatus($aURL)

If @error Then MsgBox(48, "Error: " & @error, "Connection problem: " & $urlStatus & @CRLF & "URL: " & $aURL)
If $urlStatus <> 200 Then
    MsgBox(48, "Status", "Connection problem: " & $urlStatus & @CRLF & "URL: " & $aURL)
Else
    MsgBox(32, "Status", "Connection Successful!" & @CRLF & "URL: " & $aURL)
EndIf

Func _URLStatus($aURL)
    $oHTTP = ObjCreate("WinHttp.WinHttpRequest.5.1")
    $oHTTP.Open("HEAD", $aURL, False)
    If @error Then Return SetError(1, 0, 0)
    $oHTTP.Send()
    If @error Then Return SetError(2, 0, 0)
    Return $oHTTP.Status = 200
EndFunc   ;==>_URLStatus

 

Solved:

Global $oErrorHandler = ObjEvent("AutoIt.Error", "_COMErrFunc")

Global $sURL = "https://www.autoitscriptA.com/forum/topic/aloha"

Global $urlStatus = _URLStatus($sURL)

Switch $urlStatus
    Case 200
        MsgBox(32, "Status: " & $urlStatus, "Connection Successful!" & @CRLF & "URL: " & $sURL)
    Case 404
        MsgBox(32, "Status: " & $urlStatus, "Connection Successful!" & @CRLF & "URL Not Found: " & $sURL)
    Case 105
        MsgBox(48, "Status: " & $urlStatus, "Connection error: ERR_NAME_NOT_RESOLVED" & @CRLF & "URL is Not Found: " & $sURL)
    Case Else
        MsgBox(48, "Status: " & $urlStatus, "Connection error!" & @CRLF & "URL: " & $sURL)
EndSwitch

Func _URLStatus($aURL)
    Local $oHTTP = ObjCreate("WinHttp.WinHttpRequest.5.1")
    $oHTTP.Open("HEAD", $aURL, False)
    If @error Then Return SetError(1, @error, 0)
    $oHTTP.Send()
    If @error Then Return SetError(2, @error, 105) ;Error 105 (net::ERR_NAME_NOT_RESOLVED)
    Local $oStatus = $oHTTP.Status
    If @error Then Return SetError(3, @error, 118) ;Error 118 (net::ERR_CONNECTION_TIMED_OUT)
;~  $oErrorHandler = 0
    Return $oStatus
EndFunc   ;==>_URLStatus

Func _COMErrFunc()
    ; Do nothing special, just check @error after suspect functions.
EndFunc   ;==>_COMErrFunc

 

Edited May 13, 2016 by Trong
Solved

[mLipok]

You should use COM Error Handler.
Check for:

ObjEvent ( "AutoIt.Error" [, "function"] )

 

The first example for ObjEvent() in HelpFile shows how to handle COM Errors

Edited May 13, 2016 by mLipok