[SOLVED] Not support RT_PNG ? Resources/EX UDF and AutoIt3Wrapper

[Trong]

I can not find the ID of resources RT_PNG and can not use AutoIt3Wrapper to add resources RT_PNG
I have to use RT_BITMAP to replace RT_PNG.

Someone knows ID of RT_PNG?

 

Local $aRESOURCE_TYPES[24] = ["RT_CURSOR", "RT_BITMAP", "RT_ICON", "RT_MENU", "RT_DIALOG", "RT_STRING", "RT_FONTDIR", "RT_FONT", "RT_ACCELERATOR", "RT_RCDATA", "RT_MESSAGETABLE", "RT_GROUPCURSOR", "", "RT_GROUPICON", "", "RT_VERSION", "RT_DLGINCLUDE", "", "RT_PLUGPLAY", "RT_VXD", "RT_ANICURSOR", "RT_ANIICON", "RT_HTML", "RT_MANIFEST"]

Global Const $RT_CURSOR = 1
Global Const $RT_BITMAP = 2
Global Const $RT_ICON = 3
Global Const $RT_MENU = 4
Global Const $RT_DIALOG = 5
Global Const $RT_STRING = 6
Global Const $RT_FONTDIR = 7
Global Const $RT_FONT = 8
Global Const $RT_ACCELERATOR = 9
Global Const $RT_RCDATA = 10
Global Const $RT_MESSAGETABLE = 11
Global Const $RT_GROUP_CURSOR = 12
Global Const $RT_GROUP_ICON = 14
Global Const $RT_VERSION = 16
Global Const $RT_DLGINCLUDE = 17
Global Const $RT_PLUGPLAY = 19
Global Const $RT_VXD = 20
Global Const $RT_ANICURSOR = 21
Global Const $RT_ANIICON = 22
Global Const $RT_HTML = 23
Global Const $RT_MANIFEST = 24

Resources UDF

ResourcesEX UDF

Edited May 3, 2016 by VIP

[BrewManNH]

It doesn't support it because RT_PNG doesn't exist.

https://msdn.microsoft.com/en-us/library/windows/desktop/ms648009%28v=vs.85%29.aspx

[Trong]

How I can get PNG resource?

 

[Jos]

Just:

#AutoIt3Wrapper_Res_File_Add=test.png,png

should do it..

Jos

[Trong]

2 minutes ago, Jos said:

Just:

#AutoIt3Wrapper_Res_File_Add=test.png,png

should do it..

Jos

Yeah!

and How I can get PNG resource from AutoIt?
Resources UDF  need ID of resource type, not name "PNG"!

[Jos]

This script will also retrieve the resource from the compiled script and write it to another file:

#AutoIt3Wrapper_Res_File_Add=test.png,png

#include <WinAPIRes.au3>
#include <WinAPIInternals.au3>

Local $bBytes = _GetResourceAsBytes("PNG")
If @error Then
    ; Resource not found
Else
    FileDelete("testOut.png")
    FileWrite("testOut.png", $bBytes)
EndIf

Func _GetResourceAsBytes($sResName, $seq=1)
    Local $hMod = _WinAPI_GetModuleHandle(Null)
    Local $hRes = _WinAPI_FindResource($hMod, $sResName, $seq)
    If @error Or Not $hRes Then Return SetError(1, 0, 0)
    Local $dSize = _WinAPI_SizeOfResource($hMod, $hRes)
    If @error Or Not $dSize Then Return SetError(2, 0, 0)
    Local $hLoad = _WinAPI_LoadResource($hMod, $hRes)
    If @error Or Not $hLoad Then Return SetError(3, 0, 0)
    Local $pData = _WinAPI_LockResource($hLoad)
    If @error Or Not $pData Then Return SetError(4, 0, 0)
    Local $tBuffer = DllStructCreate("byte[" & $dSize & "]")
    _WinAPI_MoveMemory(DllStructGetPtr($tBuffer), $pData, $dSize)
    Return DllStructGetData($tBuffer, 1)
EndFunc

Jos