[Solved] Calculate/Compare Functions speed ?

[DrAhmed]

Hey 

I've these two functions to do a base64 conversation , Is there any way to compare the exact speed of both of them ?

expandcollapse popup

Func _Base64Encode($input)

    $input = Binary($input)

    Local $struct = DllStructCreate("byte[" & BinaryLen($input) & "]")

    DllStructSetData($struct, 1, $input)

    Local $strc = DllStructCreate("int")

    Local $a_Call = DllCall("Crypt32.dll", "int", "CryptBinaryToString", _
            "ptr", DllStructGetPtr($struct), _
            "int", DllStructGetSize($struct), _
            "int", 1, _
            "ptr", 0, _
            "ptr", DllStructGetPtr($strc))

    If @error Or Not $a_Call[0] Then
        Return SetError(1, 0, "") ; error calculating the length of the buffer needed
    EndIf

    Local $a = DllStructCreate("char[" & DllStructGetData($strc, 1) & "]")

    $a_Call = DllCall("Crypt32.dll", "int", "CryptBinaryToString", _
            "ptr", DllStructGetPtr($struct), _
            "int", DllStructGetSize($struct), _
            "int", 1, _
            "ptr", DllStructGetPtr($a), _
            "ptr", DllStructGetPtr($strc))

    If @error Or Not $a_Call[0] Then
        Return SetError(2, 0, ""); error encoding
    EndIf

    Return DllStructGetData($a, 1)

EndFunc   ;==>_Base64Encode

 

Func _Base64Encode($sData)
    Local $oXml = ObjCreate("Msxml2.DOMDocument")
    If Not IsObj($oXml) Then
        SetError(1, 1, 0)
    EndIf

    Local $oElement = $oXml.createElement("b64")
    If Not IsObj($oElement) Then
        SetError(2, 2, 0)
    EndIf

    $oElement.dataType = "bin.base64"
    $oElement.nodeTypedValue = Binary($sData)
    Local $sReturn = $oElement.Text

    If StringLen($sReturn) = 0 Then
        SetError(3, 3, 0)
    EndIf

    Return $sReturn
EndFunc   ;==>_Base64Encode

 

Edited April 29, 2016 by DrAhmed

[JLogan3o13]

@DrAhmed look at TimerInit() and TimerDiff() in the help file. You should be able to add that in to each of your functions to get an idea of the time they take.

[DrAhmed]

28 minutes ago, JLogan3o13 said:

@DrAhmed look at TimerInit() and TimerDiff() in the help file. You should be able to add that in to each of your functions to get an idea of the time they take.

Could you give me an example please ?

[JLogan3o13]

@DrAhmed There is an awesome example...in the help file for TimerDiff:

Add a TimerInit() to the top of your function, and then a TimerDiff right before your Return statement, done.

[Danyfirex]

Hello.

#include <String.au3>




Local $sString = _StringRepeat("Hello Word", 1000)
Local $hTimer = TimerInit()
For $i = 1 To 100
    _Base64Encode($sString)
Next
Local $iDiff = TimerDiff($hTimer)

ConsoleWrite("_Base64Encode time elapsed: " & $iDiff & @CRLF)


$hTimer = TimerInit()
For $i = 1 To 100
    _Base64EncodeMsxml($sString)
Next
 $iDiff = TimerDiff($hTimer)

ConsoleWrite("_Base64EncodeMsxml time elapsed: " & $iDiff & @CRLF)

Saludos

[JLogan3o13]

Not exactly the "teach a man to fish" method, @Danyfirex

[Danyfirex]

15 minutes ago, JLogan3o13 said:

Not exactly the "teach a man to fish" method, @Danyfirex

mine is more like let them choose if want to learn  or want just the fish till teacher dies. lol

 

Saludos