ListView and Gui Pic background help [SOLVED]

[rootx]

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

Global $bChanged = False

$hGUI = GUICreate("Test", 500, 500)
 GUISetBkColor(0xE0FFFF)
$Pic = GUICtrlCreatePic(@ScriptDir&"your_background.jpg", 0, 0, 1024, 600)
GUICtrlSetState(-1, $GUI_DISABLE)

$cLV = GUICtrlCreateListView("Column 1", 10, 10, 200, 200)
$hLV = GUICtrlGetHandle($cLV)

For $i = 0 To 19
    GUICtrlCreateListViewItem("Item " & $i, $cLV)
Next

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    If $bChanged Then
        $j = _GUICtrlListView_GetSelectedIndices($hLV)
        ConsoleWrite($j & @CRLF)
        $bChanged = False
    EndIf

WEnd

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = $hLV

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_CLICK
                    $tStruct = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    $Index = DllStructGetData($tStruct, "Index")
                            Local $iItemText = _GUICtrlListView_GetItemText($cLV,DllStructGetData($tStruct, "Index"),1)
                            $item = StringSplit(_GUICtrlListView_GetItemTextString($cLV, $Index),'|')
                            $item = $item[1]
                            ConsoleWrite($item & @CRLF)
                            GUICtrlSetImage($Pic,@ScriptDir&"your_background.jpg")

                Case $LVN_KEYDOWN
                    $tStruct = DllStructCreate($tagNMLVKEYDOWN, $lParam)
                    $iKey = DllStructGetData($tStruct, "VKey")
                    Switch $iKey
                        Case 38 ; Up, Down
                            $bChanged = True
                            GUICtrlSetImage($Pic,@ScriptDir&"your_background.jpg")

                        Case 40
                            $bChanged = True
                            GUICtrlSetImage($Pic,@ScriptDir&"your_background.jpg")
                    EndSwitch

            EndSwitch

    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

 

I created a listview with icons and click control to change the background and works very well,  I tried to enter the up and down controls, but in this case the listview disappears , you know how to fix it.

my script is long so.. I copied an example from the forum "Melba" and added the necessary just to show you.

THX

Edited April 29, 2016 by rootx

[Melba23]

rootx,

Remove the GUICtrlSetImage call from within the handler and place it in the If $bChanged Then section:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>

Global $bChanged = False

$hGUI = GUICreate("Test", 500, 500)
GUISetBkColor(0xE0FFFF)
$Pic = GUICtrlCreatePic("Your jpg", 0, 0, 1024, 600)
GUICtrlSetState(-1, $GUI_DISABLE)

$cLV = GUICtrlCreateListView("Column 1", 10, 10, 200, 200)
$hLV = GUICtrlGetHandle($cLV)

For $i = 0 To 19
    GUICtrlCreateListViewItem("Item " & $i, $cLV)
Next

GUISetState()

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

    If $bChanged Then
        $j = _GUICtrlListView_GetSelectedIndices($hLV)
        ConsoleWrite($j & @CRLF)
        $bChanged = False
        GUICtrlSetImage($Pic, "Your jpg") ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    EndIf

WEnd

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    $hWndListView = $hLV

    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $NM_CLICK
                    $tStruct = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    $Index = DllStructGetData($tStruct, "Index")
                    Local $iItemText = _GUICtrlListView_GetItemText($cLV, DllStructGetData($tStruct, "Index"), 1)
                    $item = StringSplit(_GUICtrlListView_GetItemTextString($cLV, $Index), '|')
                    $item = $item[1]
                    ConsoleWrite($item & @CRLF)
                    $bChanged = True ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

                Case $LVN_KEYDOWN
                    $tStruct = DllStructCreate($tagNMLVKEYDOWN, $lParam)
                    $iKey = DllStructGetData($tStruct, "VKey")
                    Switch $iKey
                        Case 38, 40
                            $bChanged = True
                    EndSwitch

            EndSwitch

    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_NOTIFY

M23

[rootx]

THX work,  I use your method to handle up and down controls and I fix my code.

 

Edited April 29, 2016 by rootx