_ArrayUnique bug?

[maniootek]

I don't know if I do something wrong but this code fail for me:

#include <Array.au3>
local $array[0][3]
_arrayAdd($array, "row1|unique|row1")
_arrayAdd($array, "ro2|unique|row2")
_ArrayDisplay($array)
$newarray = _ArrayUnique($array, 2)
_ArrayDisplay($newarray)

 

[BrewManNH]

The tertiary operator can't be used that way, use If/Then instead.

[czardas]

@BrewManNH I'm not sure what you mean. The tertiary operator can be used like that, also without the brackets. The issue has to be elsewhere.

Local $aVar = [[True]]
;Local $aVar = [True]
Local $iDims = UBound($aVar, 0)
Local $sMsg = ( ($iDims = 1) ? ($aVar[0]) : ($aVar[0][0]) )
MsgBox(0, "", $sMsg)

I thought Melba23 had a fix for problems associated with this function.

[iamtheky]

can we always call it tertiary now, and defend it vigorously?

[czardas]

LOL. I suppose it's best to call it ternary. We'll change the name of the ternary maths counting system to 'base 3' and never have to be confused again. 

[BrewManNH]

You're right of course about the ternary operator. Stupid on my part to not test it.

The bug in _ArrayUnique in that line is that it's got the $iColumn and $iBase variables in the wrong places, they're reversed.

 

[guinness]

Was this fixed in the beta?

[BrewManNH]

No, it was broken in a different way instead. Now it doesn't check to see if you're sending it a 2D array and assumes a 1D and errors when you use a 2D array.

; Autocheck of first element
    If $iIntType = $ARRAYUNIQUE_AUTO Then
        If IsInt($aArray[$iBase]) Then

 

[maniootek]

How to make a quick fix?

tried this but still got error

 

[czardas]

For the time being you could try my version _ArrayUniqueXD(). https://www.autoitscript.com/forum/topic/180467-arrayworkshop/ I'm still not entirely satisfied with _ArrayUniqueXD() and intend to rewrite it. If it does the job, consider this a temporary fix. You can switch back to using the Array UDF version later. Providing your array is not too large or contains a lot of duplicates, performance should be fine.

ArrayWorkshop is still in beta phase of development, so expect changes. You can remove functions that are not needed from the UDF, but you should not remove the lines #AU3Stripper_Off or #AU3Stripper_On. If you do remove some functions, be very careful not to remove any dependencies.

_ArrayUniqueXD() behaves differently, because it does not target data within an individual column: I don't quite understand the logic behind that. Instead, whole rows are compared to circumvent data loss.

Edited April 28, 2016 by czardas

[Melba23]

maniootek,

If you use this (taken from the next Beta where, fingers crossed,  we have finally got it right) it should work:

; Autocheck of first element
If $iIntType = $ARRAYUNIQUE_AUTO Then
    Local $vFirstElem = ( ($iDims = 1) ? ($aArray[$iBase]) : ($aArray[$iBase][$iColumn]) )
    If IsInt($vFirstElem) Then
        Switch VarGetType($vFirstElem)
            Case "Int32"
                $iIntType = $ARRAYUNIQUE_FORCE32
            Case "Int64"
                $iIntType = $ARRAYUNIQUE_FORCE64
        EndSwitch
    Else
        $iIntType = $ARRAYUNIQUE_FORCE32
    EndIf
EndIf

M23

[czardas]

I believe this produces more or less the same behaviour as the UDF version is meant to. Posting it here for future reference.

#include <Array.au3>
#include 'ArrayWorkshop.au3'

local $array[0][3]
_arrayAdd($array, "row1|unique|row1")
_arrayAdd($array, "ro2|unique|row2") ; according to _ArrayUniqueXD, this array is already unique in both dimensions

Local $iCol = 1
Local $aCol = _ExtractRegion($array, 2, $iCol) ; returns a 2D array with 1 column
_ArrayUniqueXD($aCol)

Local $newarray[UBound($aCol)][UBound($array, 2)], $iCount = 0
For $i = 0 To UBound($array) -1
    If $array[$i][$iCol] = $aCol[$iCount][0] Then
        For $j = 0 To Ubound($array, 2) -1
            $newarray[$iCount][$j] = $array[$i][$j]
        Next
        $iCount += 1
    EndIf
    If $iCount = UBound($aCol) Then ExitLoop
Next
_ArrayDisplay($newarray, 'unique')

@Melba23 Finger's crossed - I intend to steal some ideas from you. 

Edited April 28, 2016 by czardas