GUICtrlSetOnEvent using keys.

[gottygolly]

Out of curiosity is it possible to make this work?

GUICtrlSetOnEvent("{LEFT}","_Function") 

 

[Synapsee]

i think you should look arround HotKeySet or _IsPressed samples here :

https://www.autoitscript.com/autoit3/docs/libfunctions/_IsPressed.htm

https://www.autoitscript.com/autoit3/docs/functions/HotKeySet.htm

 

Edit : or not ^^

Edited April 26, 2016 by Synapsee

[Melba23]

gottygolly,

How about this:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Opt("GUIOnEventMode", 1)

$hGUI = GUICreate("Test", 500, 500)
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

$cDummy = GUICtrlCreateDummy()
GUICtrlSetOnEvent($cDummy, "_Dummy")

GUISetState()

 Local $aAccelKeys[1][2] = [["{LEFT}", $cDummy]]
GUISetAccelerators($aAccelKeys)

While 1
    Sleep(10)
WEnd

Func _Dummy()
    MsgBox($MB_SYSTEMMODAL, "Hi", "LEFT key pressed")
EndFunc

Func _Exit()
    Exit
EndFunc

M23

[gottygolly]

Thank you for the quick reply, I have worked with those functions in the past but I was wondering if it was possible to use GUICtrlSetOnEvent() instead of those.

Melba that works and I guess is the only way to do that, thank you for the quick replies

 

EDIT: typo

Edited April 26, 2016 by gottygolly