ExtMsgBox wrong width with fixed font

[AndyS01]

When I set ExtMsgBox to use fixed font, the width is calculated incorrectly, so text wraps.

my code:

#include <_ExtMsgBox.au3>
#include <Array.au3>

    _ExtMsgBoxSet(0, 0, -1, -1, 10, "courier new") ; Set _ExtMsgBox formatting

ShowAbout()

Func ShowAbout()
    Local $ar[1] = [0]

    _ArrayAdd($ar, "Program to bla bla bla.")
    _ArrayAdd($ar, "")
    _ArrayAdd($ar, "usage: " & "[-switch>] [<datafile>.csv]")
    _ArrayAdd($ar, "")
    _ArrayAdd($ar, "<-switch>:")
    _ArrayAdd($ar, "-h ....... Display this help information")
    _ArrayAdd($ar, "-nb ...... Do not create backup files.")
    _ArrayAdd($ar, "-regdel... Delete program relative registry items before")
    _ArrayAdd($ar, "           running (debug mode only)")
    _ArrayAdd($ar, "-ro ...... Do not modify the input file.")
    _ArrayAdd($ar, "-tail .... Launch 'Tail' to tail the debug output file")
    _ArrayAdd($ar, "")
    _ArrayAdd($ar, "Copyright 2011-2016, Andy Scharmer")
    _ExtMsgBox(8, "OK", "About", _ArrayToString($ar, @CRLF, 1))
    Return
EndFunc   ;==>ShowAbout

 

[Melba23]

AndyS01,

As explained in the UDF function headers, the normal max width of the ExtMsgBox is 370 pixels - as you have not altered this in the _ExtMsgBoxSet call, that is the width you get and so as the text is too wide to fit, it wraps. You need to increase the max width of the ExtMsgBox to fit the text. I did it this way:

#include <ExtMsgBox.au3>

ShowAbout()

Func ShowAbout()

    ; Create the string in a more logical manner
    Local $sString
    $sString &= "Program to bla bla bla." & @CRLF
    $sString &= @CRLF
    $sString &= "usage: " & "[-switch>] [<datafile>.csv]"
    $sString &= @CRLF
    $sString &= "<-switch>:" & @CRLF
    $sString &= "-h ....... Display this help information" & @CRLF
    $sString &= "-nb ...... Do not create backup files." & @CRLF
    $sString &= "-regdel... Delete program relative registry items before" & @CRLF
    $sString &= "           running (debug mode only)" & @CRLF
    $sString &= "-ro ...... Do not modify the input file." & @CRLF
    $sString &= "-tail .... Launch 'Tail' to tail the debug output file" & @CRLF
    $sString &= @CRLF
    $sString &= "Copyright 2011-2016, Andy Scharmer" & @CRLF

    ; Size the string
    $aRet = _StringSize($sString, 10, Default, Default, "Courier New")

    ; Now set the ExtMsgBox to a width which will accommodate the widest line
    _ExtMsgBoxSet(0, 0, -1, -1, 10, "Courier New", $aRet[2] + 70) ; 70 = 50 for the icon + 2 borders of 10

    ; And it fits!!!
    _ExtMsgBox(8, "OK", "About", $sString)

EndFunc   ;==>ShowAbout

In fact you can increase the ExtMsgBox width to any value larger than the string width + 70 and the UDF will adjust the width to fit. All clear?

M23

Edited April 23, 2016 by Melba23
Additional info

[AndyS01]

Works like a champ!  Thank you