Multiple IF statements.

[vestanpance]

Hi all, 

It's rare i post anything as i usually find the answers i want by browsing the forum.. but i can't get this statement right, and i could well be doing it wrong anyway and i was hoping someone could either correct my code or tell me i'm doing things the hard way around..

The function below is launched via a system tray Menu/GUI (using code from "ModernMenu UDF by Holger Kotsch") So i choose Ultimatix from the Menu and it launches the function.

To run though the code briefly:

It checks to see if Ultimatix.exe is present on the local machine first and if it isn't download it and then open the local file Ultimatix.exe. - It does that just fine.

It checks to see if Ultimatix.exe is present and if it is, check to see if the remote file (Ultimatix.exe) has a higher version revision. If it does, download the remote file overwriting the local file and then open the  local file Ultimatix.exe. - It does that just fine too.

However, if the local file exists AND it's the same revision as the remote file, it doesn't do anything and that's where i'm stuck..

Func Ultimatix() ;Launch Ultimatix
Local Const $sFilePath = @MyDocumentsDir & "\AutoIT_Toolbar\Toolbar Items\Apps\Ultimatix.exe"
Local $iFileExists = FileExists($sFilePath)

If $iFileExists Then
Local $LocalFile = FileGetVersion ($sFilePath, "FileVersion")
Local $RemoteFile = FileGetVersion("\\1x.2x.1x.8x\htdocs\downloads\software\AutoIT\Ultimatix.exe", "FileVersion")
Consolewrite("The file exists" & @CRLF)

If $RemoteFile > $LocalFile Then
Local $hDownload = InetGet("http://1x.2x.1x.8x/downloads/software/AutoIT/Ultimatix.exe", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)
Do ; Wait for the download to complete by monitoring when the 2nd index value of InetGetInfo returns True.
Sleep(250)
Until InetGetInfo($hDownload, $INET_DOWNLOADCOMPLETE)
InetClose($hDownload) ; Close the handle returned by InetGet.
Consolewrite("Remote file is greater than local file" & @CRLF)
ShellExecute($sFilePath)
Elseif $LocalFile > $RemoteFile Then
Consolewrite("local file is greater than remote file" & @CRLF)
ShellExecute($sFilePath)
EndIf
Else
Local $hDownload = InetGet("http://1x.2x.1x.8x/downloads/software/AutoIT/Ultimatix.exe", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)
Do ; Wait for the download to complete by monitoring when the 2nd index value of InetGetInfo returns True.
Sleep(250)
Until InetGetInfo($hDownload, $INET_DOWNLOADCOMPLETE)
InetClose($hDownload) ; Close the handle returned by InetGet.
ShellExecute($sFilePath)
Consolewrite("I downloaded the file"  & @CRLF)
EndIf
EndFunc   ;==>Ultimatix

Have i tried to over complicate things or have i missed something a little bit obvious?

Many thanks in advance.

 

[markyrocks]

I would personally end all if statements before you enter the do statement.   Looks like all the do statements do the same thing anyway  (didn't look that closely).

 

Also the until part (I believe ) should be an expression not just a functiion call. Like InetGetInfo ($args.. whatever )<>""

would probably be best to pass InetGetInfo to a variable first like $iNetInfo=InetGetInfo($args....)

Then go.. until $iNetInfo<>""

Edited April 6, 2016 by markyrocks

[Jos]

9 minutes ago, vestanpance said:

check to see if the remote file (Ultimatix.exe) has a higher version revision

Not really as the FileGetVersion() returns a string in the format xx.xx.xx.xx! 
_VersionCompare() can do what you want.

Jos

 

[MichaelHB]

If the local file exists AND it's the same version as the remote file, what do you want it do to?

[vestanpance]

3 minutes ago, MichaelHB said:

If the local file exists AND it's the same version as the remote file, what do you want it do to?

I want to launch the local version of Ultimatix.exe.

Basically i want to do the following.

When the function is chosen from the menu:

Check to see if Ultimatix.exe is on the local machine. 

If Ultimatix.exe is NOT on the local machine, download it from the network drive and then launch the local Ultimatix.exe.

If Ultimatix.exe IS on the local machine, Is the remote version more up to date?

If the remote version of Ultimatix.exe is more up to date - download the newer version overwriting the older version and then execute the local Ultimatix.exe.

If the local version of Ultimatix.exe is the same as the remote version (so i haven't create a newer version of Ultimatix.exe and put it on a network drive) then just execute the version you have locally.

I hope i'm making sense 

[vestanpance]

14 minutes ago, Jos said:

Not really as the FileGetVersion() returns a string in the format xx.xx.xx.xx! 
_VersionCompare() can do what you want.

Jos

 

Hi Jos, thanks for your input..

Always learning, but i don't understand how to use the _VersionCompare for the two files.

If i use the code: 

Local $LocalFile = FileGetVersion ($sFilePath, "FileVersion")
Local $RemoteFile = FileGetVersion("\\1x.2x.1x.8x\htdocs\downloads\software\AutoIT\Ultimatix.exe", "FileVersion")
ConsoleWrite("The Local File Version is: " & $LocalFile & @CRLF & "The Remote File Version is: " & $RemoteFile & @CRLF)

I end up with the following result in the console:

The Local File Version is: 2.0.0.3
The Remote File Version is: 2.0.0.2

So for this instance, it doesn't download anything (because the remote file isn't newer) but what i mean is, FileGetVersion is serving it's purpose for me.... even if i am using it in the wrong way.. 

[MichaelHB]

First i would check Jos suggestion. Then see if this is what you are looking:

Func Ultimatix() ;Launch Ultimatix
    Local Const $sFilePath = @MyDocumentsDir & "\AutoIT_Toolbar\Toolbar Items\Apps\Ultimatix.exe"
    Local $iFileExists = FileExists($sFilePath)

    If $iFileExists Then
        Local $LocalFile = FileGetVersion ($sFilePath, "FileVersion")
        Local $RemoteFile = FileGetVersion("\\1x.2x.1x.8x\htdocs\downloads\software\AutoIT\Ultimatix.exe", "FileVersion")
        Consolewrite("The file exists" & @CRLF)

        If $RemoteFile > $LocalFile Then
            Local $hDownload = InetGet("http://1x.2x.1x.8x/downloads/software/AutoIT/Ultimatix.exe", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)
            
            Do ; Wait for the download to complete by monitoring when the 2nd index value of InetGetInfo returns True.
                Sleep(250)
            Until InetGetInfo($hDownload, $INET_DOWNLOADCOMPLETE)
            
            InetClose($hDownload) ; Close the handle returned by InetGet.
            Consolewrite("Remote file is greater than local file" & @CRLF)
            ShellExecute($sFilePath)
        Elseif $LocalFile >= $RemoteFile Then ;******** If Local File is greater or EQUAL RemoteFile just execute it
            Consolewrite("local file is greater than remote file" & @CRLF)
            ShellExecute($sFilePath)
        EndIf
    Else
        Local $hDownload = InetGet("http://1x.2x.1x.8x/downloads/software/AutoIT/Ultimatix.exe", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)
        
        Do ; Wait for the download to complete by monitoring when the 2nd index value of InetGetInfo returns True.
            Sleep(250)
        Until InetGetInfo($hDownload, $INET_DOWNLOADCOMPLETE)
        
        InetClose($hDownload) ; Close the handle returned by InetGet.
        ShellExecute($sFilePath)
        Consolewrite("I downloaded the file"  & @CRLF)
    EndIf
EndFunc   ;==>Ultimatix

 

[vestanpance]

Thank you so much MichaelHB, you cracked it... 

Works a treat...

Now to read and understand how you completed the statement, vs how i wrote it.

Also be looking at _VersionCompare() as advised by Jos to see how that works.

Thanks  very much to everyone who had input..

Much appreciated!

Daz

 

Edited April 6, 2016 by vestanpance
bad spelling :p

[MichaelHB]

Glad to help. 

[Jos]

Still think this if is wrong as indicated:  

If $RemoteFile > $LocalFile Then

 

20 minutes ago, vestanpance said:

Always learning, but i don't understand how to use the _VersionCompare for the two files.

The helpfile is your friend

Jos

[vestanpance]

17 minutes ago, Jos said:

Still think this if is wrong as indicated:  

If $RemoteFile > $LocalFile Then

 

The helpfile is your friend

Jos

The Helpfile and i are well acquainted  which in truth, is why i generally don't need to use the forums.

I looked at _VersionCompare() before settling with FileGetVersion because i wasn't getting the results i wanted.

I've modified the helpfile example to this. I think i have used it correctly?

Local $LocalFile = @MyDocumentsDir & "\AutoIT_Toolbar\Toolbar Items\Apps\Ultimatix.exe"
Local $RemoteFile = "\\10.228.167.84\htdocs\downloads\software\AutoIT\Ultimatix.exe"
Consolewrite(_VersionCompare($LocalFile, $RemoteFile) & @CRLF)

But i always get "1", which according to the helpfile means Version 1 is greater. Even if the remote file Version is greater.

However, if i check both .exe files (local and remote) using FileGetVersion, i get the same result for both files?

[Jos]

You obviously need to leave the FileGetVersion() for the 2 files in there and only change the If i mentioned!

Just put those 2 result variables in the UDF and bob's your uncle.

Jos

[mLipok]

First I would like to use TIDY as was used by @MichaelHB in post #7
Maybe then you can find more wise idea by yourself .

 

[vestanpance]

On 4/6/2016 at 6:20 PM, Jos said:

You obviously need to leave the FileGetVersion() for the 2 files in there and only change the If i mentioned!

Just put those 2 result variables in the UDF and bob's your uncle.

Jos

As they say on 'Who wants to be a Millionaire' ; It's only obvious if you know the answer... 

That said, this evening, i've understood what you meant by your previous comment and i've changed it to:

If $iFileExists Then
        Local $LocalFile = FileGetVersion($sFilePath, "FileVersion")
        Local $RemoteFile = FileGetVersion("\\10.228.167.84\htdocs\downloads\software\AutoIT\Ultimatix.exe", "FileVersion")
        Local $UpdateAvailable = _VersionCompare($LocalFile, $RemoteFile)

        If $UpdateAvailable = -1 Then
            Local $hDownload = InetGet("http://10.228.167.84/downloads/software/AutoIT/Ultimatix.exe", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)

So i hope i have understood your comments and direction.

Thanks to all for your input, patience and for pointing me in the right direction. 

[Jos]

Just now, vestanpance said:

So i hope i have understood your comments and direction.

Thanks to all for your input, patience and for pointing me in the right direction. 

That is indeed what I meant.  You're welcome

Jos