Help with inserting Null in a Base64 string

[TheDcoder]

I am really having a headache with this one...

expandcollapse popup

; #FUNCTION# ====================================================================================================================
; Name ..........: _Base64_Encode
; Description ...: Encode the $vData in Base64
; Syntax ........: _Base64_Encode($vData)
; Parameters ....: $vData               - $vData to Encode.
; Return values .: Success: Base64 encoded $vData in the form of a string.
;                  Failure: False and @error set to:
;                           1 - If "error calculating the length of the buffer needed"
;                           2 - If "error encoding"
; Author ........: trancexx
; Modified ......: Damon Harris (TheDcoder)
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _Base64_Encode($vData)
    $vData = Binary($vData)
    Local $tByteStruct = DllStructCreate("byte[" & BinaryLen($vData) & "]")
    DllStructSetData($tByteStruct, 1, $vData)
    Local $tIntStruct = DllStructCreate("int")
    Local $aDllCall = DllCall("Crypt32.dll", "int", "CryptBinaryToString", _
            "ptr", DllStructGetPtr($tByteStruct), _
            "int", DllStructGetSize($tByteStruct), _
            "int", 1, _
            "ptr", 0, _
            "ptr", DllStructGetPtr($tIntStruct))
    If @error Or Not $aDllCall[0] Then
        Return SetError(1, 0, False) ; error calculating the length of the buffer needed
    EndIf
    Local $tCharStruct = DllStructCreate("char[" & DllStructGetData($tIntStruct, 1) & "]")
    $aDllCall = DllCall("Crypt32.dll", "int", "CryptBinaryToString", _
            "ptr", DllStructGetPtr($tByteStruct), _
            "int", DllStructGetSize($tByteStruct), _
            "int", 1, _
            "ptr", DllStructGetPtr($tCharStruct), _
            "ptr", DllStructGetPtr($tIntStruct))
    If @error Or Not $aDllCall[0] Then
        Return SetError(2, 0, False) ; error encoding
    EndIf
    Return DllStructGetData($tCharStruct, 1)
EndFunc

ConsoleWrite(_Base64_Encode("jilles" & Null & "jilles" & Null & "sesame")) ; It should be "amlsbGVzAGppbGxlcwBzZXNhbWU="
Sleep(1000)

 

Thanks in Advance, TD.

Edited April 5, 2016 by TheDcoder
Changed Title

[Jos]

I see you started a second topic with "the Null" question. In C++ any regular string is terminated with a Null character, as explained in the other thread.
This means with the example you posted I guess the only characters encoded to Base64 are the characters before the first Null?

So what is it you are really trying here as a string in general never contains a Null character, only Binary data does?

Jos

 

[TheDcoder]

@Jos I am aware, but I was confused while deciding the Topic Title, will correct it...

But this didn't work either:

ConsoleWrite(_Base64_Encode("jilles" & Binary(Null) & "jilles" & Binary(Null) & "sesame"))

 

[Jos]

Did you read my whole post and do you have any questions after reading it? Also try answering the questions asked.
Might help if you first understand things before trying other similar things that wil also fail!

Jos

[Danyfirex]

NULL in AutoIt like a null ptr not null character.

 

YOu should do this

_Base64_Encode("jilles" & chr(0) & "jilles" & chr(0) & "sesame")

 

Saludos

 

[TheDcoder]

@Danyfirex Its "amlsbGVzAGppbGxlcwBzZXNhbWU=", that is not what I wanted...

@Jos Thanks for locking the topic, still reading your previous posts.

[TheDcoder]

17 minutes ago, Jos said:

This means with the example you posted I guess the only characters encoded to Base64 are the characters before the first Null?

No, all the characters are encoded in Base64. (expect the Null)

 

I also changed the topic

[Jos]

Let me see I understand this: So you want all characters except the Asc(0) characters encoded with Base64 and have leave the Asc(0) characters as is?

Jos

[TheDcoder]

Just now, Jos said:

So you want all characters except the Asc(0) characters encoded with Base64 and have leave the Asc(0) characters as is?

No, that is not what I want... What I want is:

jilles<NULL>jilles<NULL>sesame

encoded in Base64...

[Jos]

Ok, so what is wrong with the result from the code shown by Danyfirex as that looks close?

[TheDcoder]

Its looks close but that is not what I wanted, I want it to be exactly "amlsbGVzAGppbGxlcwBzZXNhbWU="

[Jos]

3 minutes ago, TheDcoder said:

 I want it to be exactly "amlsbGVzAGppbGxlcwBzZXNhbWU="

Try this:

ConsoleWrite(_Base64_Encode("jilles" & chr(0) & "jilles" & Chr(0) & "sesame")) ; It should be "amlsbGVzAGppbGxlcwBzZXNhbWU="

Jos

[TheDcoder]

@Jos

ConsoleWrite(_Base64_Encode("jilles" & chr(0) & "jilles" & Chr(0) & "sesame") = 'amlsbGVzAGppbGxlcwBzZXNhbWU=')

 

[Jos]

$x = _Base64_Encode("jilles" & chr(0) & "jilles" & Chr(0) & "sesame")
$x = StringReplace($x,@crlf,"")
ConsoleWrite($x & ":" & stringLen($x) & @CRLF) ; It should be "amlsbGVzAGppbGxlcwBzZXNhbWU="

if $x == 'amlsbGVzAGppbGxlcwBzZXNhbWU=' then
    ConsoleWrite("Yes!!!!" & @CRLF)
Else
    ConsoleWrite("No!!!!" & @CRLF)
EndIf

 

[TheDcoder]

@Jos Ummm... Must change my glasses . So that is what it was then... Thanks!

[Jos]

First thought my glasses weren't functioning properly as the consolewrite showed the correct string, but the additional @crlf was making your test fail.
Not sure why that is returned by the UDF.

Jos

[jchd]

I apologize for a typo I made in the other thread: I typed Asc(0) but meant Chr(0). Can't edit it after lockdown.  (Jos did it, thanks)

@TheDcoder

You really should start using NUL for the ASCII control char 0x00 and Null for the AutoIt (and SQL) "I don't know" keyword.

Edited April 6, 2016 by jchd

[TheDcoder]

@jchd Ah, understood

[Jos]

1 hour ago, jchd said:

Can't edit it after lockdown.

Fixed it.