Declaring and initializing multi-dimension arrays

[ChrisEnn]

Hi,

This is my first post here. I've searched through the help and these forums and haven't found what I'm looking for.

Although I have quite a bit of experience in programming, it's all quite a long time ago (COBOL and dBase/Clipper), and this is my first attempt to write something quite complex using AutoIt.

I'm writing an app that reads a single CSV file and then splits it into a number of separate arrays based on the 
sections in the original file. I then display each of the individual arrays in a ListView control.

In order to standardize my code I would like to declare the structure that each array/listview will have, by creating a
structure array that contains the following elements: 
- section name,
- number of columns,
- an array with the column headers,
- an array with the column widths

The last two sub-arrays will have a variable number of entries, equal to the second value, the number of columns.
Unfortunately, I can't get this to work, I keep getting syntax errors.

This is my structure array at present (note that the widths are just placeholders at present) :

Global $aStructures[10][4] = [_
["params",         3, ["parameter", "value", "comments"], [110, 150, 450] ], _
["notes",          1, ["note"], [500] ], _
["sizes",          8, ["name", "width", "height", "blockwidth", "blockheight", "hgridsize", "vgridsize", "comments"], [10, 10, 10, 10, 10, 10, 10, 10] ], _
["templates",      2, ["name", "comments"], [10, 10] ], _
["elements",      10, ["template", "name", "nature", "frontback", "left", "top", "width", "height", "font", "size"], [10, 10, 10, 10, 10, 10, 10, 10 10, 10] ], _
["schemes",        4, ["name", "frontbg", "backbg", "comments"], [10, 10, 10, 10] ], _
["elementcolours", 7, ["scheme", "element", "fg", "bg", "bg2", "gradtype", "gradval"], [10, 10, 10, 10, 10, 10, 10] ], _
["colours",        7, ["name", "r", "g", "b", "rgb", "hex", "sample"], [10, 10, 10, 10, 10, 10, 10] ], _
["sheets",         2, ["name", "comments"], [10, 10] ], _
["items",         10, ["sheet", "size", "template", "scheme", "qty", "f1", "f2", "f3", "f4", "f5"], [10, 10, 10, 10, 10, 10, 10, 10, 10, 10] ] _
]

So, two questions.

1/ Are such arrays allowed, with a variable number of dimensions ?
2/ If so, what am I doing wrong in the above code ?

Any help would be welcome.

Chris

 

Edited April 3, 2016 by ChrisEnn
removed code that wasn't between code tags

[jchd]

Variable dimensions aren't supported in AutoIt. You'll need to add dummy entries and possibly a count to hold the maximum dimension(s).

Edited April 3, 2016 by jchd

[trancexx]

You could maybe do it like this:

Global $aStructures = [ _
[["params"],         [3],  ["parameter", "value", "comments"],                                                             [110, 150, 450]] , _
[["notes"],          [1],  ["note"],                                                                                       [500]] , _
[["sizes"],          [8],  ["name", "width", "height", "blockwidth", "blockheight", "hgridsize", "vgridsize", "comments"], [10, 10, 10, 10, 10, 10, 10, 10]] , _
[["templates"],      [2],  ["name", "comments"],                                                                           [10, 10]] , _
[["elements"],       [10], ["template", "name", "nature", "frontback", "left", "top", "width", "height", "font", "size"],  [10, 10, 10, 10, 10, 10, 10, 10, 10, 10]] , _
[["schemes"],        [4],  ["name", "frontbg", "backbg", "comments"],                                                      [10, 10, 10, 10]] , _
[["elementcolours"], [7],  ["scheme", "element", "fg", "bg", "bg2", "gradtype", "gradval"],                                [10, 10, 10, 10, 10, 10, 10]] , _
[["colours"],        [7],  ["name", "r", "g", "b", "rgb", "hex", "sample"],                                                [10, 10, 10, 10, 10, 10, 10]] , _
[["sheets"],         [2],  ["name", "comments"],                                                                           [10, 10]] , _
[["items"],          [10], ["sheet", "size", "template", "scheme", "qty", "f1", "f2", "f3", "f4", "f5"],                   [10, 10, 10, 10, 10, 10, 10, 10, 10, 10]]  _
]

For $Row = 0 To UBound($aStructures) - 1
    ConsoleWrite($aStructures[$Row][0][0] & @CRLF)

    For $i = 0 To $aStructures[$Row][1][0] - 1
        ConsoleWrite(@TAB & $aStructures[$Row][2][$i])
        ConsoleWrite(" = " & $aStructures[$Row][3][$i] & @CRLF)
    Next

    ConsoleWrite(@CRLF)
Next

 

[InunoTaishou]

Could use a json UDF

expandcollapse popup

#include <GUIConstants.au3>
#include <WinApi.au3>
#include "Json.au3"

Global $sJsonString = '{"structure":{"params":[3,["parameter","value","comments"],[110,150,450]],"notes":[1,["note"],[500]],"sizes":[8,["name","width","height","blockwidth","blockheight","hgridsize","vgridsize","comments"],[10,10,10,10,10,10,10,10]],"templates":[2,["name","comments"],[10,10]],"elements":[10,["template","name","nature","frontback","left","top","width","height","font","size"],[10,10,10,10,10,10,10,10,10,10]],"schemes":[7,["scheme","element","fg","bg","bg2","gradtype","gradval"],[10,10,10,10,10,10,10]],"sheets":[2,["name","comments"],[10,10]],"colours":[10,["sheet","size","template","scheme","qty","f1","f2","f3","f4","f5"],[10,10,10,10,10,10,10,10,10,10]]}}'
Global $oJson = Json_Decode($sJsonString)
Global $hGui = GUICreate("Json Example", 800, 620)
Global $hEditJson = GUICtrlCreateEdit(Json_Encode($oJson) & @CRLF & Json_Encode($oJson, $JSON_PRETTY_PRINT, "\t", ",\r\n", "\r\n", ":"), 10, 10, 780, 280)
Global $hEditOut = GUICtrlCreateEdit("", 10, 330, 780, 280)
Global $hInput = GUICtrlCreateInput(".structure.sizes", 10, 300, 200, 20)
GUICtrlSetFont($hEditJson, 10, 400, 0, "Consolas")
GUICtrlSetFont($hEditOut, 10, 400, 0, "Consolas")
GUICtrlSetFont($hInput, 10, 400, 0, "Consolas")

GUISetState(@SW_SHOW, $hGui)

PrintStructure($oJson, ".structure.sizes")

GUIRegisterMsg($WM_COMMAND, WM_COMMAND)

While (True)
    Switch (GUIGetMsg())
        Case $GUI_EVENT_CLOSE
            GUIDelete($hGui)
            Exit 0
    EndSwitch
WEnd

Func PrintStructure(ByRef $Object, Const ByRef $sKey)
    Local $iParams = Json_Get($oJson, $sKey & "[0]")
    GUICtrlSetData($hEditOut, $iParams & " params for key " & $sKey & @CRLF)
    For $i = 0 To $iParams - 1
        GUICtrlSetData($hEditOut, GUICtrlRead($hEditOut) & $sKey & "[1][" & $i & "] = " & Json_Get($oJson, $sKey & "[1][" & $i & "]") & @CRLF)
        GUICtrlSetData($hEditOut, GUICtrlRead($hEditOut) & $sKey & "[2][" & $i & "] = " & Json_Get($oJson, $sKey & "[2][" & $i & "]") & ($i = $iParams -1 ? "" : @CRLF))
    Next
EndFunc   ;==>PrintStructure

Func WM_COMMAND($hWndFrom, $iMsg, $wParam, $lParam)
    Local $iCode = _WinAPI_HiWord($wParam)
    Local $iIDFrom = _WinAPI_LoWord ($wParam)
    Local $sKey = ""
    Local $sJson = ""
    Local $sJsonValue = ""

    Switch $iIDFrom
        Case $hInput
            Switch $iCode
                Case $EN_CHANGE
                    $sKey = StringRegExpReplace(GUICtrlRead($iIDFrom), "(?i)\.|structure", "")
                    $sJson = Json_Encode($oJson)
                    $sJsonValue = Json_Get($oJson, ".structure." & $sKey)
                    If (StringInStr($sJson, '"' & $sKey & '"')) Then
                        PrintStructure($oJson, ".structure." & $sKey)
                    ElseIf (StringRegExp($sKey, "\[|\]") and StringLen($sJsonValue)) Then
                        GUICtrlSetData($hEditOut, "Value at key '" & ".structure." & $sKey & "' = " & $sJsonValue)
                    EndIf
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

 

[ChrisEnn]

Thanks for your answers.

I'd thought of using JSON rather than CSV, and haven't yet made a definite decision on what format to use, but my existing files are CSV from Excel (I'm porting an existing Excel-VBA app to a standalone executable), so initially it just seemed easier to use _FileReadToArray and _FileWriteFromArray.

@trancexx: that seems exactly what I want, I'll use your solution for now, many thanks.

 

Chris

[ChrisEnn]

@InonuTaishou: Your reply is interesting too, my initial reply about JSON was for my data files, but I could indeed use this for my structure array. I'll go with trancess's idea for now, as it seems easier to implement.

Edited April 3, 2016 by ChrisEnn
typo

[ChrisEnn]

Another newbie question.

Using trancexx's solution above, how can I retrieve one of the sub-arrays.

This works :

Local $vVar = $aStructures[0][2][0] ; => "parameter"

but this doesn't :

Local $aArray = $aStructures[0][2]  ; => ["parameter", "value", "comments"]

Instead of retrieving the subarray, I get "Array variable has incorrect number of subscripts or subscript dimension range exceeded."

 

How can I retrieve a sub-array in one go, to then pass it as a parameter to a function ?

Thanks for your help.

[trancexx]

That's called slicing. Write a function for it in which you'd copy elements from the original array into new one. There's no buit-in mechanism for it.

[ChrisEnn]

Ok, I'll do that. Thanks for your quick reply.