Extracting from a selected sentence only the first character of each word

[ferradavi]

Hi there!
Is there a simple way to do this:

(assuming to select the text above)

HtItaswtdt

 

Thanks to all for your attention

[Melba23]

ferradavi,

#include <MsgBoxConstants.au3>

$sString = "Hi there! Is there a simple way to do this:"

$aRet = StringRegExp($sString, "(?:\A|\s)(.)", 3)

$sLetters = ""
For $i = 0 To UBound($aRet) - 1
    $sLetters &= $aRet[$i]
Next

MsgBox($MB_SYSTEMMODAL, "Extracted", $sLetters)

M23

[iamtheky]

$sStr = "Hi there!" & @LF & _
"Is there a simple way to do this:"

$aStr = stringsplit(stringreplace($sStr , @LF , " ") , " " , 2)

$output = ""

for $i = 0 to ubound($aStr) - 1
    $output &= stringleft($aStr[$i] , 1)
Next

msgbox(0 , '' , $output)

 

[iamtheky]

of course Melba wins, I think locals get affinity on the server .  His can be condensed unsafely.

#include<array.au3>

$sStr = "Hi there!" & @LF & _
"Is there a simple way to do this:"

msgbox(0, '' , _ArrayToString(StringRegExp($sStr, "(?:\A|\s)(.)", 3) , ""))

 

[Malkey]

And another method.

#include <MsgBoxConstants.au3>

Local $sString = "Hi there!" & @LF & _
        "Is there a simple way to do this:"

$aRet = StringRegExpReplace($sString, "(?s)(?!\b\w).*?", "")

MsgBox($MB_SYSTEMMODAL, "Results", _
        'The first letter of the words in the selected text: ' & @LF & @LF & _
        '"' & $sString & '"' & @LF & @LF & _
        'are:' & @LF & @LF & _
        '"' & $aRet & '"')

 

[ferradavi]

Very very cool!!

How to obtain instantly the result after selecting text? 

I mean clicking the left button mouse and releasing it in a active window.

Thanks

Edited March 21, 2016 by ferradavi

[ferradavi]

Hey guys,

I need your help... what's wrong about this code:

expandcollapse popup

#include <Misc.au3>
#include <MsgBoxConstants.au3>

HotKeySet('{ESC}', '_Exit')
Global $hDLL = DllOpen('user32.dll')


While 1

if _IsPressed ( '1', $hDLL)   Then

        If _IsPressed('11', $hDLL) AND _IsPressed('1', $hDLL) Then 

            do
               sleep (200)

            until _IsPressed ('11', $hDLL )<>1 AND _IsPressed('1', $hDLL) <>1


_GetText()

        EndIf
     EndIf

    Sleep(200)
WEnd


Func _Exit()
    DllClose($hDLL)
    Exit
EndFunc


Func _GetText()

    Local $PrevClip = ClipGet()

    Send('^c')
    ConsoleWrite(ClipGet() & @LF)
    Local $sString=string($PrevClip)
    ClipPut($PrevClip)

$aRet = StringRegExp($sString, "(?:\A|\s)(.)", 3)

$sLetters = ""
For $i = 0 To UBound($aRet) - 1
    $sLetters &= $aRet[$i]
Next

MsgBox($MB_SYSTEMMODAL, "Extracted", $sLetters)

EndFunc

 

[ferradavi]

expandcollapse popup

#include <Misc.au3>
#include <MsgBoxConstants.au3>

HotKeySet('{ESC}', '_Exit')
Global $hDLL = DllOpen('user32.dll')

While 1

if _IsPressed ('1', $hDLL)  or  _IsPressed ('10', $hDLL) Then

        If _IsPressed('10', $hDLL) And _IsPressed('1', $hDLL) Then

            do
               sleep (200)

            until _IsPressed ('10', $hDLL )<>1 And _IsPressed('1', $hDLL) <>1

  Send('^c')

_Extract()

        EndIf
     EndIf

WEnd


Func _Exit()
    DllClose($hDLL)
    Exit
EndFunc



Func _Extract()
   Local $sData  = ClipGet()

    $sString = $sData

$aRet = StringRegExp($sString, "(?:\A|\s)(.)", 3)

$sLetters = ""
For $i = 0 To UBound($aRet) - 1
    $sLetters &= $aRet[$i]
Next

MsgBox($MB_SYSTEMMODAL, "Extracted", $sLetters)

EndFunc

... and finally I got it!

[Danyfirex]

Hi just for fun. A not regexp example.

#include <array.au3>

$sStr = "Hi there!" & @LF & _
        "Is there a simple way to do this:"


Local $aSplit = StringSplit($sStr, " " & @CRLF)
Local $sOut = ""
For $i = 1 To $aSplit[0]
    $sOut &= StringLeft($aSplit[$i], 1)
Next
ConsoleWrite($sOut & @CRLF)

Saludos

Edited March 22, 2016 by Danyfirex

[Gianni]

just for fun, A not regexp nor array example.

$sStr = "Hi there!" & @LF & _
        "Is there a simple way to do this:"

$sStr = StringReplace(StringReplace(StringReplace(StringStripWS($sStr, 7), @CR, " "), @LF, " "), @TAB, " ")
Local $i = StringLen($sStr), $sOut = ""

While $i
    $i = StringInStr($sStr, " ", 0, -1, $i - 1)
    $sOut = StringMid($sStr, $i + 1, 1) & $sOut
WEnd
ConsoleWrite($sOut & @CRLF)

 

[iamtheky]

$sStr = "Hi there!" & @LF & _
        "Is there a simple way to do this:"

$sOut =  ""

while 1
    $sOut &= stringleft($sStr , 1)
    If Not StringInStr($sStr , " ") Then exitloop
    $sStr = stringtrimleft($sStr , StringinStr(StringReplace($sStr , @LF, " "), " " , 0 , 1))
wend

msgbox(0, '' , $sOut)