How check if current system HD have a "D:" partition

[GordonFreeman]

I guys, i trying check if current system HD have a "D" partition. To do something like:

 

If true then Drivesetlabel "C" -> Operational System, Drivesetlabel "D" -> User FIles

else

Drivesetlabel "C" -> Operational System

 

but i cannot do a rellation between c and d to cehck if are from same hd. Thanks in advance

[mLipok]

Check first example in HelpFile:

DriveGetDrive()

 

[GordonFreeman]

14 minutes ago, mLipok said:

Check first example in HelpFile:

DriveGetDrive()

 

Thanks but when i run this code return an array containing (C,D and H). H is my external HD usb that not have relation with my PC HD. If i am in other PC with only C partition with my external USB HD connected it probably will get the D letter and it will rename my external HD with "User Files"

#include <Array.au3>

$aArray = DriveGetDrive("FIXED")

_ArrayDisplay($aArray)

 

[mLipok]

Func _TEST($aArray, $sDriverLetter)
    For $i = 1 To $aArray[0]
        If StringInStr($aArray[$i], $sDriverLetter) then Return True
    Next
    Return False
EndIf

 

Edited March 18, 2016 by mLipok

[MuffinMan]

I'm not sure I entirely understand the situation, do you want to make sure that C: and D: are actual physically different drives (not a logical partition on a single disk)?  You could rule out USB Drives by doing something like this:

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

; Check the drive type for D:\
$DType = DriveGetType("D:\")
MsgBox($MB_SYSTEMMODAL, "", "Drive Type: " & $DType)

; Check the bus type status for D:\
$DBus = DriveGetType("D:\", $DT_BUSTYPE)
MsgBox($MB_SYSTEMMODAL, "", "Drive Bus: " & $DBus)

If $DType = "FIXED" AND $DBus <> "USB" Then
    ; Do Whatver
EndIf

Maybe if you used DriveGetSerial you could tell if C: and D: were physically different drives?  I don;t have a logical partition to test on.

[jguinch]

Look at this one :

 

[GordonFreeman]

8 minutes ago, MuffinMan said:

I'm not sure I entirely understand the situation, do you want to make sure that C: and D: are actual physically different drives (not a logical partition on a single disk)?  You could rule out USB Drives by doing something like this:

#include <AutoItConstants.au3>
#include <MsgBoxConstants.au3>

; Check the drive type for D:\
$DType = DriveGetType("D:\")
MsgBox($MB_SYSTEMMODAL, "", "Drive Type: " & $DType)

; Check the bus type status for D:\
$DBus = DriveGetType("D:\", $DT_BUSTYPE)
MsgBox($MB_SYSTEMMODAL, "", "Drive Bus: " & $DBus)

If $DType = "FIXED" AND $DBus <> "USB" Then
    ; Do Whatver
EndIf

Maybe if you used DriveGetSerial you could tell if C: and D: were physically different drives?  I don;t have a logical partition to test on.

I want check if the physical drive that Windows are installed and current running have a second partition.

[InunoTaishou]

You want to use DriveGetType

#include <Array.au3>
Local $aDrives = DriveGetDrive("ALL")
Local $aDrivesWithType = DriveGetDriveAndType($aDrives)

_ArrayDisplay($aDrivesWithType)

Func DriveGetDriveAndType($aDriveGetDrive)
    Local $aReturn[UBound($aDriveGetDrive, $UBOUND_ROWS)][2]

    For $i = 0 To UBound($aDriveGetDrive, $UBOUND_ROWS) - 1
        $aReturn[$i][0] = $aDriveGetDrive[$i]
        $aReturn[$i][1] = DriveGetType($aDriveGetDrive[$i])
    Next
    Return $aReturn
EndFunc   ;==>DriveGetDriveAndType

On mine my HDDs an SSD come up as FIXED, 1 CDROM and my usb comes up as Removable

[BrewManNH]

_WinAPI_DeviceIoControl in combination with _WinAPI_CreateFileEx.

 

[Danyfirex]

Hi. Just for fun.

#include <WinAPIFiles.au3>
#include <WinAPI.au3>
#include <Memory.au3>
Global Const $sTag_STORAGE_DEVICE_NUMBER = "dword DeviceType;dword DeviceNumber;int PartitionNumber"

Local $sMainDisk=@HomeDrive
Local $sPartition="D:"
Local $DiskNumber1 = _GetDiskNumber($sMainDisk)
Local $DiskNumber2 = _GetDiskNumber($sPartition)

If $DiskNumber1 And $DiskNumber2 Then
    If $DiskNumber1=$DiskNumber2 Then
    ConsoleWrite("Current system HD(" & $sMainDisk & ") contains a partition " & $sPartition  & @CRLF)
;~     do something
    EndIf
Else
;~     do something
EndIf

Func _GetDiskNumber($sDrive)

    Local $hDevice = _WinAPI_CreateFile("\\.\" & $sDrive, $FILE_SHARE_READ, 0)
    Local $tStorageDevNumber = DllStructCreate($sTag_STORAGE_DEVICE_NUMBER)
    Local $bRet = _WinAPI_DeviceIoControl($hDevice, $IOCTL_STORAGE_GET_DEVICE_NUMBER, 0, 0, $tStorageDevNumber, DllStructGetSize($tStorageDevNumber))
    _WinAPI_CloseHandle($hDevice)

    If Not $bRet Then Return 0

    If DllStructGetData($tStorageDevNumber, "DeviceType") = $FILE_DEVICE_DISK Then; FILE_DEVICE_DISK
        Return SetError(0, 0, DllStructGetData($tStorageDevNumber, "DeviceNumber")+1)
    EndIf

    Return 0

EndFunc   ;==>_GetDiskNumber

Saludos