how can change tab order ??

[faustf]

hi  guy i   have  a  gui  with  10  input box ,  how  is possible set a  tab order??? 

 

thankz 

 

[ViciousXUSMC]

An AutoIT GUI?

They will tab in the order that you initialize them. 

[faustf]

and  if  i wanna  change  ???  i must  re drawing  ??? 

[jguinch]

Here is a way :

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

GUICreate("gui", 280, 170)

$b1 = GUICtrlCreateButton("Bouton1", 10, 10, 100, 25)
$b2 = GUICtrlCreateButton("Bouton2", 10, 50, 100, 25)
$b3 = GUICtrlCreateButton("Bouton3", 10, 90, 100, 25)
$bQuit = GUICtrlCreateButton("Exit", 170, 130, 100, 25 )
$bTabOrder = GUICtrlCreateButton("Arrange tab order", 10, 130, 150, 25 )

$i1 = GUICtrlCreateInput("", 120, 10, 150, 25)
$i2 = GUICtrlCreateInput("", 120, 50, 150, 25)
$i3 = GUICtrlCreateInput("", 120, 90, 150, 25)

Local $aOrder = [$b1, $i1, $b2, $i2, $b3, $i3, $bTabOrder, $bQuit]

GUISetState()

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $bTabOrder
            _GUISetTabOrder($aOrder)
    EndSwitch
WEnd


Func _GUISetTabOrder($aId)
    Local $hCtrl
    For $i = 0 To UBound($aId) - 1
        $hCtrl = (IsHWnd($aId[$i]) ? $aId[$i] : GUICtrlGetHandle($aId[$i]))
        _WinAPI_SetWindowPos($hCtrl, $HWND_BOTTOM, 0, 0, 0, 0,  BitOr($SWP_NOMOVE, $SWP_NOSIZE) )
    Next
EndFunc

 

[faustf]

o thanks so much