GUIListViewEx problem with Enter Accelerator

[NewBieAuto]

Hi All!. I've learn about Edit ListView with GUIListViewEx.au3 (Thanks M23 :D) to input and Edit data in ListView

#include <GUIConstantsEx.au3>
#include <GUIListViewEx.au3>
$iEditMode = 0

Global $MainGui = GuiCreate("MyGUI", 290, 220, -1, -1)

Global $Input_1 = GuiCtrlCreateInput("", 20, 20, 80, 20)
Global $ADD = GuiCtrlCreateButton("ADD", 120, 20, 50, 20)
Global $ListView = GuiCtrlCreateListView("Col1 | Col2", 20, 50, 250, 130)

$ArrayLV = _GUIListViewEx_ReadToArray($ListView, 1)
_GUIListViewEx_Init($ListView, $ArrayLV, Default, Default, Default, 2)

Local $aAccelKeys[][] = [["{Enter}", $Add]]
GUISetAccelerators($aAccelKeys)
            ;
GuiSetState(@SW_SHOWNORMAL)
_GUIListViewEx_MsgRegister()
Do
    Switch GuiGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop

        Case $Add
           $Col2Ip = GUICtrlRead($Input_1)
           $Col1Ip =  _GUICtrlListView_GetItemCount($ListView)+1
           Global $DataIp[] = [$Col1Ip, $Col2Ip]
           _GUIListViewEx_Insert($DataIp)
           GUICtrlSetData($Input_1, "")
           ControlClick("MyGui", "", '[CLASS:Edit; INSTANCE:1]', "left")

      EndSwitch
      _GUIListViewEx_EditOnClick($iEditMode)
Until False

But there's some problem:

1. When I press ENTER to end edit item, it also add a new item to list view

2. Why     ControlClick("MyGui", "", '[CLASS:Edit; INSTANCE:1]', "left")   dont work??

[BrewManNH]

Why are you using ControlClick on your own GUI? You can do this without having to try and automate the listview, by editing the data directly, and then rebuilding the LV or setting the data in that section.

[NewBieAuto]

I want to input data to listview. This data changes everytime I input. If do like your suggestion, I will use mouse very much. But I want to input by keyboard only, mouse is used when edit item.

[Melba23]

NewBieAuto,

The problem is your choice of {ENTER} as the Accelerator key - that key is already used widely within the UDF and so there is a conflict. Why not use another key?

If you have to use {ENTER} then you could do something like looking for something in the input box and only add an item if there is indeed something to add:

Case $ADD
    $Col2Ip = GUICtrlRead($Input_1)
    If $Col2Ip <> "" Then
        $Col1Ip = _GUICtrlListView_GetItemCount($ListView) + 1
        Global $DataIp[] = [$Col1Ip, $Col2Ip]
        _GUIListViewEx_Insert($DataIp)
        GUICtrlSetData($Input_1, "")
    EndIf

Now the code will only add a row if there is some content in the input - pressing {ENTER} to end an edit will not do so.

I am afraid I have no idea what you are attempting to do with the ControlClick line.

M23

[NewBieAuto]

Thanks M23. 

I use ControlClick to move the control to the input box (to type faster). When Edit in ListView, the INSTANCE will be changed. So the controlClick dont work.

Is there an other way to do like ControlClick??

[InunoTaishou]

To add on to M23

Case $ADD
            $Col2Ip = GUICtrlRead($Input_1)
            If $Col2Ip <> "" Then
                $Col1Ip = _GUICtrlListView_GetItemCount($ListView) + 1
                Global $DataIp[] = [$Col1Ip, $Col2Ip]
                _GUIListViewEx_Insert($DataIp)
                GUICtrlSetData($Input_1, "")
                GUICtrlSetState($Input_1, $GUI_FOCUS)   ; Set the input box to focused
            EndIf

 

Edited March 24, 2016 by InunoTaishou

[Melba23]

NewBieAuto,

Quote

I use ControlClick to move the control to the input box (to type faster).

Why do you need to do this? When you open a ListView cell for editing the focus is already on the created control ready for your input - so why do you need to force a click on it?

M23