A way to store arrays

[iloveyou]

My data is stored in arrays but it doesn't appear that I can write to a file. Is there anyway to do this?

Perhaps convert array into a string write to file then convert string into array?

Thank you  

[InunoTaishou]

#include <File.au3>
#include <Array.au3>

; List all the files in the current script directory.
Local $aScriptDir = _FileListToArray(@ScriptDir)

; Create a file in the users %TEMP% directory.
Local $sFilePath = @TempDir & "\Examples.txt"

; Write array to a file by passing the file name.
_FileWriteFromArray($sFilePath, $aScriptDir, 1)

; Display the file.
ShellExecute($sFilePath)

Local $aNewScriptDir
_FileReadToArray($sFilePath, $aNewScriptDir)

_ArrayDisplay($aNewScriptDir)

 

Edited March 9, 2016 by InunoTaishou

[iloveyou]

I can't use that method because I need to keep my key value pairs. I have resorted to using _ArrayToString but how can I turn the string back into an array?

The issue is that I have  2d array so just using StringSplit doesn't work..

Here is what my ini file looks like 

[General]
$totalFrankingCredits=
$currentMoney=1000
$pendingDivPayments=Code|Pay Date|Payment amount

DCK|2016/01/01|500

BCG|2016/03/01|100
$divPaymentHistory=
$holdings=Code|Number of Stocks

CBA|1000

RIO|50

 

[Melba23]

iloveyou,

Quote

My data is stored in arrays but it doesn't appear that I can write to a file

Here is what my ini file

Where is this data that you want to store? In an array  or in this ini file?

M23

[Myicq]

a long time ago, when I was doing some coding in Access VBA, I needed to access some settings in a simple way. Essentially a bit like your setup where you have an array and key, and need to get info.

In your place, I would look at SQLite functions, and develop a few wrapper functions to read and store info. Then forget about how data is stored, you would simple be able to do

; read value
$myAmount=_get("pendingDivPayments","DCK")

; set value
_set("pendingDivPayments","DCK", "500")

 

There are also projects around here to deal with associative arrays, personally I like the SQLite approach better.

Just some random ideas.

 

[AutoBert]

You can use IniReadSection to read a whole section into Ini. You can use StringSplit for getting arrays for cases Keyvalue is a stored array:

#include <Array.au3>
$aGeneral=IniReadSection('ily.ini','General')
_ArrayDisplay($aGeneral,'[General]')

$aPendingDivPayments=StringSplit($aGeneral[3][1],'|')
_ArrayDisplay($aPendingDivPayments,'PendingDivPa

Btw.: your INI isn't valid, these lines:

DCK|2016/01/01|500
BCG|2016/03/01|100
CBA|1000
RIO|50

couldn't read with IniReadSection or IniRead.

[czardas]

Perhaps you should try  _ArrayToDeclarationString() and _ArrayDeclareFromString() by jguinch. I quite like that.
https://www.autoitscript.com/forum/topic/179779-_arraydeclarefromstring-_arraytodeclarationstring-_arrayshufflemultidim-_arraycompare-_arrayenumvalues-_arrayassign/

Edited March 9, 2016 by czardas

[iloveyou]

Basically I have 

$pendingDivPayments => [['Code','Pay Date','Payment amount'],['DCK',"2016/01/01",500],['BCG','2016/03/01',100]]

Then I convert array to a string inorder to write to the .ini file. 

_ArrayToString($pendingDivPayments) 

;returns this
Code|Pay Date|Payment amount

DCK|2016/01/01|500

BCG|2016/03/01|100

I am not sure why there are spaces?? 

[czardas]

The line breaks could be something to do with the forum. This gives no extra line breaks.

#include <Array.au3>
Local $pendingDivPayments = [['Code','Pay Date','Payment amount'],['DCK',"2016/01/01",500],['BCG','2016/03/01',100]]
_ArrayDisplay($pendingDivPayments)
MsgBox(0, "", _ArrayToString($pendingDivPayments))

I don't understand why some people consider the ini format to be a suitable way to store the contents of an array in a file: your numbers will be converted to strings.

Edited March 9, 2016 by czardas

[jguinch]

You can try _ArrayToDeclarationString and _ArrayDeclareFromString functions from my ArrayMultiDim UDF (look at the examples).
I made those functions for this use case.

 

 

[iamtheky]

Also, using the dictionary to feign maplike functions will allow you to send it to a 2Darray and back with minimal effort

 

 

 

Edited March 9, 2016 by iamtheky

[iloveyou]

45 minutes ago, jguinch said:

You can try _ArrayToDeclarationString and _ArrayDeclareFromString functions from my ArrayMultiDim UDF (look at the examples).
I made those functions for this use case.

If I call _ArrayToDeclarationString twice it seems to add the contents of the its previous call. I end up with something like this

[["Code","Pay Date","Payment amount"],["DCK","2016/01/01",500],["BCG","2016/03/01",100]] ; first call 

; second call, this should only have "[["Code","Date","Payment amount"]]" 
[["Code","Pay Date","Payment amount"],["DCK","2016/01/01",500],["BCG","2016/03/01",100]][["Code","Date","Payment amount"]]

Is there a way to work around this?

 

[jguinch]

Sorry iloveyou, it was a bug. I edited my UDF. Can you retry ?

@czardas : I didn't see your post in #7 : cool !

 

Edited March 9, 2016 by jguinch

[iloveyou]

hm it is a bit hard since I already developed a work around thanks for fixing it anyway. 

[mikell]

Not sure I understood well, but if the purpose is to write in a .ini,  isn't this easier ?

#Include <Array.au3>
Local $pendingDivPayments = [['Code','Pay Date','Payment amount'],['DCK',"2016/01/01",500],['BCG','2016/03/01',100]]
;_ArrayDisplay($pendingDivPayments)

;Code|Pay Date|Payment amount
;DCK|2016/01/01|500
;BCG|2016/03/01|100

$ini = "test.ini"
For $i = 1 to UBound($pendingDivPayments)-1
   For $j = 0 to UBound($pendingDivPayments, 2)-1
       IniWrite($ini, "my_section" & $i, $pendingDivPayments[0][$j], $pendingDivPayments[$i][$j])
   Next
Next

#cs
result in the ini :
[my_section1]
Code=DCK
Pay Date=2016/01/01
Payment amount=500

[my_section2]
Code=BCG
Pay Date=2016/03/01
Payment amount=100
#ce

Edit
or is it this ?

Local $pendingDivPayments = [['Code','Pay Date','Payment amount'],['DCK',"2016/01/01",500],['BCG','2016/03/01',100]]

$txt = ""
For $i = 0 to UBound($pendingDivPayments)-1
   For $j = 0 to UBound($pendingDivPayments, 2)-1
      $txt &=  $pendingDivPayments[$i][$j] & (($j=UBound($pendingDivPayments, 2)-1) ? @crlf : "|")
   Next
Next
Msgbox(0,"", $txt)

;Code|Pay Date|Payment amount
;DCK|2016/01/01|500
;BCG|2016/03/01|100

 

Edited March 10, 2016 by mikell

[AutoBert]

when in Inifile than like this:

#include <Array.au3>

Dim $aPendingDivPayments[][] = [['Code', 'Pay Date', 'Payment amount'], ['DCK', "2016/01/01", 500], ['BCG', '2016/03/01', 100]]
Global $aCSV

IniWrite('ily.ini', 'General', 'pendingDivPayments', _ArrayToString($aPendingDivPayments, '|', -1, -1, '<CrLf>'))

_IniReadTo2dArray('ily.ini', 'General', 'pendingDivPayments', $aCSV)
_ArrayDisplay($aCSV)

Func _IniReadTo2dArray($sIniPath, $sSection, $sKey, ByRef $aCSV)
    local $sText = IniRead($sIniPath, $sSection, $sKey, '')
    ConsoleWrite($sText & @CRLF)
    local $aCSV = StringSplit($sText, '<CrLf>', 1)
    _ArrayColInsert($aCSV, 1)
    local $iActCols = 2, $aSplit
    For $i = 1 To $aCSV[0][0]
        $aSplit = StringSplit($aCSV[$i][0], '|')
        If IsArray($aSplit) Then
            If $aSplit[0] > $iActCols Then
                _ArrayDisplay($aSplit)
                For $j = $iActCols To $aSplit[0] - 1
                    _ArrayColInsert($aCSV, $j)
                Next
                $iActCols = $aSplit[0]
            EndIf
            For $j = 0 To $aSplit[0] - 1
                $aCSV[$i][$j] = $aSplit[$j + 1]
            Next
        EndIf
    Next
EndFunc   ;==>_IniReadTo2dArray

but remember Original IniFile functions only read ~32 kb

[iloveyou]

Thank you guys for your responses.. really. 

But I have already solved this problem with jguinch's functions. They just had a slight bug but from what I hear he has fixed them now. 

<3 

[iamtheky]

Threads will live long after you have had your way with them, ask a regexp question and it will live forever.  I find it best to copy and store all correct answers, in hopes i one day have that question.

Edited March 10, 2016 by iamtheky

[mikell]

iamtheky,
I totally agree
IMHO it's a much better way for an efficient learning than to blindly use UDFs which are certainly very nice but whose you don't understand how they work 

[BrewManNH]

I only use the Array udf as a last resort myself, so I can understand that thinking.