Regarding mouse hooks, how many can i have?

[careca]

Hi, so i got this code to detect mouse wheel movement, and i noticed that if i have it running in some application, and then try to use it elsewhere, previous one will stop working.

Any way to use it on multiple scripts?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
Global Const $MSLLHOOKSTRUCT = $tagPOINT & ";dword mouseData"
$hKey_Proc = DllCallbackRegister("_Mouse_Proc", "int", "int;ptr;ptr")
$hM_Module = DllCall("kernel32.dll", "hwnd", "GetModuleHandle", "ptr", 0)
$hM_Hook = DllCall("user32.dll", "hwnd", "SetWindowsHookEx", "int", $WH_MOUSE_LL, "ptr", DllCallbackGetPtr($hKey_Proc), "hwnd", $hM_Module[0], "dword", 0)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            OnAutoItExit()
            Exit
    EndSwitch
    $hM_Hook = DllCall("user32.dll", "hwnd", "SetWindowsHookEx", "int", $WH_MOUSE_LL, "ptr", DllCallbackGetPtr($hKey_Proc), "hwnd", $hM_Module[0], "dword", 0)
    Sleep(100)
WEnd

Func _Mouse_Proc($nCode, $wParam, $lParam)
    Local $info, $mouseData
    $info = DllStructCreate($MSLLHOOKSTRUCT, $lParam)
    $mouseData = DllStructGetData($info, 3)
    Select
        Case $wParam = $WM_MOUSEWHEEL
            If _WinAPI_HiWord($mouseData) > 0 Then
                ConsoleWrite(' - Up - '&@CRLF)
                ToolTip('Up')
            Else
                ConsoleWrite(' - Down - '&@CRLF)
                ToolTip('Dn')
            EndIf
    EndSelect
EndFunc   ;==>_Mouse_Proc

Func OnAutoItExit()
    DllCall("user32.dll", "int", "UnhookWindowsHookEx", "hwnd", $hM_Hook[0])
    $hM_Hook[0] = 0
    DllCallbackFree($hKey_Proc)
    $hKey_Proc = 0
EndFunc   ;==>OnAutoItExit

 

 

Edited March 8, 2016 by careca

[careca]

So, anyone?

[Melba23]

careca,

You need to chain the hooks. If you were to use the provided _WinAPI_SetWindowsHookEx / _WinAPI_CallNextHookEx / _WinAPI_UnhookWindowsHookEx functions instead of the DLLCall lines you use at the moment, you would have discovered an example script of how to do this in the Help file.

And why are you not using the WM_MOUSEWHEEL message to detect mouse wheel movement anyway?

M23

[careca]

Hi M23, thanks for the reply.

Well, this one tells me if the wheel is going up or down, can i use WM_MOUSEWHEEL in such a way that it can tell me same?

How? Usually i use such messages with functions, but the help file isn't showing any related to this.

 _WinAPI_SetWindowsHookEx / _WinAPI_CallNextHookEx / _WinAPI_UnhookWindowsHookEx

Sorry for my ignorance, but aren't these just dll calls anyway?

I assumed i needed a way to have more than one hook, but the idea is to have a way to check if the mouse wheel is going up or down, in 2 separate scripts.

Is it possible?

Best regards

[Melba23]

caraeca,

Quote

if the wheel is going up or down, can i use WM_MOUSEWHEEL in such a way that it can tell me same?

Yes - and if you look at the details of the message in MSDN it tells you how to do so. If you prefer a quicker (and certainly less complicated) route look in my GUIScrollbars_Ex UDF and see how I did it.

And yes, those functions are indeed wrappers for a DLLCall line, but they offer a more user-friendly way to approach the matter - and show you exactly how to use them in the attached example.

M23

[careca]

Sadly i don't understand this propperly, but this works as i intend, since i compiled 2 of them, gave a bit of offset to the tooltips, and it showed 2 tooltips at the same time.

Was something like this you were sugesting?

expandcollapse popup

#include <APISysConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WinAPIMisc.au3>
#include <WinAPISys.au3>
#include <WindowsConstants.au3>

Opt('TrayAutoPause', 0)

; Create GUI
Global $g_hForm = GUICreate('Test', 0, 0, 0,0)

Local $tRID = DllStructCreate($tagRAWINPUTDEVICE)
DllStructSetData($tRID, 'UsagePage', 0x01) ; Generic Desktop Controls
DllStructSetData($tRID, 'Usage', 0x02) ; Mouse
DllStructSetData($tRID, 'Flags', $RIDEV_INPUTSINK)
DllStructSetData($tRID, 'hTarget', $g_hForm)

; Register HID input to obtain row input from mice
_WinAPI_RegisterRawInputDevices($tRID)

; Register WM_INPUT message
GUIRegisterMsg($WM_INPUT, 'WM_INPUT')

Do
    Sleep(100)
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_INPUT($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam
            Local $tRIM = DllStructCreate($tagRAWINPUTMOUSE)
            If _WinAPI_GetRawInputData($lParam, $tRIM, DllStructGetSize($tRIM), $RID_INPUT) Then
                $iFlags = DllStructGetData($tRIM, 'ButtonFlags')
                If BitAND($iFlags, $RI_MOUSE_WHEEL) Then
                    $aData = _WinAPI_WordToShort(DllStructGetData($tRIM, 'ButtonData'))
                    If $aData > 0 Then
                        ConsoleWrite(' - Up - '&@CRLF)
                ToolTip('Up')
                    Else
                        ConsoleWrite(' - Down - '&@CRLF)
                ToolTip('Dn')
                    EndIf
                Else
                    ToolTip('')
                EndIf
            EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_INPUT

 

[Melba23]

careca,

Not at all - I had suggested looking for WM_MOUSEWHEEL - but if that rather more complicated method works then good for you.

M23

[careca]

1 hour ago, Melba23 said:

Not at all - I had suggested looking for WM_MOUSEWHEEL - but if that rather more complicated method works then good for you.

It works, but im curious, and would like to learn about that method, i found something that be closer to what you suggested,

but i trimmed it and it doesn't work, can't figure out why, can you help?

#include <APIConstants.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>
;------------------------------------------------

GUIRegisterMsg($WM_MOUSEWHEEL, "WM_MOUSEWHEEL")

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
    Sleep(100)
WEnd

Func WM_MOUSEWHEEL($hWnd, $iMsg, $wParam, $lParam)
    #forceref $iMsg, $wParam
            If BitShift($wParam, 16) > 0 Then ;Wheel up
                ConsoleWrite(' - Up - '&@CRLF)
                ToolTip('Up')
            Else ;-----------------------------Wheel down
                ConsoleWrite(' - Down - '&@CRLF)
                ToolTip('Dn')
            EndIf
    ;Return "GUI_RUNDEFMSG"
EndFunc   ;==>WM_MOUSEWHEEL

Best regards

[Melba23]

careca,

Works fine for me:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ScrollbarConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

GUISetState()

GUIRegisterMsg($WM_MOUSEWHEEL, "_WM_MOUSEWHEEL")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd


Func _WM_MOUSEWHEEL($hWnd, $iMsg, $wParam, $lParam)

    #forceref $hWnd, $iMsg, $lParam
    Local $iDirn = ( (BitShift($wParam, 16) > 0) ? ($SB_LINEUP) : ($SB_LINEDOWN) )
    Switch $iDirn
        Case $SB_LINEDOWN
            ConsoleWrite("Down" & @CRLF)
        Case $SB_LINEUP
            ConsoleWrite("Up" & @CRLF)
    EndSwitch

    Return $GUI_RUNDEFMSG

EndFunc

M23

[careca]

Very nice, it works perfect, I see you added a GUI, and this only works while the mouse is on top of it, is there a way to make it work, regardless of the window?

[Melba23]

careca,

As far as I know you need a GUI to trap Windows messages, which is why I said that if your earlier code worked then good for you.

M23

[careca]

Ah, ok, i'll stick to it then, thanks a bunch!

Best regards

 

EDIT: Sadly this function "hijacked" _ispressed, and other stuff like the tray menus, so i ditched it.

Edited March 9, 2016 by careca