Pattern to replace similar character using StringReplace Function

[soft4pedia]

Hello,

I'm having several names of books those are ended with the almost same pattern (by Van Horne), (by  Philip Crosby) (by Adam Smith), etc...

My questions is how can i use StringReplace command once to replace all ending names of authors like I don't want ending character after "by" and onward. I try to study StringReplace function very deeply but unable to build any suitable pattern for this.

Guide me please

$File1 = @scriptdir & "\replace.txt"
$txt = FileRead($File1)
$txt = StringReplace($txt, "by Van Horne", "")
$txt = StringReplace($txt, "by Johnson T", "")

 

[JohnOne]

StringRegExReplace

[Cormin]

StringRegExpReplace ( "test", "pattern", "replace" [, count = 0] )

https://www.autoitscript.com/autoit3/docs/functions/StringRegExpReplace.htm

 

Here ya go

[soft4pedia]

Hello,

I know how to use this command but my problem is that I don't know how to create pattern even i study the a lot and there are lot of ways to make pattern but those are not upto to my understanding please guide me which patter will be ok for me to replace everything from character "by" and onward.

[mikell]

Here it is, but be careful if "by" is present in the title 

$txt = "my book 1 by Van Horne  " & @crlf & _
    "my book 2 by Adam Smith 2 " & @crlf & _
    "my book 3 by Philip Crosby Junior (part 2)"
Msgbox(0,"", $txt)

$txt = StringRegExpReplace($txt, 'by.+', "")
Msgbox(0,"", $txt)

 

[BrewManNH]

This might be a slightly better pattern.

$txt = "my bytes 1 by Van Horne  " & @crlf & _
    "my book 2 by Adam Smith 2 " & @crlf & _
    "my book 3 by Philip Crosby Junior (part 2)"
$txt = StringRegExpReplace($txt, ' by .+', "")
Msgbox(0,"", $txt)

 

[mikell]

$txt = "my book 1 by Van Horne  " & @crlf & _
    "bye bye 2 by Adam Smith 2 " & @crlf & _
    "stay by my side 3 by Philip Crosby Junior (part 2)"
;Msgbox(0,"", $txt)

$txt = StringRegExpReplace($txt, '(?m)^(.+)\hby\h.+', "$1")
Msgbox(0,"", $txt)

 

Edited March 7, 2016 by mikell

[soft4pedia]

This pattern really works for me...Thanks

I got another situation where the names of authors just be placed inside torrent brackets such as;

Title Book 1 [Adam Smith]

Title Book 1 {Pete Anderson}

Title Book 1 (Anna William)

Title Book 1 - Andrew Clark

only these 4 situation are commonly used in titles of my books...

In this situation which pattern is more suitable so i can use single pattern to replace all, please

[mikell]

Wow, changes are coming ...

$txt = "Title Book 1 [Adam Smith]  " & @crlf & _
    "Title Book 2 {Pete Anderson}  " & @crlf & _
    "Title Book 3 (Anna William) " & @crlf & _
    "Title Book 4 - Andrew Clark "
;Msgbox(0,"", $txt)

$txt = StringRegExpReplace($txt, '(?m)^(.+)\h[\[{\(-].+', "$1")
Msgbox(0,"", $txt)

 

[iamtheky]

yay, i get to edge case mikell instead of vice versa

$txt = "Title Book 1 [Adam Smith]  " & @crlf & _
    "Title Book 2 {Pete Anderson}  " & @crlf & _
    "Title Book 3 (Anna William) " & @crlf & _
    "Hyphenated-Title Book 4 - Andrew Clark "
;Msgbox(0,"", $txt)

$txt = StringRegExpReplace($txt, '(?m)^(.+)\h[\[{\(-].+', "$1")
Msgbox(0,"", $txt)

 

[mikell]

iamtheky,
Sorry... I can't begin to consider all possible edge cases because I need to sleep a little before going back to work tomorrow morning (it's 23:00 now in my country) 

[iamtheky]

Here it is in a slower, but maybe more manageable format as you evaluate cases that slip through

#include<array.au3>

local $aTxt = ["my bytes 1 by Van Horne  " , _
    "my book 2 by Adam Smith 2 " , _
    "my book 3 by Philip Crosby Junior (part 2)" , _
    "Title Book 4 [Adam Smith]", _
    "Title Book 5 {Pete Anderson}", _
    "Title Book 6 (Anna William)", _
    "Title Book 7 - Andrew Clark-Griswold"]


;~ _ArrayDisplay($aTxt)

For $i = 0 to ubound($aTxt) - 1
    If StringinStr($aTxt[$i] , " by " , 0 , -1) Then $aTxt[$i] = StringReplace($aTxt[$i] , stringmid($aTxt[$i] , StringinStr($aTxt[$i] , " by " , 0 , -1) , -1) , " ")
    If StringinStr($aTxt[$i] , " [" , 0 , -1) Then $aTxt[$i] = StringReplace($aTxt[$i] , stringmid($aTxt[$i] , StringinStr($aTxt[$i] , " [" , 0 , -1) , -1) , " ")
    If StringinStr($aTxt[$i] , " {" , 0 , -1) Then $aTxt[$i] = StringReplace($aTxt[$i] , stringmid($aTxt[$i] , StringinStr($aTxt[$i] , " {" , 0 , -1) , -1) , " ")
    If StringinStr($aTxt[$i] , " (" , 0 , -1) Then $aTxt[$i] = StringReplace($aTxt[$i] , stringmid($aTxt[$i] , StringinStr($aTxt[$i] , " (" , 0 , -1) , -1) , " ")
    If StringinStr($aTxt[$i] , " - " , 0 , -1) Then $aTxt[$i] = StringReplace($aTxt[$i] , stringmid($aTxt[$i] , StringinStr($aTxt[$i] , " - " , 0 , -1) , -1) , " ")
Next

_ArrayDisplay($aTxt)

 

[jguinch]

Also, you can combine both cases :

$txt = "Title Book 1 [Adam Smith]  " & @crlf & _
    "Title Book 2 {Pete Anderson}  " & @crlf & _
    "Title Book 3 (Anna William) " & @crlf & _
    "Title Book 4 - Andrew Clark " & @crlf & _
    "stay by my side 3 by Philip Crosby Junior (part 2)"

$txt = StringRegExpReplace($txt, '(.+\K\hby|.+\K\h[\[({-]).+', "")


Msgbox(0,"", $txt)