_IEGetObjById problem with " symbol

[langthang084]

ex: 

<li id="post-7772508" class="message   " data-author="vietthanh_tcnh">

    

<div class="messageUserInfo" itemscope="itemscope" itemtype="http://data-vocabulary.org/Person">    
<div class="messageUserBlock ">
    
        <div class="avatarHolder">
            <span class="helper"></span>
            <a href="members/vietthanh_tcnh.1079231/" class="avatar Av1079231m" data-avatarhtml="true"><img src="styles/bvn/xenforo/avatars/avatar_m.png" width="96" height="96" alt="vietthanh_tcnh" /></a>
            
            <!-- slot: message_user_info_avatar -->
        </div>

But when I used

_IeGetObjByID($oIE, '"post-7772508"') 

But It shows @error = 7 (No Match)

[Danp2]

Remove the double quotes and try again.

[langthang084]

I remove them but nothing change. 

[Danp2]

What is the web site? Does it use frames?

[langthang084]

Here's my code:

#include <ie.au3>

$Link = 'http://www.bikervietnam.com/threads/topic-ban-luan-danh-rieng-cho-dong-future-125-moi-doi-2012-2013.463954/page-2'
_IELoadWaitTimeout(10000)               
$IE = _IECreate($Link, 0, 1, 1)
$CommentData = _IEGetObjById($IE, "post-7767491")
$CommentData = $CommentData.innerhtml
;$CommentData = ClipGet()
MsgBox(0, 'FINISHHHHHHHHHHHH', $CommentData)

I want to get each text post from this forum. With other post, this work normally. But with post-7767491, it's error!

[mLipok]

Here is some modified example:

#include <ie.au3>
#include <MsgBoxConstants.au3>

_IEErrorHandlerRegister(_User_ErrFunc)

$Link = 'http://www.bikervietnam.com/threads/topic-ban-luan-danh-rieng-cho-dong-future-125-moi-doi-2012-2013.463954/page-2'
_IELoadWaitTimeout(10000)
$IE = _IECreate($Link, 0, 1, 1)
$CommentData = _IEGetObjById($IE, "post-7767491")
If @error Then MsgBox($MB_ICONERROR, '', _
'@error = ' & @error & @CRLF & '@extended = ' & @extended)

$CommentData = $CommentData.innerhtml
;$CommentData = ClipGet()
MsgBox(0, 'FINISHHHHHHHHHHHH', $CommentData)

; User's COM error function.
; After SetUp with ObjEvent("AutoIt.Error", ....) will be called if COM error occurs
Func _User_ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptFullPath & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_User_ErrFunc

You should read:

 

I'll look at your problem again in the evening.

 

 

[mikell]

Strange... the code below creates a quick list of all the  id="post-...."  on this page and "post-7767491" doesn't appear in the list

#Include <Array.au3>

$txt = BinaryToString(InetRead("http://www.bikervietnam.com/threads/topic-ban-luan-danh-rieng-cho-dong-future-125-moi-doi-2012-2013.463954/page-2"))

$res = StringRegExp($txt, '<li\h*id="(post-\d+)', 3)
_ArrayDisplay($res)

Edit
It looks like a post deleted

http://www.bikervietnam.com/threads/topic-ban-luan-danh-rieng-cho-dong-future-125-moi-doi-2012-2013.463954/goto/post?id=7767491#post-7767491

 

Edited February 21, 2016 by mikell

[mLipok]

Working example (even if You again use old $sLink ):

expandcollapse popup

#include <ie.au3>
#include <MsgBoxConstants.au3>

_IEErrorHandlerRegister(_User_ErrFunc)

_Example()

Func _Example()
    Local $sLink = ''
    ; $sLink = 'http://www.bikervietnam.com/threads/topic-ban-luan-danh-rieng-cho-dong-future-125-moi-doi-2012-2013.463954/page-2'
    $sLink = 'http://www.bikervietnam.com/threads/topic-ban-luan-danh-rieng-cho-dong-future-125-moi-doi-2012-2013.463954/#post-7767491'
    _IELoadWaitTimeout(10000)
    Local $oIE = _IECreate($sLink, 0, 1, 1)
    Local $oCommentData = _IEGetObjById($oIE, "post-7767491")
    If @error Then
        MsgBox($MB_ICONERROR, '', _
                '@error = ' & @error & @CRLF & '@extended = ' & @extended)
    Else
        $oCommentData = $oCommentData.innerhtml
        ;$oCommentData = ClipGet()
        MsgBox(0, 'FINISHHHHHHHHHHHH', $oCommentData)
    EndIf
EndFunc    ;==>_Example

; User's COM error function.
; After SetUp with ObjEvent("AutoIt.Error", ....) will be called if COM error occurs
Func _User_ErrFunc($oError)
    ; Do anything here.
    ConsoleWrite(@ScriptFullPath & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
            @TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
            @TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
            @TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
            @TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
            @TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
            @TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
            @TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
            @TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
            @TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc    ;==>_User_ErrFunc

 

@langthang084 You should remember to check for @error after calling function which set @error in case of failure.

mLipok

 

Edited February 21, 2016 by mLipok

[langthang084]

Yeah!! Thanks @mLipok. I checked this website again and this id wasnt found.