Problem with Window Activation While Session Minimized

[DavidLago]

Hello.

I designed a robot that measures the time of specific tasks on an application. It calls the applications, wait for the screen to come up, and starts to click around in specific places, every now and then, another window is expected to pop up after a query or something like this.

The code is:

expandcollapse popup

; -------- Start APP and checks if it is up
Run("C:\FS\FS.EXE")

;------ Wait for the main window
$vWait1 = WinWait("Folha de Dados", "Observações", 30)
If $vWait1 = 0 Then
    FileWriteLine($EUM_FDC_LOG, "Status=Error-01;timeResult=Timeout")
EndIf

; ------ Checks window existence, makes sure it is activated.
$vWhile1 = False
While $vWhile1 = False
    Sleep(100)
    If WinExists("Folha de Dados") Then
        WinActivate("Folha de Dados")
        $vWhile1 = True
    Else
        $initAppTime = $initAppTime + 0.1
        If $initAppTime > 30 Then
            FileWriteLine($EUM_FDC_LOG, "Status=Error-02;timeResult=Timeout") ;;;;;; error here
            Exit
        EndIf
    EndIf
WEnd

;------ Activate Window
Global $WinStatus1 = WinWaitActive("Folha de Dados", "Observações", 10)

;------ Gets handle
$hMainHandle = ControlGetHandle("Folha de Dados", "Observações", "[CLASSNN:msvb_lib_toolbar1]")

;------ Click on new
ControlClick("Folha de Dados", "Observações", $hMainHandle, "left", 1, 12, 12)
If @error then
    FileWriteLine($EUM_FDC_LOG, "Status=Error-02;timeResult=Timeout")
    Exit
EndIf

This is just a third of the script (it gets stuck early on the condition described below).

It works perfectly while logged to the computer and/or accessing via remote desktop. I have two monitors, If I click on the other monitor, making the remote computer screen unfocused, it runs perfectly. But if I minimize it, block the computer or close the connection at the red X (disconnecting only), it gives me this erros in the log:

Status=Error-02;timeResult=Timeout
Status=Error-02;timeResult=Timeout
Status=Error-02;timeResult=Timeout
Status=Error-02;timeResult=Timeout
Status=Error-02;timeResult=Timeout

Do you have any idea why the Windows Status funcions are failing? 

 

[mLipok]

This is normal Windows internal behavior. When you minimalize remote desktop sesion, then Windows on remote computer stops sending/analyzing some internal messages.
In your case I can only say: do not minimalize remonte desktop, just move the window outside visible area.

[Kovacic]

16 minutes ago, DavidLago said:

 

It works perfectly while logged to the computer and/or accessing via remote desktop. I have two monitors, If I click on the other monitor, making the remote computer screen unfocused, it runs perfectly. But if I minimize it, block the computer or close the connection at the red X (disconnecting only), it gives me this erros in the log:

 

 

I don't see a GUI defined, when you say Red X, are you talking about on the remote desktop window or the application you made? Also, what do you mean by 'block the computer'?

[DavidLago]

13 minutes ago, Kovacic said:

I don't see a GUI defined

There is no GUI. I'm calling an application, that has its own GUI.

13 minutes ago, Kovacic said:

are you talking about on the remote desktop window or the application you made?

Remote Desktop. I didn't make the application.

13 minutes ago, Kovacic said:

Also, what do you mean by 'block the computer'

WIN + L

 

17 minutes ago, mLipok said:

Windows on remote computer stops sending/analyzing some internal messages

If that is true, it really really sucks. Do you think there is a way around this, like, preventing the OS to stop sending those internal messages even if minimized?

I'll search for more info about this (a KB or something). If you happen to know exactly the one, please share.

[Kovacic]

Or instead of remote desktop, use something that lets you interact directly with a logged in console session like TeamViewer, then use a simple mouse jiggle to keep it from locking.

[DavidLago]

6 minutes ago, Kovacic said:

Or instead of remote desktop, use something that lets you interact directly with a logged in console session like TeamViewer, then use a simple mouse jiggle to keep it from locking.

Well, I don't think that would be possible. This computer that is going to run this will have to run it like 24/7. Its a full time end user experience monitoring. Just for the sake of information, I tested this teamviewer before and if you minimize it disconnects too. Just like mLipok said, it seems that some of the funcions just stop working...

Since I'm inside a company environtment, the policy ensures that the computer gets blocked after 10 or 15 minutes. Also, it cannot be overriden, since an user from one of those computers that will run the script could gain access to a computer who is authenticated inside the domain, with no need to type passwords. When it comes to security, this is not good.

An alternative I've been thinking, is creating another GPO (domain policy) to block the USB devices, so nobody would interact with the computer but the authorized personnel (through remote desktop).

An idea just came to my mind: using mstsc /admin to connect to the console. I'll perform a test.

[DavidLago]

2 minutes ago, DavidLago said:

An idea just came to my mind: using mstsc /admin to connect to the console. I'll perform a test.

No luck.

But I noticed that even when I come back, the screen is still there waiting (grayed out) and it only is recognized after I click on it. If I click on anything else, it won't work. (the script works clicking and typing in the application while the application is minimized too, no problem).

Any ideas?

 

[Kovacic]

Didn't know this was for business.. Sounds possible as long as you are not in the medical or financial industry..

Will an end user be using the computer as your script is running, or is this more of a lab machine?

Edited February 16, 2016 by Kovacic

[DavidLago]

Lab machine. It will be kept exclusively to run these script. I already have some working in there. By the way, they keep working while minimized, though, none of them needs those cursed Windows Status things to go through themselves.

[Bowmore]

As mLipok said once a windows session is locked then no window is allowed to be active,  You will need to change your script so that It does not need to use WinWaitActive.  Try using WinExists

[mLipok]

1 hour ago, DavidLago said:

Do you think there is a way around this, like, preventing the OS to stop sending those internal messages even if minimized?

TeamViewer.

 

[Kovacic]

1 hour ago, DavidLago said:

since an user from one of those computers that will run the script could gain access to a computer who is authenticated inside the domain, with no need to type passwords. When it comes to security, this is not good.

 

If this is a lab machine, it should be locked behind a secure door so no end users can get to it.

[DavidLago]

15 hours ago, Kovacic said:

 

If this is a lab machine, it should be locked behind a secure door so no end users can get to it.

It should, but not all branches have a datacenter. 

I tried this: https://support.smartbear.com/viewarticle/72139/

And it worked. I wished that there would be a way to do something like this to avoid that behavior when disconnecting. The only thing I found is so jury-rigged... https://support.smartbear.com/viewarticle/72794/

Edited February 17, 2016 by DavidLago
english grammar (I'm brazilian)

[mLipok]

9 minutes ago, DavidLago said:

I tried this: https://support.smartbear.com/viewarticle/72139/

And it worked.

Interesting find.

 

[DavidLago]

Thanks, @mLipok. By the way, scavenging around the forum, I've found this topic: 

Check answer nº 4: 

On 9/5/2012 at 10:45 PM, OregonJohn said:

I have three different XP machines running AutoIt3 scripts interacting with the front end of the same program. I have a third XP machine (oldie) that runs a RDP of all three machines running scripts ... I call it my RDP monitor machine.

 

As an aside, I have one of those XP machines providing two RDP sessions for the RDP monitor because I want two active scripts running on two separate programs.

 

I wish XP provided the ability to run separate desktop instances on the same machine. I tried using virtual desktops (like Dexpot) but the windows the script was watching for kept coming to the main desktop and interrupted the activity on the main desktop.

Interesting idea. I will have to consider this.

[DavidLago]

Okay, guys. This is a little spartan, but it works.

In order to be able to minimize and also disconnect from the remote computer without affecting any of the GUI oriented scripts you must do:

1. In the local computer:

• Launch the Registry editor (regedit.exe), go to HKLM\Software\Microsoft\Terminal Server Client
• Create a DWORD value named RemoteDesktop_SuppressWhenMinimized and set it to 2.

2. In the remote computer:

• Place in the desktop the file attached to this post. It's a zip file containing a .bat file with a code that will disconnect your session without telling the OS that there is no user watching it anymore.

You'll have to execute this .bat script everytime you have to disconnect the session. (If anyone wants to convert the batch to AutoIt, it would be interesting too).

Tested and confirmed.

disconnect.zip

[mLipok]

1 hour ago, DavidLago said:

• Launch the Registry editor (regedit.exe), go to HKLM\Software\Microsoft\Terminal Server Client
• Create a DWORD value named RemoteDesktop_SuppressWhenMinimized and set it to 2.

It would be nice if you make AutoIt script for that.

 

[DavidLago]

1 hour ago, mLipok said:

It would be nice if you make AutoIt script for that.

Oki.

Here it goes:

expandcollapse popup

#cs ----------------------------------------------------------------------------
    AutoIt Version: 3.3.14.2
    Author:             David
    Script Function:    Go to HKLM\Software\Microsoft\Terminal Server Client, create a DWORD value named RemoteDesktop_SuppressWhenMinimized and set it to 2
#ce ----------------------------------------------------------------------------

#RequireAdmin
#include <Process.au3>

Global $eErr

;---- Remote Desktop Connections must be closed.
If ProcessExists("mstsc.exe") Then
    Local $mAnswer = MsgBox(52, "Warning", "There is at least one Remote Desktop Session active. May the process(es) be terminated?")
    If $mAnswer = 6 Then
        ProcessClose("mstsc.exe")
        If @error Then _RunDos("taskkill /F /IM mstsc.exe")
    Else
        Exit
    EndIf
EndIf

;---- Write the Registry 1
RegWrite("HKEY_LOCAL_MACHINE\Software\Microsoft\Terminal Server Client", "RemoteDesktop_SuppressWhenMinimized", "REG_DWORD", "2")
If @error Then
    $eErr = @error
    _ErrorDisplay($eErr)
EndIf

;---- Write the Registry 2
RegWrite("HKEY_CURRENT_USER\Software\Microsoft\Terminal Server Client", "RemoteDesktop_SuppressWhenMinimized", "REG_DWORD", "2")
If @error Then
    $eErr = @error
    _ErrorDisplay($eErr)
EndIf

;---- SUCCESS
MsgBox(64, "Success", "Windows Registry settings applied successfully")

Func _ErrorDisplay($eErr)
    If $eErr = 1 Then MsgBox(16, "Error", "Unable to open requested key")
    If $eErr = 2 Then MsgBox(16, "Error", "Unable to open requested main key")
    If $eErr = 3 Then MsgBox(16, "Error", "Unable to remote connect to the registry")
    If $eErr = 4 Then MsgBox(16, "Error", "Unable to open requested value")
    If $eErr = 5 Then MsgBox(16, "Error", "Value type not supported")
    Exit
EndFunc   ;==>_ErrorDisplay

Haven't tested, though

[mLipok]

You are using strange naming convention I mean $mAnswer
For detailed information read here: https://www.autoitscript.com/wiki/Best_coding_practices#Names_of_Variables

 

[DavidLago]

Thanks, mLipok! Never knew about this. Maybe because I never studied programming (officially). I've always put a random lowcase letter in variables haha. 

Any chance your screenname follows that rule?