gui function wonte delete files until gui closes

[Milas]

Hello,

     I am working on a GUI that will perform some reg query and wmic cmds for some of our tier 1 techs. everything so far works well except for my function to get mapped printers from a remote computer. I have the function outputting the list of printers to a text file in the temp folder. at the end of the function its suppose to delete the file and that is where my issue lies. The gui wont delete the file until the GUI itself closes. this is causing an issue where if I want to run the function again the gui shuts down on me.

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <inet.au3>
#include <Constants.au3>
#RequireAdmin

#cs
    Program: Phone Tech utilitly tool
    Purpose: Assist phone techs and others with different wmic and reg query cmds to gain information from remote computers
    Creator: Salim C. Proctor
    Co-creator/Editor: John Ennis
    Date Created: 2 Feb 2016
    Last Edited: 16 Feb 2016
    Verion 1.0
#ce


#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 627, 459, 192, 114)
$Tab1 = GUICtrlCreateTab(0, 0, 625, 457)

$TabSheet1 = GUICtrlCreateTabItem("Main")
$User = GUICtrlCreateButton("Who's Logged On", 8, 40, 147, 41)
$Host = GUICtrlCreateButton("Get Hostname", 8, 96, 147, 41)
$Acc = GUICtrlCreateButton("User Account Info", 440, 40, 139, 41)
$MAC = GUICtrlCreateButton("Get MAC Address", 8, 152, 147, 41)
$nPrinter = GUICtrlCreateButton("Mapped Printers", 8, 208, 147, 41)
$sUser = GUICtrlCreateInput("", 168, 48, 249, 21)
$sHost = GUICtrlCreateInput("", 168, 104, 249, 21)
$IP = GUICtrlCreateInput("Enter IP/Hostname", 8, 424, 161, 21)
$plist = GUICtrlCreateEdit("", 168, 208, 249, 162)
$sMAC = GUICtrlCreateInput("", 168, 160, 249, 21)
$Ping = GUICtrlCreateButton("Ping", 208, 408, 163, 41)
$mDrive = GUICtrlCreateButton("Remote C$", 440, 408, 147, 41)

$TabSheet2 = GUICtrlCreateTabItem("Program Version")
$search = GUICtrlCreateButton("Search", 8, 32, 147, 41)
$program = GUICtrlCreateInput("Enter Program Name", 176, 40, 321, 21)
$prog_list = GUICtrlCreateEdit("", 8, 96, 609, 318)

GUICtrlSetData(-1, "")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $User
            remote_user()
        Case $Host
            remote_host()
        Case $MAC
            remote_Mac()
        Case $search
            remote_program()
        Case $Ping
            ping_customer()
        Case $mDrive
            map_drive()
        Case $nPrinter
            get_printers()
        Case $Acc
            Account()
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func remote_user()
    $pid = Run(@ComSpec & " /c wmic /node:" & GUICtrlRead($IP) & " computersystem get username", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

    Local $line
    While 1
        $line &= StdoutRead($pid)
        If @error Then ExitLoop

    WEnd
    While 1
        $line &= StderrRead($pid)
        If @error Then ExitLoop

    WEnd
    $split = StringSplit($line, @CRLF)
    GUICtrlSetData($sUser, $split[4])

EndFunc   ;==>remote_user

Func remote_host()
    $pid = Run(@ComSpec & " /c wmic /node:" & GUICtrlRead($IP) & " computersystem get name", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
    Local $line
    While 1
        $line &= StdoutRead($pid)
        If @error Then ExitLoop
    WEnd
    While 1
        $line &= StderrRead($pid)
        If @error Then ExitLoop
    WEnd
    $split = StringSplit($line, @CRLF)
    GUICtrlSetData($sHost, $split[4])

EndFunc   ;==>remote_host

Func remote_Mac()
    $pid = Run(@ComSpec & " /c getmac /nh /s " & GUICtrlRead($IP), @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

    Local $line
    While 1
        $line &= StdoutRead($pid)
        If @error Then ExitLoop

    WEnd
    While 1
        $line &= StderrRead($pid)
        If @error Then ExitLoop

    WEnd
    $split = StringSplit($line, @CRLF)
    $2ndSplit = StringSplit($split[3], "\")

    GUICtrlSetData($sMAC, $2ndSplit[1])



EndFunc   ;==>remote_Mac

Func remote_program()

    Local $fProgram, $nkey, $1position[33], $2position[33]
    Local $pid, $line1[33], $line, $array_size
    GUICtrlSetData($prog_list, "")
    GUICtrlSetState($search, $gui_disable)
    $fProgram = GUICtrlRead($program)
    $pid = Run(@ComSpec & ' /c reg query \\' & GUICtrlRead($IP) & '\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall /s /f ' & $fProgram & ' /d| findstr "{"', @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)


    While 1
        $line &= StdoutRead($pid)
        If @error Then ExitLoop
    WEnd
    While 1
        $line &= StderrRead($pid)
        If @error Then ExitLoop
    WEnd

    $nkey = StringSplit($line, @CRLF & @CRLF)
    $array_size = UBound($nkey)
    ReDim $1position[$array_size]
    ReDim $line1[$array_size]


    For $i = 1 To $array_size - 1
        $1position[$i] = StringLen($nkey[$i])

        If $1position[$i] < 132 Then
            $pid = Run(@ComSpec & ' /c reg query \\' & GUICtrlRead($IP) & '\' & $nkey[$i] & '| findstr /i "displayname displayversion"', @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)


            While 1
                $line1[$i] &= StdoutRead($pid)

                If @error Then ExitLoop
            WEnd

            GUICtrlSetData($prog_list, $line1[$i] & @CRLF & "~", "~")

        EndIf

        $i = $i + 1

    Next

    GUICtrlSetState($search, $gui_enable)
EndFunc   ;==>remote_program

Func ping_customer()
    Local $error

    If GUICtrlRead($IP) <> "" Then
        $pError = RunWait("ping.exe -n 1 " & GUICtrlRead($IP), "", @SW_HIDE)

        Switch $pError
            Case 0
                MsgBox(0, "Successfull", "Operation was a success!")
            Case 1
                MsgBox(48, "ERROR CODE: 001", "Host/IP is not reachable")
        EndSwitch
    Else
        MsgBox(48, "ERROR CODE: 005", "No input detected")
    EndIf
EndFunc   ;==>ping_customer

Func map_drive()
    ShellExecute("C:\Users\Salim.Proctor\Desktop\GUI\john project\c$ remote.exe")
EndFunc   ;==>map_drive

Func get_printers()
    Local $pid, $sid, $sid2, $hfileopen, $sfileread, $line, $exit, $ip45, $user45

    ;disables map printer button in gui
    GUICtrlSetState($nPrinter, $gui_disable)

    ;clears any previous data in the printer edit box
    GUICtrlSetData($plist, " ")
    
    ;reads ip address user entered
    $ip45 = GUICtrlRead($IP)
    
    ;reads the user name from the sUser input box
    $x = GUICtrlRead($sUser)
    
    ;splits the data to remove domainname\
    $y = StringSplit($x, "\")
    
    ;removes a space value from the data
    $user45 = StringSplit($y[2], " ")

    ;queries the remote users registry to find thier sid
    $pid = Run(@ComSpec & ' /c reg query "\\' & $ip45 & '\hklm\software\microsoft\windows nt\currentversion\profilelist" /s /f "' & $user45[1] & '"', @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

    ;reads the standard ouput from the reg query
    While 1
        $line &= StdoutRead($pid)
        If @error Then ExitLoop
    WEnd
    While 1
        $line &= StderrRead($pid)
        If @error Then ExitLoop
    WEnd
    ;string splits to remove all unneeded data and get only the sid
    $sid = StringSplit($line, "\")
    $sid2 = StringSplit($sid[7], @CRLF)

    ;queries the remote users registry using the newly obtained sid and writes it out to a text file
    $pid = Run(@ComSpec & ' /c reg query \\' & $ip45 & '\hkey_users\' & $sid2[1] & '\Printers\Connections > c:\temp\printer_list.txt', @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

    ;pause program to give it time to create the file
    Sleep(1000)

    ;opens the file so that it can be read
    If FileExists("c:\temp\printer_list.txt") Then
        FileWriteLine("c:\temp\printer_list.txt", "1\2\3\4\end of list")
        $hfileopen = FileOpen("c:\temp\printer_list.txt")
    EndIf

    $exit = " "
    $i = 2

    ;output the data into the gui until it reaches the end of the list
    Do
        $exit = FileReadLine("c:\temp\printer_list.txt", $i)
        $printer_string = StringSplit($exit, "\")
        GUICtrlSetData($plist, $printer_string[5] & @CRLF & "~", "~")
        $i = $i + 1

    Until $exit = "1\2\3\4\end of list"

    ;reeneables the gui map printer button
    GUICtrlSetState($nPrinter, $gui_enable)

    ;delete the text file that is created by the command line
    If FileExists("c:\temp\printer_list.txt") Then
        FileClose("c:\temp\printer_list.txt")
        FileDelete("c:\temp\printer_list.txt")

    EndIf

EndFunc   ;==>get_printers

Func Account()
    Local $line
    $split = StringSplit(GUICtrlRead($sUser), "\")

    $pid = Run(@ComSpec & " /c net user " & $split[2] & " /domain", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

    While 1
        $line &= StdoutRead($pid)
        If @error Then ExitLoop

    WEnd

    While 1
        $line &= StderrRead($pid)
        If @error Then ExitLoop

    WEnd
    MsgBox(0, "STDOUT read:", $line)
EndFunc   ;==>Account

just to reiterate the function im having issue with is func get_printers

[AutoBert]

Line 247, FileOpen is blocking the deletion, and handle is never used.

[Milas]

autoBert

it is just as you said. thank you! I cant believe I didn't see that.