Passing byref vs just using a Local\Global value or both?

[tarretarretarre]

Lets say you have this code, imagine its a laaarge project.
 

local $myArr[1]; This array

while 1
    myFunc($myArr)
    myFunc2()
wend



func myFunc(byref $arr)
    ;Heavy modifying to $arr passed by refrence including com objects and large data
endfunc

func myFunc2()
    ;Heavy modifying to $myArr from global scope including objects and large data
endfunc

I know both ways work, but i wonder if one way is more efficient than the other? is it just a principle of not mixing up local\global values? or does it affect the speed anything at all? 

Regards

[InunoTaishou]

myFunc: It's going to actually use $myArr but use it with the name $arr to access it

myFunc2: It's going to actually use $myArr and use the name $myArr to access it

Understand that when you use reference it's going to copy the variable. Reference variables are going to be references to the original variable, you're still working with the original variable, it's just a different name. One reason to pass the variable by Reference instead of just accessing the global variable is for readability and make the function less specific. What I mean by that is if you have your own custom Find function for 2d arrays, you're trying to find a 2d array inside a 2d array. Instead of using the global 2d array that you know is valid in your script, you pass it to the function anyway.

[JohnOne]

Directly accessing the array  (myFunc2) is more efficient.

[BrewManNH]

5 minutes ago, JohnOne said:

Directly accessing the array  (myFunc2) is more efficient.

Depends on how you define efficient. Passing a large array means that the array has to be copied to another array in the function, which means time taken for the copy process and memory taken by the copied array. ByRef doesn't have either of those penalties, there's no copy so less memory used in the function, and less time taken to copy the array to another array.

Normally you wouldn't be passing a global array/variable using ByRef unless you do it to avoid the 2 things I mentioned. Otherwise, all you're doing is using a local variable to change the global variable, which it being Global you don't need to do. You would usually only do this if you're using the function more than once in more than one script.

You would pass something ByRef if you're calling one function from another function and want to pass information from a local variable in the first function to the second function which otherwise wouldn't be able to access it.

[InunoTaishou]

I had to test it because my thought process for reference was it's the same as accessing the variable under a different name, so there should be no performance difference. Though I got that from C++ so it could be different for autoit. So my test, using an array with 16,777,216 elements, had it call a ByRef function and a function with Global access 1,000,000 times, and the function did some random access on the elements in the array.

My results:

Quote

Test 1:
ByRef = 4.59156988441382
Global = 4.92228892580408

Test 2
ByRef = 4.56436635400864
Global = 4.83667461824611

Test 3
ByRef = 4.59719754870342
Global = 4.97156799861628

Test 4
ByRef = 4.58162080094746
Global = 4.8747494111387

Test 5
ByRef = 4.56079234726541
Global = 4.89647722208809

Average:

Quote

ByRef = 4.57910938706775

Global = 4.900351635178652

Median:

Quote

ByRef = 4.58162080094746

Global = 4.89647722208809

The Script:

Global $aTest[16777216]
Global $iDiffRef = 0
Global $iDiffGlobal = 0
Global $tTimer

$tTimer = TimerInit()

For $i = 0 to 1000000
    Test1($aTest)
Next

$iDiffRef = TimerDiff($tTimer) / 1000

$tTimer = TimerInit()

For $i = 0 to 1000000
    Test2()
Next

$iDiffGlobal = TimerDiff($tTimer) / 1000

MsgBox("", "", "ByRef = " & $iDiffRef & @CRLF & "Global = " & $iDiffGlobal)

Func Test1(ByRef $aArray)
    $aArray[Random(0, UBound($aArray) - 1)] = Random(0, 255, 1)
EndFunc

Func Test2()
    $aTest[Random(0, UBound($aTest) - 1)] = Random(0, 255, 1)
EndFunc

My conclusion? The difference in time is so minuscule that performance is not an issue

Edited February 3, 2016 by InunoTaishou

[InunoTaishou]

And before someone comes in and says that the test is invalid because the ByRef func is called first, here's the results with the for loops switched

Quote

Test 1:
ByRef = 4.58433869164087
Global = 4.88279197731277

Test 2:
ByRef = 4.5442805081804
Global = 4.76154360336273

Test 3:
ByRef = 4.56068124135926
Global = 4.75320585582177

Test 4:
ByRef = 4.56418107740298
Global = 4.74793793443911

Test 5:
ByRef = 4.68860497826528
Global = 4.82882573669221

 

[jchd]

5 hours ago, InunoTaishou said:

Understand that when you use reference it's going to copy the variable.

Wrong.

[JohnOne]

Quote

ByRef = 8.93486825509043
Global = 7.88248641201585

ByRef = 9.01905646559787
Global = 7.81425550618496

ByRef = 8.81555893817847
Global = 7.75984786349018

 

[JohnOne]

And  a different script which I think just measures access time without function call.

Local $myArr[1000001]; This array

Sleep(500)

$timer = TimerInit()

myFunc($myArr)
ConsoleWrite("ByRef " & TimerDiff($timer) & @CRLF)

$timer = TimerInit()

myFunc2()
ConsoleWrite("Global " & TimerDiff($timer) & @CRLF)

Func myFunc(ByRef $arr)
    For $i = 0 To 1000000
        $arr[$i] = $i
    Next
EndFunc   ;==>myFunc

Func myFunc2()
    For $i = 0 To 1000000
        $myArr[$i] = $i
    Next
EndFunc   ;==>myFunc2

Quote

ByRef 1656.42429383469

Global 1212.84029968972

ByRef 1680.32492503454
Global 1223.41630521866

ByRef 1655.73951649829
Global 1212.53097236117

 

Edited February 3, 2016 by JohnOne

[InunoTaishou]

8 hours ago, jchd said:

Wrong.

Ya, I explained myself properly in everything else though.

[jchd]

I know, I was simply pointing this out for future noob readers.

[tarretarretarre]

Thanks for all your input

[mLipok]

I make some test with ByRef but with other kind of data.

This test compares speed of passing large amount of binary data INSIDE <> OUTSIDE function.

 

expandcollapse popup

#Tidy_Parameters=/sort_funcs /reel
#include <FileConstants.au3>
#include <MsgBoxConstants.au3>

_Example()
Exit

Func _Example()
    Local $sPDF_FileFullPath = FileOpenDialog("Choose PDF File", "", "PDF files (*.pdf)")
    If @error then Return SetError(@error, @extended, '')

    ConsoleWrite($sPDF_FileFullPath & @CRLF)
    ConsoleWrite('Size = '& FileGetSize($sPDF_FileFullPath) & ' Bytes' & @CRLF)

    Local $hFile = FileOpen($sPDF_FileFullPath,  $FO_BINARY )
    Local $vPDF_Content = FileRead($hFile)
    FileClose($hFile)

    Local $hTimer = 0, $fDiff = 0
    Local $vResult_2a, $vResult_2c
    Local $fDiff_1 = 0, $fDiff_2a = 0, $fDiff_2b = 0, $fDiff_2c = 0, $fDiff_3 = 0

    For $i = 1 To 100
        $hTimer = TimerInit()
        Test1($vPDF_Content)
        $fDiff_1 += TimerDiff($hTimer)

        $hTimer = TimerInit()
        $vResult_2a = Test2($vPDF_Content)
        $fDiff_2a += TimerDiff($hTimer)

        $hTimer = TimerInit()
        Test2($vPDF_Content)
        $fDiff_2b += TimerDiff($hTimer)

        $hTimer = TimerInit()
        $vResult_2c = Test2($vPDF_Content)
        $fDiff_2c += TimerDiff($hTimer)

        $hTimer = TimerInit()
        Test3($vPDF_Content)
        $fDiff_3 += TimerDiff($hTimer)
    Next

    ConsoleWrite("Time 1  : " & $fDiff_1 & @CRLF)
    ConsoleWrite("Time 2a : " & $fDiff_2a & @CRLF)
    ConsoleWrite("Time 2b : " & $fDiff_2b & @CRLF)
    ConsoleWrite("Time 2c : " & $fDiff_2c & @CRLF)
    ConsoleWrite("Time 3  : " & $fDiff_3 & @CRLF)

EndFunc   ;==>_Example

Func Test1(ByRef $vPDF_Content)
EndFunc   ;==>Test1

Func Test2($vPDF_Content)
    Return $vPDF_Content
EndFunc   ;==>Test2

Func Test3($vPDF_Content)
;~  Return $vPDF_Content
EndFunc   ;==>Test3

Quote

Z:\TOOLs\Macro\FORUM\___FORUM -- na forum\QuickPDF\_Viewer\1111_2.pdf
Size = 9036 Bytes
Time 1  : 0.58320639693292
Time 2a : 1.82712798261157
Time 2b : 1.49440731531758
Time 2c : 1.69101498235494
Time 3  : 0.88426188708387
 

 

Quote

Z:\TOOLs\Macro\FORUM\___FORUM -- na forum\QuickPDF\_Viewer\1112.pdf
Size = 782936 Bytes
Time 1  : 1.67352824273863
Time 2a : 523.318094663756
Time 2b : 424.317627247932
Time 2c : 536.550830407455
Time 3  : 179.925790057985
 

 

Quote

Z:\TOOLs\Macro\FORUM\___FORUM -- na forum\QuickPDF\_Viewer\Debenu Cross Platform PDF Library 12.11 Reference Guide.pdf
Size = 2787483 Bytes
Time 1  : 2.09226476436146
Time 2a : 1847.2679805037
Time 2b : 1482.0517522422
Time 2c : 1894.07761938363
Time 3  : 594.040141047097