Running a "Report"

[litlmike]

Looking for ideas on best practices to run a "report" on data values.  Specifically, I just want to take an array and produce a report that counts all of the occurrences of a string value.  For example, if the array were something like this:

U5L4
U5L4
U5L4
U6L5
U4L12

The reports would produce something like this:

U5L4    3
U6L5    1
U4L12   1

Any help is appreciated.  Thanks!

[Melba23]

litlmike,

I would do it like this:

#include <Array.au3>

Global $aList[] = ["U5L4", "U5L4", "U5L4", "U6L5", "U4L12"]

; Convert list to string - use double delimiters to prevent partial matches
$sList = "||" & _ArrayToString($aList, "||") & "||"

; Get unique elements of array
$aUnique = _ArrayUnique($aList)
; And add a column
_ArrayColInsert($aUnique, 1)

; loop through the unique elements
For $i = 1 to $aUnique[0][0]
    ; Check how many times the element is present
    StringReplace($sList, "|" & $aUnique[$i][0] & "|", "")
    ; And store it
    $aUnique[$i][1] = @extended
Next

; And display it
_ArrayDisplay($aUnique, "", Default, 8)

M23

[litlmike]

3 minutes ago, Melba23 said:

litlmike,

I would do it like this:

#include <Array.au3>

Global $aList[] = ["U5L4", "U5L4", "U5L4", "U6L5", "U4L12"]

; Convert list to string - use double delimiters to prevent partial matches
$sList = "||" & _ArrayToString($aList, "||") & "||"

; Get unique elements of array
$aUnique = _ArrayUnique($aList)
; And add a column
_ArrayColInsert($aUnique, 1)

; loop through the unique elements
For $i = 1 to $aUnique[0][0]
    ; Check how many times the element is present
    StringReplace($sList, "|" & $aUnique[$i][0] & "|", "")
    ; And store it
    $aUnique[$i][1] = @extended
Next

; And display it
_ArrayDisplay($aUnique, "", Default, 8)

M23

That is very clever using the @extended, thanks!

[Melba23]

litlmike,

A nice little trick I picked up over the years...

M23

P.S. When you reply, please use the "Reply to this topic" button at the top of the thread or the "Reply to this topic" editor at the bottom rather than the "Quote" button - I know what I wrote and it just pads the thread unnecessarily.

 

[iamtheky]

think this may be close as well, provided the list is already sorted in any fashion that groups like items

#include<array.au3>

Global $aList[][2] = [["U5L4"], ["U5L4"], ["U5L4"], ["U6L5"], ["U4L12"]]
$k = 1

For $i = ubound($aList) - 1 to 0 step -1
    If $i > 0 AND $aList[$i][0] = $aList[$i - 1][0] Then
        _ArrayDelete($aList , $i)
        $k += 1
    Else
        $aList[$i][1] = $k
        $k = 1
    EndIf
Next

_ArrayDisplay($aList)

 

Edited January 31, 2016 by iamtheky

[jguinch]

Also, look at that topic :

 

[litlmike]

Thanks for the tip on reply vs quote