Sum all digits within a mixed array.

[error471]

Hey folks,

I have a simple problem with an array sum. The pictures show what my intention is: Every digit in the row should be summed into a new column at the rightmost of the array.

Hope the problem is not new and someone knows a solution.

Best wishes.

error471

Edited January 28, 2016 by error471

[kylomas]

error471,

Try this...

#include <array.au3>

local $aArray = [ _
                ['Alex',1,2,3], _
                ['Bob',0,0,9,5,' '], _
                ['Ted',10,0,9,5,17] _
                ]

redim $aArray[ubound($aArray)][ubound($aArray,2) + 1]

local $tot = 0
for $i = 0 to ubound($aArray) - 1
    for $j = 0 to ubound($aArray,2) - 1
        if IsNumber($aArray[$i][$j]) then $tot += $aArray[$i][$j]
    next
    $aArray[$i][ubound($aArray,2) - 1] = $tot
    $tot = 0
next
_arraydisplay($aArray)

kylomas

Edited January 28, 2016 by kylomas
corrected code

[error471]

@kylomas:

Your script works, but I can't integrate it into my project. Weird...

Seems to make difficulties with this line:

 

IsNumber($aLVArray[$i][$j]) then $tot = $tot + $aLVArray[$i][$j]

 

[Jfish]

Any chance your source array is being read from a spreadsheet?

[kylomas]

error message?

[error471]

I found the problem. I changed this:

IsNumber($aLVArray[$i][$j]) then $tot = $tot + $aLVArray[$i][$j]

to that:

$tot = $tot + $aLVArray[$i][$j]

It works now, but checking for digits would still be very crucial...

 

[kylomas]

This stmt should work

if IsNumber($aArray[$i][$j]) then $tot += $aArray[$i][$j]

can you post a reproducer?

kylomas

[error471]

Here it is:

 

#include <array.au3>
#include <File.au3>

Global $aArray
_FileReadToArray("array.txt", $aArray,0,"|")
_arraydisplay($aArray)
redim $aArray[ubound($aArray)][ubound($aArray,2) + 1]

local $tot = 0
for $i = 0 to ubound($aArray) - 1
    for $j = 0 to ubound($aArray,2) - 1
        if IsNumber($aArray[$i][$j]) then $tot += $aArray[$i][$j]
    next
    $aArray[$i][ubound($aArray,2) - 2] = $tot
    $tot = 0
next
_arraydisplay($aArray)

 

array.txt

[kylomas]

error471,

Two things...

1. You did not pick up the edited code I posted.  This

$aArray[$i][ubound($aArray,2) - 2] = $tot

   was changed to

$aArray[$i][ubound($aArray,2) - 1] = $tot

2. Your data is really a string so I changed the function IsNumber to StringIsDigit.

It should work like this...

#include <array.au3>
#include <File.au3>

Global $aArray
_FileReadToArray("array.txt", $aArray,0,"|")
_arraydisplay($aArray)
redim $aArray[ubound($aArray)][ubound($aArray,2) + 1]

local $tot = 0
for $i = 1 to ubound($aArray) - 1
    for $j = 0 to ubound($aArray,2) - 1
        if stringisdigit($aArray[$i][$j]) then $tot += $aArray[$i][$j]
    next
    $aArray[$i][ubound($aArray,2) - 1] = $tot
    $tot = 0
next
_arraydisplay($aArray)

kylomas

[error471]

@kylomas:

It works. Thank you!

[iamtheky]

shrunk a bit

#include <File.au3>

Global $aArray
_FileReadToArray("array.txt", $aArray,0,"|")
_arraydisplay($aArray)

redim $aArray[ubound($aArray)][ubound($aArray,2) + 1]

for $i = 1 to ubound($aArray) - 1

    $aArray[$i][ubound($aArray,2) - 1] = execute(stringtrimright(_ArrayToString($aArray , "+" , $i , $i , @CRLF , 1) , 1))

next

_arraydisplay($aArray)