StringSplit exclude values

[compact21]

Example()

Func Example()
    Local $aDays = StringSplit("Mon,Tues,Wed,Thur,Fri.Sat,Sun", ",.") ; Split the string of days using the delimiter "," and the default flag value.
    For $i = 1 To $aDays[0] ; Loop through the array returned by StringSplit to display the individual values.
        MsgBox($MB_SYSTEMMODAL, "", "$aDays[" & $i & "] - " & $aDays[$i])
    Next
EndFunc   ;==>Example

Hello, this is from help file. How do i return all values excluding "Fri" which is delimited by a period?

[Melba23]

compact21,

You need a RegEx for that:

#include <Array.au3>
#include <StringConstants.au3>

$sText = "Mon,Tues,Wed,Thur,Fri.Sat,Sun"

Example()

_NoPeriod()

Func Example()
    Local $aDays = StringSplit($sText, ",.") ; Split the string of days using the delimiter "," and the default flag value.
    _ArrayDisplay($aDays, "StringSplit", Default, 8)
EndFunc   ;==>Example

Func _NoPeriod()
    $aDays = StringRegExp($sText, "(\w{3,4})(?:,|\z)", $STR_REGEXPARRAYGLOBALMATCH)
    _ArrayDisplay($aDays, "RegEx", Default, 8)
EndFunc

RegEx decode:

(\w{3,4}) - capture all sequences of 3 or 4 letters
(?:,|\z)  - followed by a comma or the end of the string, but do not capture this delimiter

M23

[mikell]

A variation  

#Include <Array.au3>

Local $sDays = "Mon,Tues,Wed,Thur,Fri.Sat,Sun"
Local $aDays = StringRegExp($sDays, '\w+(?=,|$)', 3)

_ArrayDisplay($aDays)

This one means : "get all sequences of word chars followed by a comma or end of string"

[czardas]

Ha, Melba and mikell beat me to it. I remove the unwanted day using StringRegExpReplace() before using StringSplit(). The regular expression is different: removing anything ending with a period. It serves as another illustration of the numerous possible ways there are to do things.
 

Example()

Func Example()
    Local $sString = StringRegExpReplace("Mon,Tues,Wed,Thur,Fri.Sat,Sun", '[^,]+\.', '') ; remove xxxx.
    Local $aDays = StringSplit($sString, ",") ; Split the string of days using the delimiter "," and the default flag value.
    For $i = 1 To $aDays[0] ; Loop through the array returned by StringSplit to display the individual values.
        MsgBox($MB_SYSTEMMODAL, "", "$aDays[" & $i & "] - " & $aDays[$i])
    Next
EndFunc   ;==>Example

 

[iamtheky]

Or if you have already determined what the string is that needs to be removed, just split on it in its entirety

#include<array.au3>

$sText = "Mon,Tues,Wed,Thur,Fri.Sat,Sun"

$aText = stringsplit($sText , "Fri." , 3)

msgbox(0, '' , _ArrayToString($aText , ""))

 

[compact21]

Thank you M23. Exactly what i needed. 

Edited January 17, 2016 by compact21

[compact21]

53 minutes ago, Melba23 said:

compact21,

You need a RegEx for that:

#include <Array.au3>
#include <StringConstants.au3>

$sText = "Mon,Tues,Wed,Thur,Fri.Sat,Sun"

Example()

_NoPeriod()

Func Example()
    Local $aDays = StringSplit($sText, ",.") ; Split the string of days using the delimiter "," and the default flag value.
    _ArrayDisplay($aDays, "StringSplit", Default, 8)
EndFunc   ;==>Example

Func _NoPeriod()
    $aDays = StringRegExp($sText, "(\w{3,4})(?:,|\z)", $STR_REGEXPARRAYGLOBALMATCH)
    _ArrayDisplay($aDays, "RegEx", Default, 8)
EndFunc

RegEx decode:

(\w{3,4}) - capture all sequences of 3 or 4 letters
(?:,|\z)  - followed by a comma or the end of the string, but do not capture this delimiter

M23

A tip how to use StringRegExp when delimiter is "?" instead of ","   ? Thakn you.

[mikell]

Just escape the question mark with a backslash => \?

[iamtheky]

#include<array.au3>

$delim = "?"

;~ $sText = "Mon,Tues,Wed,Thur,Fri.Sat,Sun"
$sText = "Mon,Tues,Wed?Thur,Fri,Sat,Sun"

$aText = stringsplit(stringreverse(stringregexpreplace(stringreverse($sText) , "(\" & $delim & "\D+?)," , ",")) , "," , 2)

_ArrayDisplay($aText)

 

[mikell]

#Include <Array.au3>

$delim = "?"
Local $sDays = "Mon?Tues?Wed?Thur?Fri.Sat?Sun"
Local $aDays = StringRegExp($sDays, '\w+(?=\Q' & $delim & '\E|$)', 3)

_ArrayDisplay($aDays)

 

[iamtheky]

yup I was backwards, I totally thought he asked what if it was '?' instead of '.' 

\Q....\E would make my regex life so much easier if I remembered to use them, but working on the reversed string is still my favorite way to provide examples

Edited January 17, 2016 by iamtheky

[mikell]

1 hour ago, iamtheky said:

.. working on the reversed string is still my favorite way to provide examples

I admit that this could be efficient but isn't it a slightly twisted way ?  

[iamtheky]

but its an easy win for the recipient to fix and then they have to reverse the regex which means they did something more than copy/paste.  And if you see that crap from anyone but me, you know where they got it from.

[mikell]

Irrefutable argument ... hat off  

[compact21]

Thanks a lot!