how to compare the 3 last lines of a text file ?

[asiawatcher]

test.au3

How can we read a whole text file and compare the last 3 lines with each other ? cheers

Edited January 17, 2016 by Melba23
Fixed post

[InunoTaishou]

I don't really know what exactly you're trying to accomplish, a little more info would help, but you just stated you want to compare the last three lines in a file. You can use StringCompare to do that

#include <File.au3>

Example()

Func Example()
    Local $aFile
    Local $iLastIndex
    Local $iCompare1
    Local $iCompare2
    Local $iCompare3

    _FileReadToArray(@ScriptDir & "\Test File.txt", $aFile, $FRTA_NOCOUNT)
    
    If (@Error) Then
        MsgBox("", "_FRTA Error", "Failed to read file to array")
        Return
    EndIf
    
    If (UBound($aFile) >= 3) Then
        $iLastIndex = UBound($aFile) - 1
        $iCompare1 = StringCompare($aFile[$iLastIndex], $aFile[$iLastIndex - 1])
        $iCompare2 = StringCompare($aFile[$iLastIndex - 1], $aFile[$iLastIndex - 2])
        $iCompare3 = StringCompare($aFile[$iLastIndex - 2], $aFile[$iLastIndex])

        MsgBox("", "Compare", "Last line and one line before last: " & ($iCompare1 = 0 ? "Equal" : $iCompare1 > 0 ? "Last line is greater" : "Line before last is greater") & @CRLF & _
                                "One line before last and two lines before last: " & ($iCompare2 = 0 ? "Equal" : $iCompare2 > 0 ? "Line before last is greater" : "Two lines before last is greater") & @CRLF & _
                                "Two lines before last and Last line: " & ($iCompare3 = 0 ? "Equal" : $iCompare3 > 0 ? "Two lines before last is greater" : "Last line is greater"))
    Else
        MsgBox("", "Array Size", "Array is too small to compare")
    EndIf
    
EndFunc

 

[asiawatcher]

hi thanks for your reply i got a text file filled with numbers in one column like

 

2

3

4

5

5

5

I want when i find 3 instances like 5,5,5 to throw an error but always the last line compared to the x2 above ones thanks 

[asiawatcher]

i guess this will do the trick thank you so much

[InunoTaishou]

If they're just numbers then you don't need to do StringCompare.

Sounds like you're just trying to make sure that there isn't three consecutive lines with 5s on them?

#include <File.au3>

Example()

Func Example()
    Local $aFile
    Local $bError = False

    _FileReadToArray(@ScriptDir & "\Test File.txt", $aFile, $FRTA_NOCOUNT)

    If (@Error) Then
        MsgBox("", "_FRTA Error", "Failed to read file to array")
        Return
    EndIf

    For $i = UBound($aFile) - 1 To 2 Step -1
        If ($aFile[$i] = 5 and $aFile[$i - 1] = 5 and $aFile[$i - 2] = 5) Then
            $bError = True
            ConsoleWrite("Detected three 5s on lines " & ($i - 1) & " to " & ($i + 1) & @LF)
        EndIf
    Next

    If ($bError) Then
        MsgBox("", "555", "Error detected in file")
    Else
        MsgBox("", "No Errors", "No errors detected in file")
    EndIf
EndFunc

Idk why I did it backwards through the file but that's how I did it.... lol

[asiawatcher]

it can be 555 or 333 or 222 i just want to make sure i dont have 3 lines with same numbers not just 5's any number

[InunoTaishou]

Then replace 5 with the other corresponding lines

[mikell]

You can try this

$txt = StringStripWS(FileRead("1.txt"), 8)
If StringRegExp($txt, '(.)\1\1$') Then Msgbox(0,"", "the 3 last ones are the same")

 

[guinness]

8 => $STR_STRIPALL and 0 => $MB_OK

Edited January 17, 2016 by guinness

[mikell]

5 minutes ago, guinness said:

8 => $STRIP_ALL and 0 => $MB_OK

Sorry ...
8 => $STRIP_ALL   $STR_STRIPALL 

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

$last3 = StringRegExpReplace(StringStripWS(FileRead("1.txt"), $STR_STRIPALL), '.*(.{3})$', "$1")
Msgbox($MB_OK ,"", $last3 & @crlf & "the 3 last ones are " & ((StringRegExp($last3, '(.)\1\1')=1) ? "" : "not") & " the same")

 

[guinness]

Thanks

[asiawatcher]

15 hours ago, mikell said:

You can try this

$txt = StringStripWS(FileRead("1.txt"), 8)
If StringRegExp($txt, '(.)\1\1$') Then Msgbox(0,"", "the 3 last ones are the same")

 

thank you so much everybody for your replies the above example is very nice and small 2 lines only

any way on top of that to also detect if there is the number 4 present before the 3 that we are already comparing  ? cheers

[mikell]

Here it is

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

$txt = StringStripWS(FileRead("1.txt"), $STR_STRIPALL)
; If StringRegExp($txt, '(.)\1\1$') Then Msgbox($MB_OK,"", "the 3 last ones are the same")
If StringRegExp($txt, '4...$') Then Msgbox($MB_OK,"", 'there is a "4" before the 3 last ones')

 

[asiawatcher]

17 hours ago, mikell said:

You can try this

$txt = StringStripWS(FileRead("1.txt"), 8)
If StringRegExp($txt, '(.)\1\1$') Then Msgbox(0,"", "the 3 last ones are the same")

 

amazing thanks works as a charm