_Filelistoarray remove extensions of results?

[darknezz21]

I'm trying to remove the extensions of the files returned with _Filelistoarray but am not sure how to express this.

Also tried _RecFileListToArray by Melba23 as suggested in the link I found below but I don't see an option for this functionality.

Here is what Ive tried so far, any suggestions?
 

;Local $aFileList = _FileListToArray(@ScriptDir, "*.txt")
Local $aFileList = _RecFileListToArray(@ScriptDir, "*.*", 0, 0, 0, 1, "*.au3", "")

   If @error = 1 Then
        MsgBox($MB_SYSTEMMODAL, "", "Path was invalid.")
        Exit
    EndIf
    If @error = 4 Then
        MsgBox($MB_SYSTEMMODAL, "", "No file(s) were found.")
        Exit
    EndIf
    ; Display the results returned by _FileListToArray.
    _ArrayDisplay($aFileList, "$aFileList")

MsgBox($MB_SYSTEMMODAL, "", $aFileList[1])

 

[Melba23]

darknezz21,

The comment refers to excluding certain file extensions from the returned array - not removing the extensions from the returned files.

My ChooseFileFolder UDF does have this functionality when displaying a file list (I use it when listing mp3 files) but that is not a lot of use to you. I think you are going to have to remove the extensions in a loop like this:

#include <File.au3>

Local $aFileList = _FileListToArrayRec(@ScriptDir, "*.*|*.au3", $FLTAR_FILES, $FLTAR_NORECUR, $FLTAR_NOSORT)

If @error = 1 Then
    MsgBox($MB_SYSTEMMODAL, "", "Path was invalid.")
    Exit
EndIf
If @error = 4 Then
    MsgBox($MB_SYSTEMMODAL, "", "No file(s) were found.")
    Exit
EndIf

; Now loop and remove the extension
For $i = 1 To $aFileList[0]
    $aFileList[$i] = StringRegExpReplace($aFileList[$i], "^.*\\|\..*$", "")
Next

_ArrayDisplay($aFileList, "$aFileList")

MsgBox($MB_SYSTEMMODAL, "", $aFileList[1])

Note that the deprecated  _RecFileListToArray UDF is now part of the standard UDFs (with a slightly different name) and has a different syntax for the excluded files and folders as you can see - look in the Help file for more details.

M23

 

[darknezz21]

I'm having trouble getting it to edit the .txt extensions off still. Here is basically what was tried. I also tried the .txt without the wildcard in front but it's the same.

Local $aFileList = _RecFileListToArray(@ScriptDir, "*.*", 1, 1, 1, 1, "*.au3", "")

$post = $aFileList[1]

; Now loop and remove the extension
For $i = 1 To $post
    $aFileList[$i] = StringRegExpReplace($aFileList[$i], "*.txt", "")
Next

_ArrayDisplay($aFileList, "$aFileList")

 

Edited January 16, 2016 by darknezz21

[Melba23]

darknezz21,

Why are you still using my old UDF? As I explained above, it is now deprecated and you should use the standard _FileListToArrayRec UDF.

And of course the RegEx will not work as you have coded it - the pattern will never match. If you leave the command exactly as I posted it will work.

M23

[mikell]

Melba,

$File = "C:\my.beloved.singer.mp3"
$File = StringRegExpReplace($File, "^.*\\|\..*$", "")
Msgbox(0,"", $File)

May I suggest

$File = StringRegExpReplace($File, '^.*\\|\.[^.]*$', "")

 

[Melba23]

mikell,

Of course you may - always ready to learn.

M23