Doubt about a variable's source

[DavidLago]

It's easier to see than to explain:

1. I IECreate a webpage,

$oIE = _IECreate("https://somewebsite.somewhere.net", 1, 1, 0)

Local $oImg = _IEImgGetCollection($oIE, 1)
If @error Then
    FileWriteLine(@ScriptDir & "\ObjError.log", "Error ImgCollection - " & @HOUR & ":" & @MIN)
    Sleep(250)
EndIf

Sleep(250)

Local $sInfo = $oImg.src
If @error Then
    FileWriteLine(@ScriptDir & "\ObjError.log", "Error Img.src - " & @HOUR & ":" & @MIN)
    Sleep(250)
EndIf

First @error returns something for sure, because its listed in the help file.

Second @error, not sure.

Is there a way to figure out if setting a variable to a variable.src is causing my script to eventually show this?

[jguinch]

If $oImg is not an object, you will have an error with $oImg.src. Add a Else to you first condition

Try this instead :

$oIE = _IECreate("https://somewebsite.somewhere.net", 1, 1, 0)

Local $oImg = _IEImgGetCollection($oIE, 1)
If @error Then
    FileWriteLine(@ScriptDir & "\ObjError.log", "Error ImgCollection - " & @HOUR & ":" & @MIN)
    Sleep(250)
    ; exit the script ?
Else
    Local $sInfo = $oImg.src
    ....
    ....
    ....
EndIf

 

[AdamUL]

You can also use IsObj.  

$oIE = _IECreate("https://somewebsite.somewhere.net", 1, 1, 0)

Local $oImg = _IEImgGetCollection($oIE, 1)
If @error Then
    FileWriteLine(@ScriptDir & "\ObjError.log", "Error ImgCollection - " & @HOUR & ":" & @MIN)
    Sleep(250)
EndIf

Sleep(250)

If IsObj($oImg) Then
    Local $sInfo = $oImg.src
    If @error Then
        FileWriteLine(@ScriptDir & "\ObjError.log", "Error Img.src - " & @HOUR & ":" & @MIN)
        Sleep(250)
    EndIf
EndIf

 

Adam

 

[DavidLago]

jguinch, that way I wouldn't know if there is an issue with $oImg.src or not. I'm thinking there is, because sometimes the page takes a while to load. And since the script measures the time it takes to load, its already inside a loop.

Adam, your suggestion might be exactly what I need!

[DavidLago]

Guys,

It seems that the error is happening inside 

Local $oImg = _IEImgGetCollection($oIE, 1)

I'll try to circle around and have an @error looping on it for 30 sec. I'll post it here if it solved the problem.

[mLipok]

Which AutoIt version you are using ?

[DavidLago]

@mLipok v3.3.14.2, Windows 7*

Edited January 18, 2016 by DavidLago

[mLipok]

I think this is a known bug reported on Track.
The only thing you can do is wait for the solution to the problem - new beta or release.

 

[DavidLago]

Do you know exactly what is this bug? The description? Is it on collecting the info from the IE?

[mLipok]

https://www.autoitscript.com/trac/autoit/ticket/3167

EDIT:

After further reflection, I have to say that this problem is therefore only if you are using the error handler, and yet still have this problem.

Edited January 18, 2016 by mLipok

[DavidLago]

@mLipok OK, help me understand that:

I saw that the bug reported is from a COM error that happens within some versions. But is this related somehow to the collecting of properties from IE with the function I mentioned above? (I'm asking because I really don't know).

Maybe the way that _IEImgGetCollection collects the info it needs uses this function with the COM error?

[mLipok]

First question is do you use ErrorHandler ?

Btw.
Yes this this is realted to _IEImgGetCollection ...
This UDF should be rewriten ... and is WorkInProgress.
 

[DavidLago]

I do not use the Error Handler. Never used, too.

What I'm thinking in order to get around the error problem is something like this:

$aWhileT2 = False

Local $startLoginTimer = TimerInit() ;Time it

While $aWhileT2 = False
    Local $sInfo = ""
    Local $oImg = ""
    Sleep(100)
    Local $oImg = _IEImgGetCollection($oIE, 1)
    Sleep(500 ; Give it some time to get the info and sort it in memory
    If @error Then
        Sleep(50)
        ;_ErrorDebug() ; Create a function to write a debug log         
    EndIf
    Local $sInfo = $oImg.src    
    If $sInfo <> "https://Citrix.somewhere.com/Citrix/Apps/Store/media/DownArrow.png" Then 
        Local $endLoginTimer = TimerDiff($startLoginTimer)
        $timeLogIn = Round($endLoginTimer / 1000, 1)
        If $timeLogIn > 30 Then ; Caso exceda 30seg, os usuários podem estar tendo problemas para autenticar.
            _FileAppendToLine($PathtoLogFile, 1, "resultLogin=failure;" & "statusLogin=Failure: Users might be having problems to authenticate;" & "timeLogIn=Null;")
            _RenameToFinalLog()
            _RunDos($KillIECommand) ; KILL IE
            Exit
        EndIf
    Else
        _FileAppendToLine($PathtoLogFile, 1, "resultLogin=success;" & "statusLogin=Success;" & "timeLogIn=" & $timeLogIn & ";")
        _RenameToFinalLog()
        $aWhileT2 = True
    EndIf
WEnd

 

[DavidLago]

But now I think I get what that error is...

Correct me if I'm wrong:

When this error right here happens: 

Local $oImg = _IEImgGetCollection($oIE, 1)
    Sleep(500) ; Give it some time to get the info and sort it in memory
    If @error Then
        Sleep(50)
        ;_ErrorDebug() ; Create a function to write a debug log         
    EndIf

It crashes, before setting the @error flag to non-zero.

amirite?

[mLipok]

1 hour ago, DavidLago said:

I do not use the Error Handler. Never used, too.

So you should start to use it (look in my signature).

1 hour ago, DavidLago said:

 

Local $oImg = _IEImgGetCollection($oIE, 1)
    Sleep(500) ; Give it some time to get the info and sort it in memory
    If @error Then
        Sleep(50)
        ;_ErrorDebug() ; Create a function to write a debug log         
    EndIf

 

Why you are testing for  Error from Sleep() ( this second line reset Error macro )

 

 

[jguinch]

Does the Example 2 in _IEImgGetCollection work for you ?

Also, variables should be declaced once, not every time. Can you try with that kind of code ?

$aWhileT2 = False

Local $startLoginTimer = TimerInit(), $endLoginTimer
Local $sInfo, $oImg

While $aWhileT2 = False
    $oImg = _IEImgGetCollection($oIE, 1)
    If @error Then
        Sleep(500)
    Else
        $sInfo = $oImg.src    
        
        If $sInfo <> "https://Citrix.somewhere.com/Citrix/Apps/Store/media/DownArrow.png" Then 
            $endLoginTimer = TimerDiff($startLoginTimer)
            $timeLogIn = Round($endLoginTimer / 1000, 1)
            If $timeLogIn > 30 Then ; Caso exceda 30seg, os usuários podem estar tendo problemas para autenticar.
                _FileAppendToLine($PathtoLogFile, 1, "resultLogin=failure;" & "statusLogin=Failure: Users might be having problems to authenticate;" & "timeLogIn=Null;")
                _RenameToFinalLog()
                _RunDos($KillIECommand) ; KILL IE
                _IEQuit()
                Exit
            EndIf
        Else
            _FileAppendToLine($PathtoLogFile, 1, "resultLogin=success;" & "statusLogin=Success;" & "timeLogIn=" & $timeLogIn & ";")
            _RenameToFinalLog()
            $aWhileT2 = True
        EndIf
    EndIf
WEnd

 

[water]

With AutoIt 3.3.14.x you need to implement a COM error handler. Else your script will always crash in case of a COM error.

The bug in Trak describes a problem when multiple objects/properties are accessed in a single statement. When an error occurres the script crashes even when a COM error handler is defined.
Lets assume the following statement:

$vResult = $oIE.Collection.Object.Property

If Object does not exist then a COM error is raised. But the next processing step is to access Property before the COM error can be returned to the calling script.
Only solution at the moment: Split the Statement into pieces and check for errors after each step.

Edited January 18, 2016 by water

[DavidLago]

1 hour ago, mLipok said:

Why you are testing for  Error from Sleep() ( this second line reset Error macro )

Right? That was stupid. Haha. I didn't even try (I'm far away from the testing computer now) I'm gonna fix it later.

@water Your explanation made it clear to me, thanks a lot for that.

@jguinch I'll test that code. It really makes sense to use it like this.

If it doesn't work, I'll try to split every property.

  

[water]

Or use Version 3.3.12.0 of AutoIt. Handles COM Errors without the need for a COM error handler and without any bugs  

[DavidLago]

@water Something weird happens when I run this version. Let me try to explain:

I am in Brazil, and I have a computer in the US running this script, to access a citrix environment and perform a lot of tests, running apps, clocking them, and some more things related to user experience.

When I run it from Chile, Colombia and other places nearby, they mostly work. When its far away, such as the US, China, Germany, and a bunch of other countries overseas, eventually the problem happens.

After heaps of testing, I figured out that the problem happens here:
 

$oIE = _IECreate("https://citrix.env.net", 1, 1, 0)
If @error Then
        MsgBox(0, "", "error IE CREATE") ; never shows any error
EndIf

; If I put a sleep(3000) here, it works most of the plays. If I change to 8000, works everytime.

Local $IELoadFlag = False
While $IELoadFlag = False
    $oForms = _IEFormGetCollection($oIE) ; it gets stuck here, it doesn't change the error flag, also never showed the MsgBox
    If @error Then
        MsgBox(0, "", "error get collection") 
    Else
        MsgBox(0, "", "Pass")
        $IELoadFlag = True
    EndIf
WEnd

I put the comments after the lines. 

It seems that the bug for the COM error still happens here. I think that, when IEFormGetCollection doesn't find an expected object (page not fully loaded), it crashes out, it won't loop, won't even set an @error flag, just out.

(OBS: IELoadWait won't work, because the Citrix https blocks it).

The behavior looks very much alike the newer versions. 

 

Edited January 19, 2016 by DavidLago