Single instance of a process

[Buzbee]

Im looking for a way to launch an executable (not the current script), get the pid, and close any other instance of that executable that does not match the pid!

Any leads in the right direction or snippets around?

I found something similar but it seems the user didnt care what instance of the process was closed

[BrewManNH]

ProcessList using the name of the executable will return all instances of the program that is running. Then you can search through the array for any instance that doesn't match the PID and then close it with ProcessClose.

[EmilyLove]

Here you go.

Global $WhitelistSinglePID = "15616" 
Global $Process = "Notepad.exe" ;Set Notepad.exe as the Process we are checking
Global $Processes = ProcessList($Process);get all relevant Processes
For $i = 1 To $Processes[0][0]; For Each found unique PID
    If Not ($Processes[$i][1] = $WhitelistSinglePID) Then ProcessClose($Processes[$i][1]);Close Process if it is not the whitelisted process
Next

 

Edited January 13, 2016 by BetaLeaf

[BrewManNH]

BetaLeaf, I'm guessing you've never heard of the concept of "Teach a man to fish"?

Take special note of the red text in my signature for an extension to that idea.

 

[jdelaney]

Check out this function in helpfile as well:

Run()

 

[EmilyLove]

Yea well here's the thing, I was already this exact code in many of my projects. I know it works. Also, while I do agree with you, the user did go thru the effort to search before posting, so I felt sharing what I already knew would have been find in this case.

[jdelaney]

It give a good baseline for the loop part.  I don't like the static variable for the pid though.  PID will never be static.  It must be obtained dynamically.

[EmilyLove]

It give a good baseline for the loop part.  I don't like the static variable for the pid though.  PID will never be static.  It must be obtained dynamically.

It is just an example post to get the op in the right direction.

[jdelaney]

Might as well actually demonstrate it then:

$Process = "Notepad.exe"

; populate a few processes to be closed later
Run($Process)
Run($Process)
Run($Process)

; the actual "process" you will initiate in your script
$iPid = Run($Process)
$Processes = ProcessList($Process)
For $i = 1 To $Processes[0][0]
    If Not ($Processes[$i][1] = $iPid) Then ProcessClose($Processes[$i][1])
Next

And now I'm getting bored

#include <WinAPI.au3>
$Process = "Notepad.exe"

; populate a few processes to be closed later
For $i = 1 To 5
    Run($Process)
Next

; the actual "process" you will initiate in your script
$iPid = Run($Process)
ConsoleWrite($iPid & " will not be closed" & @CRLF)
Sleep(1000)
$a = WinList("[CLASS:Notepad]")
Local $sPid, $x = 0, $y = 0
For $i = UBound($a)-1 To 1 Step -1
    _WinAPI_GetWindowThreadProcessId($a[$i][1],$sPid)
    ControlSetText($a[$i][1],"",15,"PID=[" & $sPid & "]")
    WinMove($a[$i][1],"",$x,$y)
    $x+=10
    $y+=80
Next

MsgBox(1,1,$iPid & " will not be closed")
$Processes = ProcessList($Process)
For $i = 1 To $Processes[0][0]
    If Not ($Processes[$i][1] = $iPid) Then ProcessClose($Processes[$i][1])
Next

 

Edited January 13, 2016 by jdelaney

[Buzbee]

Thank you  BrewManNH, BetaLeaf, and jdelaney for the help.

Func LoadPID()
    SplashTextOn($app_name & " Monitor", $app_name & " not running!" & @CRLF & "Please wait for it to reload!", 250, 75, -1, -1, $DLG_TEXTVCENTER, "", 12)
    Global $iPID = Run($app_path)
        Sleep($tick*1000)
    If ProcessExists($proc_name) Then
        Sleep($tick*1000)
        SplashOff()
    EndIf
EndFunc

Func MonPID()
    Global $proc_list = ProcessList($proc_name)
    For $i = 1 To $proc_list[0][0]
        If Not ($proc_list[$i][1] = $iPID) Then ProcessClose($proc_list[$i][1])
        Next
EndFunc

Im currently using these functions to run and monitor the process.
Had a problem properly getting the PID of the process if it was running before the script executes, to work around that I check for the process at script launch and if its running it will close the process and then run LoadPID()

Everything I am trying to accomplish has been working, with the exception of calling to execute  "script2.au3" script from "script1.au3". It works in the editor just fine but it will not run "script2.au3" from a compiled "script1.exe". For now I compile both scripts and call to the exe and not the au3.  

[Melba23]

Buzbee,

Quote

it will not run "script2.au3" from a compiled "script1.exe"

If you are using a recent version of AutoIt you need to add the following directive to allow a compiled exe to run an external script:

#pragma compile(AutoItExecuteAllowed, True)

By default this functionality is now disabled.

M23

[EmilyLove]

No Problem, Buzbee. Glad to help.