How to change tooitip font size?

[marsfann]

Hi

I have check tooltip function

but, I can not find the way to change font size

How to change tooitip font size?

Edited January 12, 2016 by marsfann

[InunoTaishou]

The tooltip font size is system dependent. You'd have to change it through the desktop properties.

You could try creating your own tooltip with adjustable font properties or perhaps a TrayTip?

[jguinch]

It seems to work with _WinAPI_CreateFont and _SendMessage :

 

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <FontConstants.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>

Local $hGUI = GUICreate("GUI", 300, 200)
Local $IDButton = GUICtrlCreateButton("Button", 10, 10, 200, 30)
Local $hToolTip = _GUIToolTip_Create(0, $TTS_BALLOON)

_GUIToolTip_AddTool($hToolTip, 0, "Tooltip with the specified font", GUICtrlGetHandle($IDButton) )

GUISetState(@SW_SHOW)

Local $hDC = _WinAPI_GetDC(0)
Local $hFont = _WinAPI_CreateFont(50, 0, 0, 0, 800, False, False, False, $DEFAULT_CHARSET, _
        $OUT_DEFAULT_PRECIS, $CLIP_DEFAULT_PRECIS, $DEFAULT_QUALITY, 0, 'Verdana')
$hOldFont = _WinAPI_SelectObject($hDC, $hFont)
_SendMessage ($hToolTip, $WM_SETFONT, $hFont, TRUE)

Do 
Until GUIGetMsg() = $GUI_EVENT_CLOSE

_WinAPI_SelectObject($hDC, $hOldFont)
_GUIToolTip_Destroy($hToolTip)
_WinAPI_DeleteObject($hFont)
_WinAPI_ReleaseDC(0, $hDC)
_WinAPI_InvalidateRect(0, 0)

 

[marsfann]

The tooltip font size is system dependent. You'd have to change it through the desktop properties.

You could try creating your own tooltip with adjustable font properties or perhaps a TrayTip?

if i use "GUICreate" ,when i play the game that is fullscreen

gmae will be minimize or crash

so, I have to use tooltip

[BrewManNH]

Look at the GUIToolTip_TrackPosition example script, you don't even need the GUI in that one. Combine the correct tracking functions for the tooltip with jguinch's code to get what you're looking for.

[qwert]

Since the good search tools went away last year, I've never been able to get decent results with Search ... so I resort to google.  But this time, it came up short.

So I'll just ask:  What's the current prescribed search method?

[BrewManNH]

Help file

[marsfann]

Look at the GUIToolTip_TrackPosition example script, you don't even need the GUI in that one. Combine the correct tracking functions for the tooltip with jguinch's code to get what you're looking for.

Use "GUIToolTip_TrackPosition",tooltip will trace my mouse

 

 

#include <GuiToolTip.au3>
#include <WinAPI.au3>
#include <GUIConstantsEx.au3>
#include <FontConstants.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>

Local $hToolTip = _GUIToolTip_Create(0), $hDC = _WinAPI_GetDC(0)
Local $hFont = _WinAPI_CreateFont(32, 0, 0, 0, 800, False, False, False, $DEFAULT_CHARSET,$OUT_DEFAULT_PRECIS, $CLIP_DEFAULT_PRECIS, $DEFAULT_QUALITY, 0, 'Tahoma')
Local $hOldFont = _WinAPI_SelectObject($hDC, $hFont)
_SendMessage ($hToolTip, $WM_SETFONT, $hFont, TRUE)
_GUIToolTip_AddTool($hToolTip, 0, "55555555555555555")
_GUIToolTip_TrackPosition($hToolTip,0 ,0)
_GUIToolTip_TrackActivate($hToolTip, True, 0, 0)
Sleep(1500)
_GUIToolTip_UpdateTipText($hToolTip, 0, 0, "999999999999")
Sleep(3000)
_GUIToolTip_Destroy($hToolTip)

[BrewManNH]

Use "GUIToolTip_TrackPosition",tooltip will trace my mouse

It only follows your mouse because the flags for the AddTool function weren't set.

Try this script out and you'll see it won't follow your mouse.

#include <GuiToolTip.au3>
#include <WinAPI.au3>
#include <GUIConstantsEx.au3>
#include <FontConstants.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>

Local $hToolTip = _GUIToolTip_Create(0), $hDC = _WinAPI_GetDC(0)
Local $hFont = _WinAPI_CreateFont(32, 0, 0, 0, 800, False, False, False, $DEFAULT_CHARSET, $OUT_DEFAULT_PRECIS, $CLIP_DEFAULT_PRECIS, $DEFAULT_QUALITY, 0, 'Tahoma')
Local $hOldFont = _WinAPI_SelectObject($hDC, $hFont)
_SendMessage($hToolTip, $WM_SETFONT, $hFont, True)
_GUIToolTip_AddTool($hToolTip, 0, "55555555555555555", 0, 0, 0, 0, 0, BitOR($TTF_TRACK, $TTF_ABSOLUTE)) ; <<<<<<<<<<<<<<<
_GUIToolTip_TrackPosition($hToolTip, 0, 0)
_GUIToolTip_TrackActivate($hToolTip, True, 0, 0)
Sleep(1500)
_GUIToolTip_UpdateTipText($hToolTip, 0, 0, "999999999999")
_GUIToolTip_TrackPosition($hToolTip, 100, 100)
Sleep(3000)
_GUIToolTip_Destroy($hToolTip)

 

[marsfann]

It only follows your mouse because the flags for the AddTool function weren't set.

Try this script out and you'll see it won't follow your mouse.

#include <GuiToolTip.au3>
#include <WinAPI.au3>
#include <GUIConstantsEx.au3>
#include <FontConstants.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>

Local $hToolTip = _GUIToolTip_Create(0), $hDC = _WinAPI_GetDC(0)
Local $hFont = _WinAPI_CreateFont(32, 0, 0, 0, 800, False, False, False, $DEFAULT_CHARSET, $OUT_DEFAULT_PRECIS, $CLIP_DEFAULT_PRECIS, $DEFAULT_QUALITY, 0, 'Tahoma')
Local $hOldFont = _WinAPI_SelectObject($hDC, $hFont)
_SendMessage($hToolTip, $WM_SETFONT, $hFont, True)
_GUIToolTip_AddTool($hToolTip, 0, "55555555555555555", 0, 0, 0, 0, 0, BitOR($TTF_TRACK, $TTF_ABSOLUTE)) ; <<<<<<<<<<<<<<<
_GUIToolTip_TrackPosition($hToolTip, 0, 0)
_GUIToolTip_TrackActivate($hToolTip, True, 0, 0)
Sleep(1500)
_GUIToolTip_UpdateTipText($hToolTip, 0, 0, "999999999999")
_GUIToolTip_TrackPosition($hToolTip, 100, 100)
Sleep(3000)
_GUIToolTip_Destroy($hToolTip)

 

BrewManNH!!!!

thank you so much