Hide autoit created popup taskbar button

[careca]

Hi there, this is supposed to work as a toast, called by functions and such. Kinda looks like the windows 10 notification, as intended,

and the only problem is that i can't find a way to hide the taskbar button.

 

expandcollapse popup

Opt("WinSearchChildren", 1)
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
HotKeySet("{ESC}", "Terminate")

Local $hParentWin, $hChildWin, $aMsg

$hParentWin = GUICreate("Parent GUI", 200, 100)
GUISetState(@SW_SHOW)

$hChildWin = GUICreate("Child GUI", 360, 65, @DesktopWidth + 400, @DesktopHeight - 106, $WS_POPUP, $WS_EX_APPWINDOW+$WS_EX_TOPMOST)
GUISetBkColor(0x1F1F1F, $hChildWin)
GUICtrlCreatePic(@ScriptDir&'\Info.bmp', 8, 8, 48, 48)
$Title = GUICtrlCreateLabel('Title', 70, 10, 250, 25)
GUICtrlSetFont($Title, 14, 900, 0, 'Arial', 5)
GUICtrlSetColor($Title, 0xFFFFFF)
GUICtrlSetBkColor($Title, 0x1F1F1F)
$Text = GUICtrlCreateLabel('Text', 70, 35, 250, 25)
GUICtrlSetFont($Text, 10, 600, 0, 'Arial', 5)
GUICtrlSetColor($Text, 0x707070)
GUICtrlSetBkColor($Text, 0x1F1F1F)
GUISetState(@SW_SHOW)

Show()

Func Show()
    WinMove($hChildWin, '', @DesktopWidth - 360, @DesktopHeight - 106, 360, 65, 1)
    ConsoleWrite('Show - ' & @MSEC & @CRLF)
EndFunc   ;==>Show

Func Hide()
    WinMove($hChildWin, '', @DesktopWidth + 400, @DesktopHeight - 106, 360, 65, 1)
    ConsoleWrite('Hide - ' & @MSEC & @CRLF)
EndFunc   ;==>Hide

While 1
    Sleep(300)
WEnd

Func Terminate()
    Exit
EndFunc   ;==>Terminate

 

Info.bmp

Edited January 6, 2016 by careca

[InunoTaishou]

If you create a fake GUI and never set it to @SW_SHOW and set your real GUI to the child of the fake, the task bar button will never show up.

#include <GUIConstants.au3>

Global $frmFakeGUI = GUICreate("Fake GUI", 0, 0)
Global $frmRealGUI = GUICreate("Real GUI", 200, 100, -1, -1, -1, -1, $frmFakeGUI)
Global $lblMsg = GUICtrlCreateLabel("This is a GUI without a task bar icon", 10, 10, 180, 40)

GUICtrlSetFont($lblMsg, 12)

GUISetState(@SW_SHOW, $frmRealGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit 0
    EndSwitch
WEnd

 

[careca]

Awesome! Exactly what i was looking for! Although i think it would be nice to just have a flag to make it so, without playing those tricks, also i didn't see it in help file.

Best regards.

[BrewManNH]

Instead of creating a hidden GUI you can always use the AutoIt hidden GUI that is created everytime you run a script. You can get an idea of how to interact with it by checking the help file for AutoItWinGetTitle.

[careca]

Thanks BrewManNH, but whatever i do with AutoItWinGetTitle, the taskbar button appears as soon as i need to see the hidden window and call @SW_SHOW,

Maybe i just didn't understand where you're pointing?

[BrewManNH]

Take InunoTaishou's script, and instead of creating a new hidden GUI as his script does, you can use the one that AutoIt creates every time you run your script. Saves you from having to create unnecessary GUIs.

[InunoTaishou]

Use WinGetHandle(AutoItWinGetTitle()) to get a handle to the AutoIt Window and use that handle instead of $frmFakeGUI

[BrewManNH]

BTW InunoTaishou, that's a pretty slick way of doing that. I normally ended up using a popup style window or something similar.

[careca]

I incorporated the method in another script, where i do need both gui's.

[InunoTaishou]

Glad we were able to help!

[Holger]

To create something like an info window you only need the Windows ExStyle WS_EX_TOOLWINDOW.

You can combine the style WS_POPUP and WS_BORDER or just use WS_CAPTION as style.

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>

Dim $hGUI = GUICreate("MyGUI", 200, 80, -1, -1, BitOr($WS_BORDER, $WS_POPUP), $WS_EX_TOOLWINDOW)

GUISetState()

While 1
    $Msg = GUIGetMsg()
    If $Msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd

GUIDelete()

Exit

 

[careca]

Nice. Thanks.

[Tiotua]

On 6.1.2016 at 11:15 PM, InunoTaishou said:

If you create a fake GUI and never set it to @SW_SHOW and set your real GUI to the child of the fake, the task bar button will never show up.

#include <GUIConstants.au3>

Global $frmFakeGUI = GUICreate("Fake GUI", 0, 0)
Global $frmRealGUI = GUICreate("Real GUI", 200, 100, -1, -1, -1, -1, $frmFakeGUI)
Global $lblMsg = GUICtrlCreateLabel("This is a GUI without a task bar icon", 10, 10, 180, 40)

GUICtrlSetFont($lblMsg, 12)

GUISetState(@SW_SHOW, $frmRealGUI)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit 0
    EndSwitch
WEnd

 

Wonderful. Exactly what I needed.  With

Global $frmRealGUI = GUICreate("Real GUI", 200, 100, -1, -1, $WS_SYSMENU, -1, $frmFakeGUI)

you'll get a GUI with only a close button (like a dialog box).

Edited September 25, 2016 by Tiotua
My text was inside quote ._.

[careca]

9 months, just like a baby huh?