Track ListViewItems in a ListView

[TheDcoder]

Hello! I want to keep track of all the ListViewItems in a ListView:

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 267, 206, 192, 124)
$ListView1 = GUICtrlCreateListView("Col 1|Col 2", 8, 8, 250, 150)
$Button1 = GUICtrlCreateButton("Get Extended", 8, 168, 251, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

GUICtrlCreateListViewItem("Foo|Bar", $ListView1) ; Extended: Comman Placeholders
GUICtrlCreateListViewItem("Baz|Qux", $ListView1) ; Extended: Rare Placeholders

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
            
        Case $Button1
            ; ...?

    EndSwitch
WEnd

In the above example situation, I want to get the extended text (commented after each ListViewItem) for the the ListViewItem... If I select Foo & Bar (1st Item) and press "Get Extended" a MsgBox should display "Comman Placeholders"

 

Thanks in Advance, TD

 

P.S The items are dynamically created in my program and the extended information is stored in a array

[TheDcoder]

This is a perfect situation to use maps, I hope it may release soon!

[Melba23]

TheDcoder,

The items are dynamically created in my program and the extended information is stored in a array

And what is the link between the two? How do you determine which element of the extended information array relates to the selected ListView item?

M23

[TheDcoder]

And what is the link between the two?

Each Item has a path associated...

How do you determine which element of the extended information array relates to the selected ListView item?

That is what I was looking for

[Melba23]

TheDcoder,

Assuming that you create the extended information at the same time as a ListView row, you can use an array to very easily link the two elements:

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Global $aData[2][2] = [["Foo|Bar", "Comman Placeholder"], ["Baz|Qux", "Rare Placeholders"]]

$Form1 = GUICreate("Form1", 267, 206, 192, 124)
$ListView1 = GUICtrlCreateListView("Col 1|Col 2", 8, 8, 250, 150)
$Button1 = GUICtrlCreateButton("Get Extended", 8, 168, 251, 25)
GUISetState(@SW_SHOW)

For $i = 0 To UBound($aData) - 1
    GUICtrlCreateListViewItem($aData[$i][0], $ListView1)
Next

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg

        Case $GUI_EVENT_CLOSE
            Exit

        Case $Button1
            $iIndex = _GUICtrlListView_GetSelectedIndices($ListView1)
            If $iIndex <> "" Then
                MsgBox($MB_SYSTEMMODAL, "Extended", $aData[$iIndex][1])
            EndIf



    EndSwitch
WEnd

Just add a new row to the array each time you create a ListView row.

M23

[TheDcoder]

@Melba23 Just what I was looking for, Thanks you!