IniWriteSection

[Bert]

Having a bit of trouble with this one for the example is really muddy. I'm trying to record window positions in an INI file. What I've tried:

$W1=WinGetPos("Microsoft Outlook", "FolderBar")
IniWriteSection(@ScriptDir&"/settings.ini","MO", $W1)

I'm assuming the Array is what is causing me the problem. I know the data is a 2-dimension however it isn't being written to the INI.

I also tried to write to the INI with this for the Parameters for data states: The data to write. The data can either be a string or an array. If the data is a string, then each key=value pair must be delimited by @LF. If the data is an array, the array must be 2-dimensional and the second dimension must be 2 elements.

IniWriteSection(@ScriptDir&"/settings.ini","MO", $W1[1][1]@LF $W1[2][1]@LF $W1[3][1]@LF $W1[4][1])

How do I code it to pass the data to the INI? 

[jguinch]

?

$ret = IniWriteSection(@ScriptDir & "\settings.ini","MO", "X=" & $W1[0] & @LF & "Y=" & $W1[1] & @LF & "W=" & $W1[2] & @LF & "H=" & $W1[3])

[Bert]

Just tried the code. Getting an error. 

IniWriteSection(@ScriptDir & "\settings.ini","MO", "X=" & $W1[0] & @LF & "Y=" & $W1[1] & @LF & "Width=" & $W1[2] & @LF & "Height=" & $W1[3])
IniWriteSection(@ScriptDir & "\settings.ini","MO", "X=" & $W1^ ERROR

[BrewManNH]

#include <Array.au3>
$W1 = WinGetPos("[active]", "")
Global $sData = ""
$sData &= "X=" & $w1[0] & @LF
$sData &= "Y=" & $w1[1] & @LF
$sData &= "Width=" & $w1[2] & @LF
$sData &= "Height = " & $w1[3]
IniWriteSection(@ScriptDir & "\settings.ini", "MO", $sData)
$array = IniReadSection(@ScriptDir & "\settings.ini", "MO")
_ArrayDisplay($array)

 

[jguinch]

You have an error because $W1 is not an array (no window found), isn't it ?

This code works for me :

$W1 = WinGetPos("Microsoft Outlook", "")
IniWriteSection(@ScriptDir & "\settings.ini","MO", "X=" & $W1[0] & @LF & "Y=" & $W1[1] & @LF & "W=" & $W1[2] & @LF & "H=" & $W1[3])

Also, with a 2D array :

$W1 = WinGetPos("Microsoft Outlook", "")
Local $aArr[5][2] = [[], ["X", $W1[0]], ["Y", $W1[1]], ["W", $W1[2]], ["H", $W1[3]] ]
IniWriteSection(@ScriptDir & "\settings.ini","MO", $aArr)

 

[JohnOne]

WinFetPos does not create 2 dimensional array

[Bert]

@BrewManNH I see how that works but the example in the help file is not even close to that. I guess my main complaint is the help fine example is horrid. It be great if there was a simple example showing how it works and not the example where it is used over and over for several commands in the help file. 

[Bert]

You have an error because $W1 is not an array (no window found), isn't it ?

This code works for me :

$W1 = WinGetPos("Microsoft Outlook", "")
IniWriteSection(@ScriptDir & "\settings.ini","MO", "X=" & $W1[0] & @LF & "Y=" & $W1[1] & @LF & "W=" & $W1[2] & @LF & "H=" & $W1[3])

Also, with a 2D array :

$W1 = WinGetPos("Microsoft Outlook", "")
Local $aArr[5][2] = [[], ["X", $W1[0]], ["Y", $W1[1]], ["W", $W1[2]], ["H", $W1[3]] ]
IniWriteSection(@ScriptDir & "\settings.ini","MO", $aArr)

 

OK, that works and is very simple. Thanks!

[Bert]

I wanted to mark this thread as solved but I see we can't do that like we used to. (or I'm missing it)

[JohnOne]

Simplest way for me would be...

Func _WinGetPos($title, $text = "")
    Local $a = WinGetPos($title, $text)
    Local $size = UBound($a) - 1
    Local $a2[$size][2]
    For $i = 0 To $size - 1
        $a2[$i][0] = $a[$i]
        $a2[$i][1] = $a[$i + 1]
    Next
    Return $a2
EndFunc

 

[BrewManNH]

The example in the help file is using a 2D array, WinGetPos returns a 1D array so it has to be manipulated into a 2D array to make it work.

[Bert]

I ended up doing this for the function and it works perfectly. I have 3 monitors and when I use my KVM the three windows I need to track get moved. I have the function that moves them back but I wanted something that would record the positions when I use a different workstation (I have 4 office locations I work out of):

Func _MW2()
   $W1=WinGetPos("Microsoft Outlook", "FolderBar")
   $W2=WinGetPos("Avaya one-X® Communicator", "")
   $W3=WinGetPos("Microsoft Lync","")
   IniWriteSection(@ScriptDir & "\settings.ini","MO", "X=" & $W1[0] & @LF & "Y=" & $W1[1] & @LF & "W=" & $W1[2] & @LF & "H=" & $W1[3])
   IniWriteSection(@ScriptDir & "\settings.ini","AVAYA", "X=" & $W2[0] & @LF & "Y=" & $W2[1] & @LF & "W=" & $W2[2] & @LF & "H=" & $W2[3])
   IniWriteSection(@ScriptDir & "\settings.ini","ML", "X=" & $W3[0] & @LF & "Y=" & $W3[1] & @LF & "W=" & $W3[2] & @LF & "H=" & $W3[3])
EndFunc

 

Edited December 29, 2015 by Bert

[BrewManNH]

What I find odd about IniWriteSection is that if you use @CRLF instead of just @LF, you get a line ending of CR on the key/value pairs line, and an extra CRLF line after every entry. That's some weird Windows voodoo going on there.

[Bert]

I see this in the help file for the macros:

@CR	Carriage return, Chr(13); occasionally used for line breaks.
@LF	Line feed, Chr(10); occasionally used for line breaks.
@CRLF	@CR & @LF; typically used for line breaks.

[BrewManNH]

I understand what the macros are, I just found it odd that when using the wrong one you got strange results in the INI file.

The LF is converted to a CR in the file, the CRLF gets converted to a CR and a CRLF in the file. Just thought it a bit strange.

[TheSaint]

I have not looked closely at the issue being discussed here, but INI files do not cope with line feeds or carriage returns.

I have always found that a substitution is required, like the pipe character ... conversion in and out.

That is with IniWrite though.

[guinness]

@BrewManNH I see how that works but the example in the help file is not even close to that. I guess my main complaint is the help fine example is horrid.

Example in the help file (v3.3.14.2) looks okay to me, as I re-wrote them ages ago.

Edited December 29, 2015 by guinness

[guinness]

@All, if you're not satisfied with an example in the help file, then instead of letting it sit there misinforming users, create a ticket and clearly point out why it's a bad example. It also helps if you can provide us with an example that is better suited, because of course it's your help file too.

As for the example specified here, I see nothing wrong with it and therefore won't be re-writing something that looks self-explanatory to me.

Edited December 29, 2015 by guinness

[JohnOne]

and who deals with the ticket?

[BrewManNH]

Any one of numerous MVPs have access to the trac system and the help files.